[Backstabnoob]

Hello.

I'd like to know how to detect when two players are killed by 1 grenade.
I'm not sure if deathmsg defines the killer properly when it's done by grenade, so:
1. Is the killer in DeathMsg index of player who actually killed someone with grenade? If so, is the grenade's string "hegren", as it is for all other weapons?
2. How do I detect if it was a double kill?

For the second point, I think the gametime for both the kills should be the same, but I'm not sure.

[Hunter-Digital]

Yes, killer is the player index and it's "hegren"... you could've just tested by debugging deathmsg

And yeah, game time + killer check should be ok, but they don't have to match exacly, you can allow at least 1 second for error because a player can't throw grenades faster than 1 second AFAIK.

[Backstabnoob]

In DeathMsg if(equali(weapon, "hegren")) works not.

Edit: The weapon name is actually "grenade"

[Hunter-Digital]

See, it took you 5 minutes to test it out (the additional minute to edit your post )

[Bugsy]

There may be a better way but this works. It will notify via client_print if more than 1 kill is made with the same grenade.

PHP Code:

#include <amxmodx>
#include <engine>
#include <hamsandwich>
#include <fakemeta>
#include <celltrie>

new const Version[] = "0.1";

new Trie:g_Trie;

public plugin_init() 
{
    register_plugin( "Multi Grenade Kill" , Version , "bugsy" );
    
    RegisterHam( Ham_TakeDamage , "player" , "fw_HamTakeDamage" , 1 );
    register_think( "grenade" , "fw_GrenadeThink" );

    g_Trie = TrieCreate();
}

public plugin_end()
{
    TrieDestroy( g_Trie );
}

public fw_GrenadeThink( iEntity ) 
{
    //This gets called 3 times when the condition ( get_gametime() > entity_get_float( iEntity, EV_FL_dmgtime ) is checked.
    //The third and last time always occurred at approx 0.650005 in my tests.
    if( !is_valid_ent( iEntity ) || ( ( get_gametime() - entity_get_float( iEntity, EV_FL_dmgtime ) ) < 0.64 ) )
        return;
    
    new szKey[ 4 ];
    num_to_str( iEntity , szKey , charsmax( szKey ) );
    
    if ( TrieKeyExists( g_Trie , szKey ) )
    {
        new iKills;
        TrieGetCell( g_Trie , szKey , iKills );
        
        if ( iKills > 1 )
        {
            new szOwner[ 9 ] , iKiller , szName[ 33 ]
            formatex( szOwner , charsmax( szOwner ) , "%s%s" , szKey , "OWNER" );
            TrieGetCell( g_Trie , szOwner , iKiller );
            
            get_user_name( iKiller , szName , charsmax( szName ) );
            client_print( 0 , print_chat , "* %s's grenade killed %d players!" , szName , iKills );
            
            TrieDeleteKey( g_Trie , szOwner );
        }
        
        TrieDeleteKey( g_Trie , szKey );
    }
}

public fw_HamTakeDamage( iVictim , iInflictor , iAttacker , Float:fDamage , iDamageBits )
{
    if ( iInflictor && ( iInflictor != iAttacker ) && !is_user_alive( iVictim ) && ( fm_cs_get_grenade_type( iInflictor ) == CSW_HEGRENADE ) )
    {
        new szKey[ 4 ] , szOwner[ 9 ] , iKillCount;
        num_to_str( iInflictor , szKey , charsmax( szKey ) );
        formatex( szOwner , charsmax( szOwner ) , "%sOWNER" , szKey );
        TrieGetCell( g_Trie , szKey , iKillCount );
        TrieSetCell( g_Trie , szKey , ++iKillCount );
        TrieSetCell( g_Trie , szOwner , iAttacker );
    }
}

fm_cs_get_grenade_type( index ) 
{
    if (!pev_valid(index))
        return 0
    
    new classname[9]
    pev(index, pev_classname, classname, 8)
    if (!equal(classname, "grenade"))
        return 0
    
    if (get_pdata_int(index, 96) & (1<<8))
        return CSW_C4
    
    new bits = get_pdata_int(index, 114)
    if (bits & (1<<0))
        return CSW_HEGRENADE
    else if (bits & (1<<1))
        return CSW_SMOKEGRENADE
    else if (!bits)
        return CSW_FLASHBANG
    
    return 0
} 


[Exolent[jNr]]

I prefer this method:

#include <amxmodx>
#include <csx>
#include <hamsandwich>

new g_grenadeKills[33]

public plugin_init() {
    RegisterHam(Ham_Think, "grenade", "FwdGrenadeThink")
}

public FwdGrenadeThink(ent) {
    if(!pev(ent, pev_bInDuck)) {
        new Float:dmgtime
        pev(ent, pev_dmgtime, dmgtime)
        
        if(dmgtime <= get_gametime()) {
            g_grenadeKills[pev(ent, pev_owner)] = 0
            set_pev(ent, pev_bInDuck, 1)
        }
    }
}

public client_death(victim, killer, weapon, hitPlace, teamKill) {
    if(weapon == CSW_HEGRENADE && ++g_grenadeKills[killer] > 1) {
        // more than 1 kill for nade
    }
}

The only difference with my method is that you can't properly check for more than 1 kill number without using tasks and more stuff.
But with bugsy's code, it's easy to check for more than 1 kill number.
(By more than 1 kill number, I mean checking for 2 or 3 kills)

[SpeeDeeR]

Is it the same with other weapons?

[Exolent[jNr]]

Originally Posted by SpeeDeeR Is it the same with other weapons?

No, that's for grenades only.

[SpeeDeeR]

Could you show me how can it be made with the other weapons.

[r14170]

deleted.