[Flimbo]

I found a plugin called "instantautoassign" it automatically assigns someone to a team as soon as they enter the server but I would love for it to also put them in a class too.

https://forums.alliedmods.net/showthread.php?t=213521 I found it here but I have no clue how to code for this

[Bacardi]

I forgot:
Use cvar = mp_forceautoteam 1

PHP Code:




#include <sdktools>


public void OnPluginStart()
{
    HookEvent("player_activate", player_activate);
    HookEvent("player_team", player_team);
}


public void player_activate(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(event.GetInt("userid"));

    // Bots, SourceTV, Replay
    if(IsFakeClient(client))
        return;

    if(GetTeamClientCount(2) <= GetTeamClientCount(3)) {
        ChangeClientTeam(client, 2);
    } else {
        ChangeClientTeam(client, 3);
    }
}


public void player_team(Event event, const char[] name, bool dontBroadcast)
{
/*
Server event "player_team", Tick 6012:
- "userid" = "3"
- "team" = "3"
- "oldteam" = "0"
- "disconnect" = "0"
- "autoteam" = "1"
- "silent" = "0"
- "name" = "'Bacardi"
*/
    static ConVar mp_forceautoteam;

    if(mp_forceautoteam == null)
    {
        mp_forceautoteam = FindConVar("mp_forceautoteam");
    }

    if(mp_forceautoteam == null || !mp_forceautoteam.BoolValue || event.GetBool("disconnect") || event.GetInt("oldteam") != 0)
        return;

    int client = GetClientOfUserId(event.GetInt("userid"));
    ClientCommand(client, "joinclass random");

} 


[Kuumi]

@Bacardi do you mind compiling it and making it a smx for me please? I'd really appreciate it.

[Bacardi]

...I could,
but maybe it is better you to learn, how it is maded.
And I don't want to be a as whole, you could try to search (even with google) how you compile SourceMod plugin.



It is very easy.

[Kuumi]

Compileing spits this error at me

instantautoassign.sp(16) : error 076: syntax error in the expression, or invalid function call

[Bacardi]

updated, forget add client in IsFakeClient

*edit
Use cvar mp_forceautoteam 1

[Kuumi]

The compile worked thanks a ton!