[Gilbert Tux]

Bonjour a tous ,

J'ai un gros problème avec se plugin des que le temps du rounds est fini le serveur crash comment faire pour qu'il ne crash pu ?

PHP Code:

#define RESTART_NUMS 3

#include <amxmodx> 
#include <amxmisc> 

new sv_restart
new bool:g_bIsRoundRestarting, g_iRestartsNum

public plugin_init()
{ 
    register_plugin("Admin Restart", "1.0", "ConnorMcLeod") 
    register_clcmd("say /rs", "ClCmd_Say_Rs", ADMIN_LEVEL_A) 

    register_event("HLTV", "Event_HLTV_New_Round", "a", "1=0", "2=0")
    register_event("TextMsg", "Event_TextMsg_RestartRound", "a", "2&#Game_w")
    
    sv_restart = get_cvar_pointer("sv_restart")
}

public ClCmd_Say_Rs(id, lvl, cid)
{
    if( cmd_access(id, lvl, cid, 0) )
    {
        g_iRestartsNum = RESTART_NUMS
        client_print(0, print_chat, "%d RS !!", g_iRestartsNum)
        set_pcvar_num(sv_restart, 1)
        state Restarts
    }
}

public Event_TextMsg_RestartRound() <NoRestart> {}
public Event_TextMsg_RestartRound() <Restarts>
{
    g_bIsRoundRestarting = true
    if( !g_iRestartsNum )
    {
        state NoRestart
    }
}

public Event_HLTV_New_Round() <NoRestart> {}
public Event_HLTV_New_Round() <Restarts>
{
    if( g_bIsRoundRestarting )
    {
        g_bIsRoundRestarting = false
        switch( --g_iRestartsNum )
        {
            case 1:
            {
                set_pcvar_num(sv_restart, 3)
            }
            default:
            {
                set_pcvar_num(sv_restart, 1)
            }
        }
        client_print(0, print_chat, "%d RS !! ", g_iRestartsNum)
    }
} 


[Arkshine]

Je ne vois pas en quoi le plugin peut faire crasher le serveur, ça ne fait que balancer un sv_restart. Je dirais plus que tu as d'autres plugins qui après un sv_restart font crasher ton serveur. Sans plus d'informations sur le crash, ou les plugins utilisés, impossible d'aider.

[Kidev]

Euh Arkshine, tu peux m'expliquer les <> dans le plugin stp? Car je ne comprends pas tout la?

[Arkshine]

Automaton, voir le tutoriel dans la section des tutoriels.

Mais en gros, ça te permet de définir différents états pour une même fonction. Etats que tu définis avec 'state'. Bref, tu peux créer une sorte de circuit logique selon des conditions. Dans le code, selon l'état est sur Restarts/NoRestart, et quand l'event est appelé, ça va executer le code de la fonction avec l'état défini. Quand c'est sur NoRestart, aucun code sera executé vu que la fonction est vide. C'est une utilisation très basique de state, et en général tu ne risque pas vraiment d'en avoir besoin. Le changement est global au plugin. Ca peut, selon ce que fais le plugin, aider à simplifier le code et aussi éviter d'executer du code inutilement.

[Gilbert Tux]

Je c'est pas comment t'expliquer car jai enlever le plugin de mon serveur est mon serveur a arrêter de crach je t'expliquer :

le plugin rs est sur le serveur a chaque fois que le temp du round est terminer pas que une des équipe perd c'est quand il y a match nul .

[Arkshine]

Je n'ai pas compris ton explication, mais je le redis, ce plugin n'est qu'un déclencheur de redémarrage de round. Si bug il y a, c'est sûrement que d'autres plugins ne font pas leur boulot comme il devrait quand ça redémarre au moment t.

[Gilbert Tux]

c'est bizzard

[ConnorMcLeod]

Essaie quand même ça :

PHP Code:

#define RESTART_NUMS 3

#include <amxmodx> 
#include <amxmisc> 

new sv_restart
new bool:g_bIsRoundRestarting, g_iRestartsNum

public plugin_init()
{ 
    register_plugin("Admin Restart", "1.1", "ConnorMcLeod") 

    state NoRestart

    register_clcmd("say /rs", "ClCmd_Say_Rs", ADMIN_LEVEL_A) 
    register_event("HLTV", "Event_HLTV_New_Round", "a", "1=0", "2=0")
    register_event("TextMsg", "Event_TextMsg_RestartRound", "a", "2&#Game_w")

    sv_restart = get_cvar_pointer("sv_restart")
}

public ClCmd_Say_Rs(id, lvl, cid)
{
    if( cmd_access(id, lvl, cid, 0) )
    {
        g_iRestartsNum = RESTART_NUMS
        client_print(0, print_chat, "%d RS !!", g_iRestartsNum)
        set_pcvar_num(sv_restart, 1)
        state Restarts
    }
}

public Event_TextMsg_RestartRound() <NoRestart> {}
public Event_TextMsg_RestartRound() <Restarts>
{
    if( !g_iRestartsNum )
    {
        state NoRestart
    }
    else
    {
        g_bIsRoundRestarting = true
    }
}

public Event_HLTV_New_Round() <NoRestart> {}
public Event_HLTV_New_Round() <Restarts>
{
    if( g_bIsRoundRestarting )
    {
        g_bIsRoundRestarting = false
        switch( --g_iRestartsNum )
        {
            case 1:
            {
                set_pcvar_num(sv_restart, 3)
            }
            default:
            {
                set_pcvar_num(sv_restart, 1)
            }
        }
        client_print(0, print_chat, "%d RS !! ", g_iRestartsNum)
    }
} 


[Gilbert Tux]

Sa marche merci connor

[Kidev]

Originally Posted by Arkshine Automaton, voir le tutoriel dans la section des tutoriels. Mais en gros, ça te permet de définir différents états pour une même fonction. Etats que tu définis avec 'state'. Bref, tu peux créer une sorte de circuit logique selon des conditions. Dans le code, selon l'état est sur Restarts/NoRestart, et quand l'event est appelé, ça va executer le code de la fonction avec l'état défini. Quand c'est sur NoRestart, aucun code sera executé vu que la fonction est vide. C'est une utilisation très basique de state, et en général tu ne risque pas vraiment d'en avoir besoin. Le changement est global au plugin. Ca peut, selon ce que fais le plugin, aider à simplifier le code et aussi éviter d'executer du code inutilement.

Merci