[Sn!ff3r]

Hi, short question:

how to change footstep sounds (if this is possible) ?

[Alka]

No.But you can make block original sound, then make a fake ent and emit custom sound with a delay(time between steps).

[Sn!ff3r]

No.But you can make block original sound, then make a fake ent and emit custom sound with a delay(time between steps).

Oh yeah :>

Maybe small example :] ?

[Alka]

#include <amxmodx>
#include <fakemeta>
 
#define PLUGIN "New Plugin"
#define VERSION "1.0"
#define AUTHOR "Alka"
 
#define STEP_DELAY 0.5
 
new Float:g_fNextStep[33];
 
new const g_szStepSound[] = "custom_step_sound.wav";
 
public plugin_init() {
 
 register_plugin(PLUGIN, VERSION, AUTHOR);
 
 register_forward(FM_PlayerPreThink, "fwd_PlayerPreThink", 0);
}
 
public plugin_precache()
 precache_sound(g_szStepSound);
 
public fwd_PlayerPreThink(id)
{
 if(!is_user_alive(id))
  return FMRES_IGNORED;
 
 set_pev(id, pev_flTimeStepSound, 999);
 
 if(g_fNextStep[id] < get_gametime())
 {
  if(fm_get_ent_speed(id) && (pev(id, pev_flags) & FL_ONGROUND))
   emit_sound(id, CHAN_BODY, g_szStepSound, VOL_NORM, ATTN_STATIC, 0, PITCH_NORM);
  
  g_fNextStep[id] = get_gametime() + STEP_DELAY;
 }
 return FMRES_IGNORED;
}
 
stock Float:fm_get_ent_speed(id)
{
 if(!pev_valid(id))
  return 0.0;
 
 static Float:vVelocity[3];
 pev(id, pev_velocity, vVelocity);
 
 vVelocity[2] = 0.0;
 
 return vector_length(vVelocity);
}

[TSuNaMi_]

but there is 4 steps ??

[Alka]

what 4 steps? This should block any footstep sounds.

[TSuNaMi_]

you look to into:

sound/players/ and you will see:

pl_step1.wav
pl_step2.wav
pl_step3.wav
pl_step4.wav

[Alka]

Yest, they are played random...you can modify the array to 2D size, then put more custom sounds, and into emit_sound native, make it play a random step sound.

PHP Code:

#include <amxmodx>
#include <fakemeta>

#define PLUGIN "New Plugin"
#define VERSION "1.0"
#define AUTHOR "Alka"

#define STEP_DELAY 0.5

new Float:g_fNextStep[33];

#define MAX_SOUNDS 4 //Max num of sound for list below

new const g_szStepSound[MAX_SOUNDS][] = {
    
    "custom_step_sound#1.wav",
    "custom_step_sound#2.wav",
    "custom_step_sound#3.wav",
    "custom_step_sound#4.wav"
};

public plugin_init() {
    
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    register_forward(FM_PlayerPreThink, "fwd_PlayerPreThink", 0);
}

public plugin_precache()
{
    new i;
    for(i = 0; i < MAX_SOUNDS ; i++)
        precache_sound(g_szStepSound[i]);
}

public fwd_PlayerPreThink(id)
{
    if(!is_user_alive(id))
        return FMRES_IGNORED;
    
    set_pev(id, pev_flTimeStepSound, 999);
    
    if(g_fNextStep[id] < get_gametime())
    {
        if(fm_get_ent_speed(id) && (pev(id, pev_flags) & FL_ONGROUND))
            emit_sound(id, CHAN_BODY, g_szStepSound[random(MAX_SOUNDS)], VOL_NORM, ATTN_STATIC, 0, PITCH_NORM);
        
        g_fNextStep[id] = get_gametime() + STEP_DELAY;
    }
    return FMRES_IGNORED;
}

stock Float:fm_get_ent_speed(id)
{
    if(!pev_valid(id))
        return 0.0;
    
    static Float:vVelocity[3];
    pev(id, pev_velocity, vVelocity);
    
    vVelocity[2] = 0.0;
    
    return vector_length(vVelocity);
} 


[TSuNaMi_]

i did it but sounds coming to mix to players.

[TSuNaMi_]

oke thanks i will try now.