if ! [Help] Equali, Print

Baws · **Author**

I want something like when i type the command ( /search ) and if it didn't find anything it will print "Results: Nothing was found". What i did, didn't work. Tried many things didn't work. if(!...... else print ...etc didn't work. Is there a way to do it?

PHP Code:


			
public Cmd_Say( id ) 
{
        new szText[ 192 ];
        read_args( szText, charsmax( szText ) );
        remove_quotes( szText );
    
        if( szText[ 0 ] != '/' )
                return PLUGIN_CONTINUE;
    
        if( equali( szText[ 1 ], "music", 5 ) ) 
        {
                SongList( id );
        
                return PLUGIN_HANDLED;
        }
    
        else if( equali( szText[ 1 ], "stop", 4 ) ) 
        {
                new Motd[ 384 ], Len;
        
                Len = formatex( Motd, charsmax( Motd ), "<html><head><style type=^"text/css^">pre{color:#FFB000;}body{background:#000000;margin-left:8px;margin-top:0px;}</style></head><pre><body><center>" );
                Len += formatex( Motd[ Len ], charsmax( Motd ) - Len, "<b>Music Stopped</b>." );
                Len += formatex( Motd[ Len ], charsmax( Motd ) - Len, "This has been brought you by %s.^n", g_szAuthor );
                Len += formatex( Motd[ Len ], charsmax( Motd ) - Len, "%s is the most powerful music player plugin ever!^n", g_szPlugin );
                Len += formatex( Motd[ Len ], charsmax( Motd ) - Len, "Hope you had fun listening to the nice music!^n" );
                formatex( Motd[ Len ], charsmax( Motd ) - Len, "</center></body></pre></html>" );
        
                show_motd( id, Motd, g_szPlugin );
                return PLUGIN_HANDLED;
        }
    
        else if( equali( szText[ 1 ], "replay", 6 ) ) 
        {
        
                if( g_Song[ id ] != 0 )
                        Play_Song( id, g_Song[ id ] );
                else
                        client_print_color( id, NORMAL, "%L", id, "NO_SONG_PLAYED" );
            
                return PLUGIN_HANDLED;
        }
    
        else if( equali( szText[ 1 ], "copy", 4 ) ) 
        {
                Cmd_CopySong( id );
        
                return PLUGIN_HANDLED;
        }
    
        else if( equali( szText[ 1 ], "search", 6 ) ) 
        {
                new szName[ 64 ];
                strbreak( szText, "", 0, szName, charsmax( szName ) );
        
                Cmd_Search( id, szName );
        
                return PLUGIN_HANDLED;
        }
    
        return PLUGIN_CONTINUE;
}

public SongList_Handler( id, hMenu, item ) 
{    
        if( item != MENU_EXIT )
        {
                new szData[ 6 ], szName[ 64 ], access, callback;
                menu_item_getinfo( hMenu, item, access, szData, charsmax( szData ), szName, charsmax( szName ), callback )

                new sChoice = str_to_num( szData );

                Play_Song( id, sChoice );
        }
    
        menu_destroy( hMenu )
        return PLUGIN_HANDLED;
}

Cmd_Search( id, const iText[ ] )
{
        client_print_color( id, NORMAL, "%L", id, "SEARCHED_FOR", iText ); //Where it says: "Searched for 'x'. " I want that if the 'x' word is not found well it will says instead of searched for, it'll say not found.

        new szNum[ 6 ], hMenu = menu_create( "\ySearch Results:", "SongList_Handler" );
    
        for( new i = 1 ; i < g_SongCount + 1 ; i++ ) 
        {
                num_to_str( i, szNum, 5 )
                ArrayGetArray( g_hArray, i, g_SongInformation );

                if( containi( g_SongInformation[ Name ], iText ) == -1 )
                        continue;
        
                menu_additem( hMenu, g_SongInformation[ Name ], szNum );
        }

        menu_display( id, hMenu )
        return PLUGIN_HANDLED;
}

Kiske · *Last edited by Kiske; 03-13-2014 at 21:39.*

PHP Code:


			
Cmd_Search( id, const iText[ ] )
{
    new szNum[ 6 ], hMenu = menu_create( "\ySearch Results:", "SongList_Handler" );

    for( new i = 1 ; i < g_SongCount + 1 ; i++ ) 
    {
        num_to_str( i, szNum, 5 )
        ArrayGetArray( g_hArray, i, g_SongInformation );

        if( containi( g_SongInformation[ Name ], iText ) == -1 )
            continue;

        menu_additem( hMenu, g_SongInformation[ Name ], szNum );
    }

    if(menu_items(hMenu) <= 0) {
        client_print_color( id, NORMAL, "Results: Nothing was found");

        menu_destroy(hMenu);
        return PLUGIN_HANDLED;
    } else {
        client_print_color( id, NORMAL, "%L", id, "SEARCHED_FOR", iText );
    }

    menu_display( id, hMenu )
    return PLUGIN_HANDLED;
}

Baws · *Last edited by Baws; 03-14-2014 at 00:10.*

Won't work.

g_SongInformation[ Name ] = For the names and i think it should be used..

fysiks · 03-14-2014 , 01:20 Re: if ! [Help] Equali, Print

TL;DR

Just initialize a boolean as false. Set it to true ONLY if you find a match. At the end of the function, if the boolean is still false, no match was found.

Baws · 03-14-2014 , 17:43 Re: if ! [Help] Equali, Print

I did everything, in any way possible. Didn't work.

Can you explain more please?

Black Rose · 03-14-2014 , 18:39 Re: if ! [Help] Equali, Print

This is what fysiks suggested which is a good idea.

Code:

Cmd_Search( id, const iText[ ] )
{
    
    new bool:bMatch, szNum[ 6 ], hMenu = menu_create( "\ySearch Results:", "SongList_Handler" );
    
    for( new i = 1 ; i < g_SongCount + 1 ; i++ )
    {
        num_to_str( i, szNum, 5 )
        ArrayGetArray( g_hArray, i, g_SongInformation );
        
        if( containi( g_SongInformation[ Name ], iText ) == -1 )
        continue;
        
        bMatch = true;
        menu_additem( hMenu, g_SongInformation[ Name ], szNum );
    }
    
    if ( ! bMatch ) {
        client_print_color( id, NORMAL, "%L", id, "NOT_FOUND", iText );
        menu_destroy(hMenu);
        return;
    }
    
    client_print_color( id, NORMAL, "%L", id, "SEARCHED_FOR", iText );
    menu_display( id, hMenu )
    return;
}

Baws · 03-14-2014 , 20:06 Re: if ! [Help] Equali, Print

It works, but i want to understand why what i did didn't work.

Here:

PHP Code:


			
new bool:bSearchFound;

Cmd_Search( id, const iText[ ] )
{
        if ( bSearchFound ) //if bool is false itll print this
        {
                client_print_color( id, NORMAL, "%L", id, "NOT_FOUND", iText );
        
                menu_destroy( hMenu );
                return;
        }
        else //if bool is true, normal print 
                client_print_color( id, NORMAL, "%L", id, "SEARCHED_FOR", iText );

        new szNum[ 6 ], hMenu = menu_create( "\ySearch Results:", "SongList_Handler" );
    
        for( new i = 1 ; i < g_SongCount + 1 ; i++ )
        {
                num_to_str( i, szNum, 5 )
                ArrayGetArray( g_hArray, i, g_SongInformation );
        
                if( containi( g_SongInformation[ Name ], iText ) == -1 )
                continue;
        
                bSearchFound = true;
                menu_additem( hMenu, g_SongInformation[ Name ], szNum );
        }

        menu_display( id, hMenu )
        return;
}

**Arkshine** · 03-15-2014 , 02:58 Re: if ! [Help] Equali, Print

Come one baws, try to think. You see well you check bSearchFound before being set to true. Do you think once set, it will magically read the function from the start?

Baws · *Last edited by Baws; 03-15-2014 at 11:53.*

Quote:

Originally Posted by Arkshine

Come one baws, try to think. You see well you check bSearchFound before being set to true. Do you think once set, it will magically read the function from the start?

I just searched and a boolean is false from the start, yeah i did some effort and searched for it to make sure. Thanks mate.

Fixed btw.

fysiks · 03-15-2014 , 15:09 Re: if ! [Help] Equali, Print

Quote:

Originally Posted by baws

I just searched and a boolean is false from the start, yeah i did some effort and searched for it to make sure. Thanks mate.

Fixed btw.

You never set the boolean back to false (in your code).