[Matheus28]

I still can't understand it, I tried to make this work, but I just can't.

How to copy the values from this keyvalues string to two arrays "mapsFile" and "mapsName"?

"maps"
{
	"cp_dustbowl"			"Dustbowl"
	"cp_gravelpit"			"Gravel Pit"
	"cp_steel"			"Steel"
	"pl_badwater"			"Badwater Basin"
	"pl_goldrush"			"Gold Rush"
	"pl_hoodoo_final"		"Hoodoo"
}

[FaTony]

KvGetSectionName for mapsFile and KvGetString for mapsName.

[Matheus28]

KvGetString requires a key.

[Silvers]

"cp_dustbowl" would be your key. http://wiki.alliedmods.net/KeyValues...d_Scripting%29

[Matheus28]

The problem is: I don't know the key because it will change based on what the user puts there.

Also, it needs to be keyvalues, because this is only a part of the file, the rest is working fine.

[FaTony]

Pass NULL_STRING to get current section value.

[Matheus28]

Doesn't work:

PHP Code:

if(!KvJumpToKey(kv, "maps")){
    ThrowError("List contains no maps");
}

new count=0;
do{
    new i=count++;
    KvGetString(kv, NULL_STRING, mapsName[i], sizeof(mapsName[]));
    KvGetSectionName(kv, mapsFile[i], sizeof(mapsFile[]));
}while(KvGotoNextKey(kv));

KvGoBack(kv); 


[Thrawn2]

PHP Code:

#pragma semicolon 1
#include <sourcemod>

#define MAX_ENTRIES 64

new String:g_sMapFile[MAX_ENTRIES][64];
new String:g_sMapName[MAX_ENTRIES][64];
new g_iCount;

public OnPluginStart() {
    ReadKV("mapnames.cfg");
}

public ReadKV(const String:sFile[]) {
    new String:sPath[PLATFORM_MAX_PATH];

    BuildPath(Path_SM, sPath, sizeof(sPath), "configs/%s", sFile);

    if(!FileExists(sPath)) {
        LogMessage("File does not exist");
        return;
    }

    new Handle:hKV = CreateKeyValues("maps");
    FileToKeyValues(hKV, sPath);

    g_iCount = 0;
    if(KvGotoFirstSubKey(hKV, false)) {
        do {
            new String:sKey[64];
            KvGetSectionName(hKV, sKey, sizeof(sKey));

            new String:sValue[64];
            KvGetString(hKV, NULL_STRING, sValue, sizeof(sValue));

            strcopy(g_sMapFile[g_iCount], 64, sKey);
            strcopy(g_sMapName[g_iCount], 64, sValue);
            LogMessage("%s is %s", g_sMapFile[g_iCount], g_sMapName[g_iCount]);
            g_iCount++;
        } while (KvGotoNextKey(hKV, false));
    } else {
        LogMessage("No map names specified");
    }

    return;
} 


-->

L 11/20/2010 - 20:47:46: [read_kv.smx] cp_dustbowl is Dustbowl
L 11/20/2010 - 20:47:46: [read_kv.smx] cp_gravelpit is Gravel Pit
L 11/20/2010 - 20:47:46: [read_kv.smx] cp_steel is Steel
L 11/20/2010 - 20:47:46: [read_kv.smx] pl_badwater is Badwater Basin
L 11/20/2010 - 20:47:46: [read_kv.smx] pl_goldrush is Gold Rush
L 11/20/2010 - 20:47:46: [read_kv.smx] pl_hoodoo_final is Hoodoo

[Matheus28]

It works! Thanks

[rhelgeby]

Just for future reference; this concept is called key/value iterating, which is used when you don't know the keys' names.