[deadmau54]

I can't seem to find a plugin that allows players to set their jump height, I've seen 'set speed' one but there is no 'set jump height' plugin.

If anyone could do it, it would be greatly appretiated.

Thanks in advance.

[Potato Uno]

Use the TF2Items give weapon plugin (the advanced one by a SM approver, not by FlamingSarge) and assign the jump height bonus attribute to the weapon?

I'm on mobile so I can't find the URL to the plugin or the attribute ID for jump height bonus. However, does that sound like an appropriate solution? (You may want to write a small wrapper plugin for it.)

[Arkarr]

Command : sm_setjumpheight
CODE:

PHP Code:

#include <sourcemod>
#include <morecolors>
#include <tf2attributes>

new Float:JumpMultiplier[MAXPLAYERS+1] = 1.0;


public Plugin:myinfo =
{
    name        =    "Set jump height",
    author        =    "Arkarr",
    description    =    "Set the jump height on a player",
    version        =    "1.0",
    url            =    "http://www.sourcemod.net"
};

public OnPluginStart()
{
    RegAdminCmd("sm_setjumpheight", CMD_SetJumpHeight, ADMFLAG_CHEATS);
    HookEvent("player_spawn", PlayerSpawn);
}

public Action:CMD_SetJumpHeight(client, args)
{
    if(args != 2)
    {
        CPrintToChat(client, "{green}[Jump Height]{default} Usage : sm_setjumpheight <target> <multiplier>");
        return Plugin_Handled;
    }
    
    decl String:arg1[50], String:arg2[20];
    GetCmdArg(1, arg1, sizeof(arg1));
    GetCmdArg(2, arg2, sizeof(arg2));
    new String:target_name[MAX_TARGET_LENGTH];
    new target_list[MAXPLAYERS], target_count;
    new bool:tn_is_ml;
    if ((target_count = ProcessTargetString(
            arg1,
            client,
            target_list,
            MAXPLAYERS,
            COMMAND_FILTER_NO_BOTS,
            target_name,
            sizeof(target_name),
            tn_is_ml)) <= 0)
    {
        ReplyToTargetError(client, target_count);
        return Plugin_Handled;
    }
    
    for (new i = 0; i < target_count; i++)
    {
        JumpMultiplier[target_list[i]] = StringToFloat(arg2);
        TF2Attrib_SetByName(target_list[i], "increased jump height", JumpMultiplier[target_list[i]]);
    }
    
    return Plugin_Handled;
}

public Action:PlayerSpawn(Handle:event, const String:name[], bool:dontBroadcast){
    
    new client = GetClientOfUserId(GetEventInt(event, "userid"));
    
    if(IsValidClient(client) && JumpMultiplier[client] != 1.0)
        TF2Attrib_SetByName(client, "increased jump height", JumpMultiplier[client]);
    
    return Plugin_Continue;
}

stock bool:IsValidClient(client)
{
    if(client <= 0 ) return false;
    if(client > MaxClients) return false;
    if(!IsClientConnected(client)) return false;
    return IsClientInGame(client);
} 


NOTE: I set the attribute on the player instend of the weapon. 'cause I have no limit.

[zyox123cc]

Originally Posted by Potato Uno Use the TF2Items give weapon plugin (the advanced one by a SM approver, not by FlamingSarge) and assign the jump height bonus attribute to the weapon? I'm on mobile so I can't find the URL to the plugin or the attribute ID for jump height bonus. However, does that sound like an appropriate solution? (You may want to write a small wrapper plugin for it.)

sm_setjumpheight @bots 1000000 wtf i do

[Arkarr]

Originally Posted by zyox123cc sm_setjumpheight @bots 1000000 wtf i do

That necro bump haha

[BraveFox]

Originally Posted by Arkarr Command : sm_setjumpheight NOTE: I set the attribute on the player instend of the weapon. 'cause I have no limit.

Use the new style.

PHP Code:

include <sourcemod> 
#include <morecolors> 
#include <tf2attributes> 

int float JumpMultiplier[MAXPLAYERS+1] = 1.0; 


public Plugin:myinfo = 
{ 
    name        =    "Set jump height", 
    author        =    "Arkarr", 
    description    =    "Set the jump height on a player", 
    version        =    "1.0", 
    url            =    "http://www.sourcemod.net" 
}; 

public OnPluginStart() 
{ 
    RegAdminCmd("sm_setjumpheight", CMD_SetJumpHeight, ADMFLAG_CHEATS); 
    HookEvent("player_spawn", PlayerSpawn); 
} 

public Action CMD_SetJumpHeight(client, args) 
{ 
    if(args != 2) 
    { 
        CPrintToChat(client, "{green}[Jump Height]{default} Usage : sm_setjumpheight <target> <multiplier>"); 
        return Plugin_Handled; 
    } 
     
    char arg1[50], char arg2[20]; 
    GetCmdArg(1, arg1, sizeof(arg1)); 
    GetCmdArg(2, arg2, sizeof(arg2)); 
    char target_name[MAX_TARGET_LENGTH]; 
    int target_list[MAXPLAYERS], target_count; 
    bool tn_is_ml; 
    if ((target_count = ProcessTargetString( 
            arg1, 
            client, 
            target_list, 
            MAXPLAYERS, 
            COMMAND_FILTER_NO_BOTS, 
            target_name, 
            sizeof(target_name), 
            tn_is_ml)) <= 0) 
    { 
        ReplyToTargetError(client, target_count); 
        return Plugin_Handled; 
    } 
     
    for (int i = 0; i < target_count; i++) 
    { 
        JumpMultiplier[target_list[i]] = StringToFloat(arg2); 
        TF2Attrib_SetByName(target_list[i], "increased jump height", JumpMultiplier[target_list[i]]); 
    } 
     
    return Plugin_Handled; 
} 

public Action PlayerSpawn(Handle event, char name[64], bool dontBroadcast){ 
     
    new client = GetClientOfUserId(GetEventInt(event, "userid")); 
     
    if(IsValidClient(client) && JumpMultiplier[client] != 1.0) 
        TF2Attrib_SetByName(client, "increased jump height", JumpMultiplier[client]); 
     
    return Plugin_Continue; 
} 

stock bool IsValidClient(client) 
{ 
    if(client <= 0 ) return false; 
    if(client > MaxClients) return false; 
    if(!IsClientConnected(client)) return false; 
    return IsClientInGame(client); 
} 


[Arkarr]

Originally Posted by BraveFox Use the new style. [...]

Dude, it was the 3 January 2015. No new style at this date.

[shanapu]

Originally Posted by BraveFox PHP Code: int float JumpMultiplier[MAXPLAYERS+1] = 1.0;

int float?

Originally Posted by BraveFox Use the new style. PHP Code: public Action CMD_SetJumpHeight(client, args)

This and some other parts are not Transitional Syntax. https://wiki.alliedmods.net/SourcePa...itional_Syntax

try with this

PHP Code:

#pragma newdecls required