[strahh]

Hello everyone, I wanted to make a multilang of standard zombie classes

faced with the problem that zombieclasses.ini does not read info from lang (ML_)
, i.e. for the place of text information in the game with lang, I get ML_CLSC, ML_BIG etc.

but in the zombie selection menu, everything works



in zombie_plague.txt keys are present

[CrazY.]

Search for

register_dictionary("zombie_plague.txt")

And paste this below it

register_dictionary("zombie_classes.txt")

Create the zombie_classes.txt file in addons/amxmodx/data/lang and replace the ShowHud function (should be in line 8525) with this.

// Show HUD Task
public ShowHUD(taskid)
{
	static id
	id = ID_SHOWHUD;
	
	// Player died?
	if (!g_isalive[id])
	{
		// Get spectating target
		id = pev(id, PEV_SPEC_TARGET)
		
		// Target not alive
		if (!g_isalive[id]) return;
	}
	
	// Format classname
	static class[32], red, green, blue
	
	if (g_zombie[id]) // zombies
	{
		red = 255
		green = 255
		blue = 0
		
		if (g_nemesis[id])
		{
			formatex(class, charsmax(class), "%L", ID_SHOWHUD, "CLASS_NEMESIS")
		}
		else
		{
			ArrayGetString(g_zclass_name, g_zombieclass[id], class, charsmax(class))

			new key[64]
			formatex(key, charsmax(key), "ZOMBIE(%s)", class)
			replace_all(key, charsmax(key), " ", "-")

			if (GetLangTransKey(key) != TransKey_Bad)
			{
				formatex(class, charsmax(class), "%L", ID_SHOWHUD, key)
			}
		}

		//copy(class, charsmax(class), g_zombie_classname[id])
	}
	else // humans
	{
		red = 0
		green = 0
		blue = 255
		
		if (g_survivor[id])
		formatex(class, charsmax(class), "%L", ID_SHOWHUD, "CLASS_SURVIVOR")
		else
		formatex(class, charsmax(class), "%L", ID_SHOWHUD, "CLASS_HUMAN")
	}
	
	// Spectating someone else?
	if (id != ID_SHOWHUD)
	{
		// Show name, health, class, and ammo packs 
		set_dhudmessage(255, 255, 255, HUD_SPECT_X, HUD_SPECT_Y, 0, 6.0, 1.1, 0.0, 0.0)
		show_dhudmessage(ID_SHOWHUD, "[%L %s]^n[HP: %d] [%L %s] [%L %d]", ID_SHOWHUD, "SPECTATING", g_playername[id], pev(id, pev_health), ID_SHOWHUD, "CLASS_CLASS", class, ID_SHOWHUD, "AMMO_PACKS1", g_ammopacks[id])
	}
	else
	{
		// Show health, class and ammo packs 
		set_hudmessage(red, green, blue, HUD_STATS_X, HUD_STATS_Y, 0, 6.0, 1.1, 0.0, 0.0)
		show_hudmessage(ID_SHOWHUD, "[%L: %d] [%L %s] [%L %d]", id, "ZOMBIE_ATTRIB1", pev(ID_SHOWHUD, pev_health), ID_SHOWHUD, "CLASS_CLASS", class, ID_SHOWHUD, "AMMO_PACKS1", g_ammopacks[ID_SHOWHUD])
	}
}

Now just add the translations for the classes in the zombie_classes.txt file you created. The format is

ZOMBIE(Zombie-Name) = The Zombie Name

where "Zombie-Name" is the name of the class. Spaces must be replaced with a dash "-".

Suppose you've this in zp_zombieclasses.ini

[Classic Zombie]
NAME = Classic Zombie
INFO = =Balanced=
MODELS = host_zombie
CLAWMODEL = models/nst_zombie/v_knife_tank_zombi.mdl
HEALTH = 3000
SPEED = 0.75
GRAVITY = 1.00
KNOCKBACK = 1.00

You would replace "Zombie-Name" with the one marked in red, in this case, Classic Zombie.

ZOMBIE(Classic-Zombie) = Classic Zombie

Hope that makes sense.

[strahh]

yes it really works, thanks

I also changed it here according to your example

// Show selected zombie class info and stats

new key[64]
formatex(key, charsmax(key), "ZOMBIE(%s)", name)
replace_all(key, charsmax(key), " ", "-")

if (GetLangTransKey(key) != TransKey_Bad)
{
formatex(name, charsmax(name), "%L", id, key)
}

// Show selected zombie class info and stats
zp_colored_print(id, "^x04[ZM]^x01 %L: ^x04%s", id, "ZOMBIE_SELECT", name)
zp_colored_print(id, "^x04[ZM]^x01 %L: ^x04%d ^x01%L: ^x04%d ^x01%L: ^x04%d ^x01%L: ^x04%d%%", id, "ZOMBIE_ATTRIB1", ArrayGetCell(g_zclass_hp, g_zombieclassnext[id]), id, "ZOMBIE_ATTRIB2", ArrayGetCell(g_zclass_spd, g_zombieclassnext[id]),
id, "ZOMBIE_ATTRIB3", floatround(Float:ArrayGetCell(g_zclass_grav, g_zombieclassnext[id]) * 800.0), id, "ZOMBIE_ATTRIB4", floatround(Float:ArrayGetCell(g_zclass_kb, g_zombieclassnext[id]) * 100.0))

[CrazY.]

In this line

formatex(name, charsmax(name), "%L", name, key)

name should be either id or LANG_PLAYER

formatex(name, charsmax(name), "%L", id, key)

[strahh]

Originally Posted by CrazY. In this line formatex(name, charsmax(name), "%L", name, key) name should be either id or LANG_PLAYER formatex(name, charsmax(name), "%L", id, key)

Yes, I did the same, accidentally inserted one of the failed attempts in reply!
Thanks again!