[MightyMalcolm]

Hey guys,

the headline says it all. I want to read the server.cfg file and find out what values are stored there (e.g. sv_password blalba). How to?

[Steell]

This is pretty basic, but:

//Finds the value of a given cvar in the given cfg file. Returns true on success, false on failure.
//    fileName: the path to the cfg file
//    cvar: the name of the cvar we're looking for
//    buffer: string we're storing the value in
//    buffersize: maximum length of the result string
bool:FindConVarInCfg(const String:fileName[], const String:cvar[], String:buffer[], buffersize)
{
    //Try to open the cfg file.
    new Handle:file = OpenFile(fileName, "rt");
    if (file == INVALID_HANDLE)
        return false;

    new bool:result = false;

    //Setup the regex we'll use to find the cvar
    decl String:pattern[256];
    Format(pattern, sizeof(pattern), "^\\s*%s\\s+(\"[^\"]*\"|\\S+)\\s*(?://.*)?$", cvar);
    new Handle:reCvar = CompileRegex(pattern);

    //Search each line of the cfg file for the cvar
    decl String:line[256];
    while (!IsEndOfFile(file) && ReadFileLine(file, line, sizeof(line)))
    {
        //if we find the correct cvar...
        if (MatchRegex(reCvar, line) != -1)
        {
            //Store the value.
            GetRegexSubString(reCvar, 1, buffer, buffersize);
            result = true;
        }
    }
    
    //Strip any quotes from the stored value.
    if (result)
    {
        StripQuotes(buffer);
    }
    
    //And we're done here.
    CloseHandle(file);
    CloseHandle(reCvar);
    return result;
}

And so in your plugin, if you had this function, you would:

decl String:password[256];
FindConVarInCfg("cfg/server.cfg", "sv_password", password, sizeof(password));

[MightyMalcolm]

Thx Steell, but my compiler is crying out loud:

SourcePawn Compiler 1.3.6 Copyright (c) 1997-2006, ITB CompuPhase, (C)2004-2008 AlliedModders, LLC F:\Dokumente\Dark Messiah\Server\sourcemod-1.3.6-windows\addons\sourcemod\scripting\mm_test.sp (47) : error 017: undefined symbol "CompileRegex" F:\Dokumente\Dark Messiah\Server\sourcemod-1.3.6-windows\addons\sourcemod\scripting\mm_test.sp (47) : warning 213: tag mismatch F:\Dokumente\Dark Messiah\Server\sourcemod-1.3.6-windows\addons\sourcemod\scripting\mm_test.sp (52) : error 001: expected token: ")", but found "{" F:\Dokumente\Dark Messiah\Server\sourcemod-1.3.6-windows\addons\sourcemod\scripting\mm_test.sp (54) : error 017: undefined symbol "MatchRegex" F:\Dokumente\Dark Messiah\Server\sourcemod-1.3.6-windows\addons\sourcemod\scripting\mm_test.sp (57) : error 017: undefined symbol "GetRegexSubString" F:\Dokumente\Dark Messiah\Server\sourcemod-1.3.6-windows\addons\sourcemod\scripting\mm_test.sp (35) : warning 203: symbol is never used: "buffersize" 4 Errors. Compilation Time: 0,42 sec

Any includes i need to add? (sry me nub :<)

[Steell]

#include <regex>

[MightyMalcolm]

thx, works, love you guys ;)

[Despirator]

result = GetRegexSubString(reCvar, 1, buffer, buffersize);