[IloveMusic]

Hello every1 I want to block some heroes in my dota2 server mod, are there any suggestions how to implement it?

I'm creating Zombie Swarm mode, the Dire is Zombie team and the Radiant have to survive or even find the cure from zombie virus.
And I need to block all "undead" heroes such as Pudge, Wraith King and etc FOR RADIANT TEAM and block survivors ( all non-undead heroes ) for DIRE team.
Help me please.

[psychonic]

PHP Code:

#include <sourcemod>

StringMap g_AllowedHeroesRadiant;
StringMap g_AllowedHeroesDire;

enum DotaTeam
{
    DotaTeam_Unassigned,
    DotaTeam_Spectator,
    DotaTeam_Radiant,
    DotaTeam_Dire,
}

public void OnPluginStart()
{
    AddCommandListener(dota_select_hero, "dota_select_hero");
    
    g_AllowedHeroesDire = StringMap();
    g_AllowedHeroesDire.SetValue("npc_dota_hero_pudge", 1);
    g_AllowedHeroesDire.SetValue("npc_dota_hero_skeleton_king", 1);
    
    g_AllowedHeroesRadiant = StringMap();
    g_AllowedHeroesRadiant.SetValue("npc_dota_hero_puck", 1);
    
    // etc.
}

public Action dota_select_hero(int client, const char[] szCommand, int argc)
{
    if (argc > 1 && client != 0 && IsClientInGame(client))
    {
        DotaTeam team = view_as<DotaTeam>(GetClientTeam(client));
        char szHero[64];
        int dummy;
        
        GetCmdArg(1, szHero, sizeof(szHero));

        if (team == DotaTeam_Radiant)
        {
            if (!g_AllowedHeroesRadiant.GetValue(szHero, dummy))
                return Plugin_Handled;
        }
        else if (team == DotaTeam_Dire)
        {
            if (!g_AllowedHeroesDire.GetValue(szHero, dummy))
                return Plugin_Handled;
        }
    }
    
    return Plugin_Continue;
} 


Something like this should work, although you're better off putting them in a config file and reading from there, rather than hardcoding in the plugin.

[Mathias.]

nicely done psychonic

[wanted2411]

Same question, but with Items. How can i Disable part of items? (Shop items, like a 'Gem' or other...)

[psychonic]

I'm not sure how to do that without replacing some of the game's script files or some crazy hacks in a custom SM extension.

[Mathias.]

Is there a place that we can download the lastest updated binaries for linux?

[Cuban_Dota]

Originally Posted by psychonic PHP Code: #include <sourcemod> StringMap g_AllowedHeroesRadiant; StringMap g_AllowedHeroesDire; enum DotaTeam {     DotaTeam_Unassigned,     DotaTeam_Spectator,     DotaTeam_Radiant,     DotaTeam_Dire, } public void OnPluginStart() {     AddCommandListener(dota_select_hero, "dota_select_hero");          g_AllowedHeroesDire = StringMap();     g_AllowedHeroesDire.SetValue("npc_dota_hero_pudge", 1);     g_AllowedHeroesDire.SetValue("npc_dota_hero_skeleton_king", 1);          g_AllowedHeroesRadiant = StringMap();     g_AllowedHeroesRadiant.SetValue("npc_dota_hero_puck", 1);          // etc. } public Action dota_select_hero(int client, const char[] szCommand, int argc) {     if (argc > 1 && client != 0 && IsClientInGame(client))     {         DotaTeam team = view_as<DotaTeam>(GetClientTeam(client));         char szHero[64];         int dummy;                  GetCmdArg(1, szHero, sizeof(szHero));         if (team == DotaTeam_Radiant)         {             if (!g_AllowedHeroesRadiant.GetValue(szHero, dummy))                 return Plugin_Handled;         }         else if (team == DotaTeam_Dire)         {             if (!g_AllowedHeroesDire.GetValue(szHero, dummy))                 return Plugin_Handled;         }     }          return Plugin_Continue; }  Something like this should work, although you're better off putting them in a config file and reading from there, rather than hardcoding in the plugin.

Dude you really help a lot of people, you should get a medal or something, LOL

[psychonic]

Originally Posted by Black-Rabbit Is there a place that we can download the lastest updated binaries for linux?

Binaries of what?

[Mathias.]

server binary, I don't have dota 2 host on linux. I was just wondering if there were a place that offer up to date binaries on the web for supported game in case that people like me don't have a linux setup or vise versa.

[psychonic]

Originally Posted by Black-Rabbit server binary, I don't have dota 2 host on linux. I was just wondering if there were a place that offer up to date binaries on the web for supported game in case that people like me don't have a linux setup or vise versa.

SteamCMD.