[bibu]

Instead of doing:

PHP Code:

if(get_pcvar_num(cvar)) 


I want todo something like this:

PHP Code:

if(user_wants(id)) 


And the player should be able to change his state with a say command, with a menu.

I don't have any idea about sql, and would really appreciate it if someone can show me a pretty good way.

[fysiks]

Why not use a global array then do if( user_wants[id] ) then update sql when the status changes (via the menu or whatever function).

[bibu]

Originally Posted by fysiks then update sql when the status changes

How I told, I don't have any idea for that.

[Exolent[jNr]]

PHP Code:

#include < amxmodx >
#include < sqlx >

enum _:Item
{
    Item_Specific
};

new const g_szItemSaveName[ Item ][ ] =
{
    "specific"
};

new Trie:g_tSaveNameToItem;

new g_bItems[ Item ];

new const SQL_HOST[ ] = "";
new const SQL_USER[ ] = "";
new const SQL_PASS[ ] = "";
new const SQL_DB[ ] = "";

new Handle:g_hSqlTuple;

//#define SetPlayerItem(%1,%2,%3) %3 ? (%1 |= (1<<(%2&31))) : (%1 &= ~(1<<(%2&31)))
stock SetPlayerItem(item, id, enabled) enabled ? (g_bItems[item] |= (1<<(id&31))) : (g_bItems[item] &= ~(1<<(id&31)));
//#define GetPlayerItem(%1,%2) %1 & (1<<(%2&31))
stock GetPlayerItem(item, id) return (g_bItems[item] & (1<<(id&31)));

public plugin_init( )
{
    g_tSaveNameToItem = TrieCreate( );
    
    InitSQL( );
}

InitSQL( )
{
    if( !( g_hSqlTuple = SQL_MakeDbTuple( SQL_HOST, SQL_USER, SQL_PASS, SQL_DB ) ) )
    {
        set_fail_state( "Could not make SQL tuple" );
    }
    
    new iError, szError[ 128 ];
    new Handle:hConnection = SQL_Connect( g_hSqlTuple, iError, szError, charsmax( szError ) );
    
    if( !hConnection )
    {
        set_fail_state( szError );
    }
    
    new szQuery[ 1024 ], iQueryLen;
    for( new i = 0; i < Item; i++ )
    {
        TrieSetCell( g_tSaveNameToItem, g_szItemSaveName[ i ], i );
        
        iQueryLen += formatex( szQuery[ iQueryLen ], charsmax( szQuery ) - iQueryLen, "%s%s INT NOT NULL DEFAULT 0", i ? ", " : "", g_szItemSaveName[ i ] );
    }
    
    new Handle:hQuery = SQL_PrepareQuery( hConnection, "CREATE TABLE IF NOT EXISTS items (steamid VARCHAR(35) NOT NULL, %s);", szQuery );
    
    if( !SQL_Execute( hQuery ) )
    {
        SQL_QueryError( hQuery, szError, charsmax( szError ) );
        log_amx( "Error creating table: %s", szError );
    }
    
    SQL_FreeHandle( hQuery );
    
    /* Check if any new items were added to the plugin after the table was already created */
    
    hQuery = SQL_PrepareQuery( hConnection, "SHOW COLUMNS FROM items;" );
    
    if( !SQL_Execute( hQuery ) )
    {
        SQL_QueryError( hQuery, szError, charsmax( szError ) );
        log_amx( "Error selecting columns: %s", szError );
    }
    else
    {
        new Trie:tColumns = TrieCreate( );
        
        new szColumn[ 64 ];
        
        while( SQL_MoreResults( hQuery ) )
        {
            SQL_ReadResult( hQuery, 0, szColumn, charsmax( szColumn ) );
            
            TrieSetCell( tColumns, szColumn, 1 );
            
            SQL_NextRow( hQuery );
        }
        
        iQueryLen = 0;
        
        new iNewItemIndex = 0;
        
        for( new i = 0; i < Item; i++ )
        {
            if( !TrieKeyExists( tColumns, g_szItemSaveName[ i ] ) )
            {
                iQueryLen += formatex( szQuery[ iQueryLen ], charsmax( szQuery ) - iQueryLen, "%sADD %s INT NOT NULL DEFAULT 0", ++iNewItemIndex > 1 ? ", " : "", g_szItemSaveName[ i ] );
            }
        }
        
        if( iNewItemIndex )
        {
            SQL_FreeHandle( hQuery );
            
            hQuery = SQL_PrepareQuery( hConnection, "ALTER TABLE items %s;", szQuery );
            
            if( !SQL_Execute( hQuery ) )
            {
                SQL_QueryError( hQuery, szError, charsmax( szError ) );
                log_amx( "Error adding new columns: %s", szError );
            }
        }
    }
    
    SQL_FreeHandle( hQuery );
    
    /* End of checking for new items */
    
    SQL_FreeHandle( hConnection );
}

public client_authorized( iPlayer )
{
    LoadItems( iPlayer );
}

LoadItems( iPlayer )
{
    new szSteamID[ 35 ];
    get_user_authid( iPlayer, szSteamID, charsmax( szSteamID ) );
    
    new szQuery[ 96 ];
    formatex( szQuery, charsmax( szQuery ), "SELECT * FROM items WHERE steamid = ^"%s^";", szSteamID );
    
    new iData[ 2 ];
    iData[ 0 ] = iPlayer;
    iData[ 1 ] = get_user_userid( iPlayer );
    
    SQL_ThreadQuery( g_hSqlTuple, "QueryLoadItems", szQuery, iData, sizeof( iData ) );
}

public QueryLoadItems( iFailState, Handle:hQuery, szError[ ], iError, iData[ ], iDataSize, Float:fQueueTime )
{
    if( iFailState == TQUERY_CONNECT_FAILED || iFailState == TQUERY_QUERY_FAILED )
    {
        log_amx( "%s", szError );
    }
    else
    {
        new iPlayer = iData[ 0 ];
        
        if( !is_user_connected( iPlayer ) || get_user_userid( iPlayer ) != iData[ 1 ] )
        {
            return;
        }
        
        new szColumn[ 64 ], iItem;
        
        for( new i = 0, iNumColumns = SQL_NumColumns( hQuery ); i < iNumColumns; i++ )
        {
            SQL_FieldNumToName( hQuery, i, szColumn, charsmax( szColumn ) );
            
            if( TrieGetCell( g_tSaveNameToItem, szColumn, iItem ) )
            {
                SetPlayerItem( iItem, iPlayer, SQL_ReadResult( hQuery, i ) );
            }
        }
    }
}

public MenuHandler( iPlayer, hMenu, iItem )
{
    if( /* item was picked */ )
    {
        ChangeStateForItem( iPlayer, Item_Specific );
    }
}

public CmdHandler( iPlayer )
{
    ChangeStateForItem( iPlayer, Item_Specific ):
}

ChangeStateForItem( iPlayer, iItem )
{
    new bEnabled = !GetPlayerItem( iItem, iPlayer );
    SetPlayerItem( iItem, iPlayer, bEnabled );
    
    new szSteamID[ 35 ];
    get_user_authid( iPlayer, szSteamID, charsmax( szSteamID ) );
    
    new szQuery[ 128 ];
    formatex( szQuery, charsmax( szQuery ), "REPLACE INTO items (steamid, %s) VALUES (^"%s^", %d);", g_szItemSaveName[ iItem ], szSteamID, bEnabled );
    
    SQL_ThreadQuery( g_hSqlTuple, "QueryIgnoreResults", szQuery );
}

public QueryIgnoreResults( iFailState, Handle:hQuery, szError[ ], iError, iData[ ], iDataSize, Float:fQueueTime )
{
    if( iFailState == TQUERY_CONNECT_FAILED || iFailState == TQUERY_QUERY_FAILED )
    {
        log_amx( "%s", szError );
    }
} 


[bibu]

And where's that part?

PHP Code:

// update SQL with bEnabled for this specific item 


[Exolent[jNr]]

Do you even know SQL?

[bibu]

Originally Posted by bibu I don't have any idea about sql....

[Exolent[jNr]]

Then why do you want to use SQL instead of something simpler like a vault?

[bibu]

Cause a friend wants it with SQL, that's why I need that. And is it hard todo or what?

[Exolent[jNr]]

Updated the code in my post.