[Liverwiz]

So i have this mod that makes your screen move around (Brass Knuckles by Cheap_Suit if you remember it) and i rewrote a bit of it. In my version i use Ham_TakeDamage isntead of stock registered "Damage" but when i use the Ham functions, it doesn't work. Any ideas as to why this is? Does Ham just not work properly with Engine? Is there another way to do it so i can still use Ham?

My ham function: commented out as debugging

PHP Code:

ublic event_hamDamage(victimID, i_weapon, attackerID, Float:flDamage, iDmgBits)
{
    new bool:alive = ( is_user_alive(victimID) || is_user_alive(attackerID) )
    new bool:connected = ( is_user_connected(victimID) || is_user_connected(attackerID) )
    if(!alive || !connected)
        return HAM_HANDLED
        
    if(i_weapon != CSW_KNIFE || !g_bknuckles[attackerID])
        return HAM_HANDLED
        
    
    //new Float:Random_Float[3]    // Punch View Vector
    
    if(get_pcvar_num(frags_pcvar) == 0)
    {
        //for(new i = 0; i < 3; i++) 
        //    Random_Float[i] = random_float(100.0, 150.0)
    }
    else 
    {
        new aLevel = getLevel(attackerID) // level of attacker
        switch(aLevel)
        {
        //case 0:    // Low knock
        //{
        //    for(new i = 0; i < 3; i++)     // sets the Punch View vector
        //        Random_Float[i] = random_float(25.0, 75.0)
        //}
        case 4:
        {
        //    for(new i = 0; i < 3; i++) 
        //        Random_Float[i] = random_float(100.0, 150.0)
                
        //    SetHamParamFloat(4, flDamage + get_pcvar_num(strength_pcvar))
        }
        // case 5: will have powers enabled
    #if defined INSTAKILL
        case INSTAKILL:
        {
            SetHamParamFloat(4, 110.0)
            client_cmd(attackerID, INSTAKILL_SOUND)
            client_cmd(victimID, INSTAKILL_SOUND)
        }
    #endif
        default:// normal power 
        {
        //    if(aLevel > 4)
        //        SetHamParamFloat(4, flDamage + 7)
        //    for(new i = 0; i < 3; i++) 
        //        Random_Float[i] = random_float(100.0, 150.0)
        }
        } 
    }
    new Float:Random_Float[3]
    for(new i = 0; i < 3; i++)
        Random_Float[i] = random_float(100.0, 150.0)
    Punch_View(victimID, Random_Float)

    return HAM_HANDLED
} 


And here is the working code:

Spoiler

PHP Code:

 public Event_Damage(id)
{
    if(!is_user_alive(id) || !is_user_connected(id)) 
        return PLUGIN_CONTINUE
        
    new AttakerWeapon, AttakerPartHit
    new Attacker = get_user_attacker(id, AttakerWeapon, AttakerPartHit)
    
    if(AttakerWeapon != CSW_KNIFE)
        return PLUGIN_CONTINUE
    
    if(!g_bknuckles[Attacker])
        return PLUGIN_CONTINUE
    
    new Float:Random_Float[3]
    for(new i = 0; i < 3; i++) 
        Random_Float[i] = random_float(100.0, 150.0)
    Punch_View(id, Random_Float)

    return PLUGIN_CONTINUE
} 


stock Punch_View(id, Float:ViewAngle[3])
{
	entity_set_vector(id, EV_VEC_punchangle, ViewAngle)
}

any ideas why this work but the ham_damage doesn't?
I want to use Ham so i can set the damage done to the victim, but even that won't work. If anyone can answer that too i'd be much appricaiative.

[Exolent[jNr]]

Your code in the handler is just wrong, and that variable is not the weapon ID, even though the documentation says so.

#include <amxmodx>
#include <hamsandwich>

new gMaxPlayers;

public plugin_init() {
    RegisterHam(Ham_TakeDamage, "player", "FwdTakeDamagePlayerPost", 1);
    
    gMaxPlayers = get_maxplayers();
}

public FwdTakeDamagePlayerPost(victim, inflictor, attacker, Float:damage, damageBits) {
    if(inflictor == attacker
    && (1 <= attacker <= gMaxPlayers)
    && attacker != victim
    && g_bknuckles[attacker]
    && is_user_alive(victim)
    && get_user_weapon(attacker) == CSW_KNIFE) {
         // attacker hit victim with brass knuckles and victim is still alive
    }
}

[Liverwiz]

Originally Posted by Exolent[jNr] Your code in the handler is just wrong, and that variable is not the weapon ID, even though the documentation says so. #include <amxmodx> #include <hamsandwich> new gMaxPlayers; public plugin_init() {     RegisterHam(Ham_TakeDamage, "player", "FwdTakeDamagePlayerPost", 1);         gMaxPlayers = get_maxplayers(); } public FwdTakeDamagePlayerPost(victim, inflictor, attacker, Float:damage, damageBits) {     if(inflictor == attacker     && (1 <= attacker <= gMaxPlayers)     && attacker != victim     && g_bknuckles[attacker]     && is_user_alive(victim)     && get_user_weapon(attacker) == CSW_KNIFE) {          // attacker hit victim with brass knuckles and victim is still alive     } }

what the hell is the inflictor, then?

-testing your code now-

EDIT: and what about grenade damage that is delt while the attacker has a knife out?

[ConnorMcLeod]

When a weapon is involved, inflictor is equal to attacker, when it is another entity, such as a grenade, then inflictor is the nade entity index.
Also, if you plain to change params, hook the function before it actually happen.

[Liverwiz]

Originally Posted by ConnorMcLeod When a weapon is involved, inflictor is equal to attacker, when it is another entity, such as a grenade, then inflictor is the nade entity index. Also, if you plain to change params, hook the function before it actually happen.

that explains all my above questions. Thank you.
and i do have it hooked as post=0
I did get that much from the documentation.