[loadrino]

Hello everyone, i need a plugin for kick every people who connect on server with an exception of some steamids, i was wondering if could uses the reservation slot plugin with lower flags.
ps: i've tried to search before but i didnt found any good keywords to search something like this.

[secondtimesold]

why not just use a password on server?

[Toastbrot_290]

Try it with the keyword whitelist. There are plugins like that one that you would like to have.

[loadrino]

Originally Posted by secondtimesold why not just use a password on server?

because i just manage the servers, and it up to 100 ppl at same time, everytime someone else just tell the password for some friend who arent to be there, so i need to spend time to connect to server and check out the "whitelist" steamids and if needed kick him, something with an auto kick will be perfect.

Originally Posted by Toastbrot_290 Try it with the keyword whitelist. There are plugins like that one that you would like to have.

i've tried this one, it's pretty usualy word on most of topics, sure probably that one exist on forum but so deep :/

[Arkarr]

I made that for you, make sure to create a new config file called 'ServerWhiteList.txt' in your config folder. He should contains STEAMIDs of allowed user (In any format you want, this mean 2,3 and 64 format !).

EDIT:
Oh and you can use sm_reloadwhitelist to reload the whitelist.

EDIT #2:
Updated to match with Asherkin advices.

PHP Code:

#include <sourcemod>

Handle ListSteamID = INVALID_HANDLE;
char listKey[55];

public Plugin:myinfo =
{
    name        = "Server locker",
    author      = "Arkarr",
    description = "An alternative to make your servers private",
    version     = "0.1",
    url         = "http://www.sourcemod.net"
};

public void OnPluginStart()
{
    
    RegAdminCmd("sm_reloadwhitelist", CMD_ReloadWhiteList, ADMFLAG_ROOT, "Reload the white list.");
    
    ListSteamID = CreateTrie();
    ReadConfigFile();
    
    PrintToServer("*** SERVER IS IN PRIVATE MODE ! ***");
}

public void OnClientAuthorized(client)
{
     char steamID[50];
     char clientSteamID2[50];
     char clientSteamID3[50];
     char clientSteamID64[50];
     GetClientAuthId(client, AuthId_Steam2, clientSteamID2, sizeof(clientSteamID2));
     GetClientAuthId(client, AuthId_Steam3, clientSteamID3, sizeof(clientSteamID3));
     GetClientAuthId(client, AuthId_SteamID64, clientSteamID64, sizeof(clientSteamID64));
     
     for(int i = 0; i < GetArraySize(ListSteamID); i++)
     {
        Format(listKey, sizeof(listKey), "SteamID#%i", i);
         GetTrieString(ListSteamID, listKey, steamID, sizeof(steamID));
         if(StrEqual(steamID, clientSteamID2) || StrEqual(steamID, clientSteamID3) || StrEqual(steamID, clientSteamID64) )
        {
            KickClient(client, "You are not allowed to join this server !");
        }
     }
}

public Action CMD_ReloadWhiteList(client, args)
{
    PrintToServer("*** RELOADING THE SERVER WHITLIST ***");
    
    ReadConfigFile();
    
    PrintToServer("*** DONE ! ***");
    
    return Plugin_Handled;
}

public void ReadConfigFile()
{
    int index;
    ClearTrie(ListSteamID);
    decl String:path[PLATFORM_MAX_PATH],String:line[128];
    BuildPath(Path_SM,path,PLATFORM_MAX_PATH,"config/ServerWhiteList.txt");
    new Handle:fileHandle=OpenFile(path,"r");
    while(ReadFileLine(fileHandle,line,sizeof(line)))
    {
        Format(listKey, sizeof(listKey), "SteamID#%i", index);
        SetTrieString(ListSteamID, listKey, line, false);
        index++;
    }
    CloseHandle(fileHandle);
} 


[asherkin]

1. You can't get a client's steamid before OnClientAuthorized.
2. Use StringMap, your implementation there will get slower as more steamids are added.
3. You can just use ReadFileLine, it returns false on EOF.
4. Your CMD_ReloadWhiteList function is missing a return statement.

[Arkarr]

Originally Posted by asherkin You can't get a client's steamid before OnClientAuthorized. Use StringMap, your implementation there will get slower as more steamids are added. You can just use ReadFileLine, it returns false on EOF. Your CMD_ReloadWhiteList function is missing a return statement.

Right right right, so much erros I should have take more time to do that.

EDIT:
Mind to check if it's better now ?

[asherkin]

Originally Posted by Arkarr Mind to check if it's better now ?

That's just using the StringMap as an array - store the config file lines as the map keys (you probably also want to call TrimString first).

[Arkarr]

Originally Posted by asherkin That's just using the StringMap as an array - store the config file lines as the map keys (you probably also want to call TrimString first).

I don't understand this. I should store the steamIDs into a keyvalue file ? Something like that ?

[asherkin]

Originally Posted by Arkarr I don't understand this. I should store the steamIDs into a keyvalue file ? Something like that ?

Not tested, but something like this:

PHP Code:

#pragma semicolon 1
#pragma newdecls required

StringMap whitelist;

public void OnPluginStart()
{
    whitelist = new StringMap();
    
    RegAdminCmd("sm_reloadwhitelist", OnReloadWhitelist, ADMFLAG_GENERIC, "Reload the whitelist.");
    
    OnReloadWhitelist(0, 0);
}

public Action OnReloadWhitelist(int client, int args)
{
    char path[PLATFORM_MAX_PATH];
    BuildPath(Path_SM, path, sizeof(path), "configs/server_whitelist.txt");
    
    File whitelistFile = OpenFile(path, "r");
    if (!whitelistFile) {
        ReplyToCommand(client, "Failed to open whitelist file. (%s)", path);
        
        return Plugin_Handled;
    }
    
    whitelist.Clear();
    
    int count;
    char line[64];
    while (whitelistFile.ReadLine(line, sizeof(line))) {
        TrimString(line);
        
        if (line[0] == '\0' || line[0] == '#') {
            continue;
        }
        
        whitelist.SetValue(line, true);
        
        count++;
    }
    
    delete whitelistFile;
    
    ReplyToCommand(client, "Reloaded whitelist with %d entries.", count);
    
    return Plugin_Handled;
}

public void OnClientAuthorized(int client, const char[] auth)
{
    char steamid[64];
    int unused;
    
    if (GetClientAuthId(client, AuthId_Steam2, steamid, sizeof(steamid)) && whitelist.GetValue(steamid, unused)) {
        return;
    }
    
    if (GetClientAuthId(client, AuthId_Steam3, steamid, sizeof(steamid)) && whitelist.GetValue(steamid, unused)) {
        return;
    }
    
    if (GetClientAuthId(client, AuthId_SteamID64, steamid, sizeof(steamid)) && whitelist.GetValue(steamid, unused)) {
        return;
    }
    
    KickClient(client, "Not on whitelist.");
}