[Unkolix]

I want a script that would make VIP have a random model (Bender1, 2,3 or 4)
But I only know how to change the model:

PHP Code:

public resetModel(id, level, cid) 
{
    if (get_user_flags(id) & ADMIN_LEVEL_H) 
    {
        cs_set_user_model(id, "Random")
    }
    return PLUGIN_CONTINUE
} 


And I want to know how to change knife model, pistol model, hands model and sleeves models.

[Bos93]

use Ham_Spawn,for change player model and Ham_Deploy - weapon models

[Unkolix]

Ok, thanks but how to make it be random between these models: Bender1,Bender2,Bender3,Bender4?

[Bos93]

PHP Code:

switch( random_num( 1 , 4 ) )
{
     case 1: cs_set_user_model(id, "bender1")
     case 2: cs_set_user_model(id, "bender2")
     case 3: cs_set_user_model(id, "bender3")
     case 4: cs_set_user_model(id, "bender4")
} 


[Unkolix]

Do I have to precashe all those models? BTW it doesn't work for me.

[Bos93]

precache - yes

show code

[.Dare Devil.]

PHP Code:

new bender[8], r = random_num( 1, 4 )
format( bender, charsmax(bender), "bender%d", r )
cs_set_user_model(id, bender) 


[Unkolix]

Code I use:

PHP Code:

new const g_ModelNames[][] =
{
    "Bender1", "Bender2", "Bender3", "Bender4"
}
...
public plugin_precache()
{
    precache_model("models/player/DeathRunVip/Bender1.mdl")
    precache_model("models/player/DeathRunVip/Bender2.mdl")
    precache_model("models/player/DeathRunVip/Bender3.mdl")
    precache_model("models/player/DeathRunVip/Bender4.mdl")
}
...
public plugin_init()
{
        ...
        register_event("ResetHUD", "resetModel", "b")
        ...
}
...
public resetModel(id, level, cid) 
{
    if (get_user_flags(id) & ADMIN_LEVEL_H) 
    {
        cs_set_user_model( id, g_ModelNames[ random( sizeof( g_ModelNames ) ) ] )
    }
    return PLUGIN_CONTINUE
} 


[guipatinador]

PHP Code:

precache_model("models/player/DeathRunVip/Bender1.mdl") 


You can't do that. The path should be models/player/ABC/ABC.mdl (ABC is just an example).

Use this,

PHP Code:

#include < amxmodx >
#include < cstrike >
#include < hamsandwich >

static PLUGIN[ ] = "New Plug-In"
static VERSION[ ] = "1.0.0"
static AUTHOR[ ] = "author"

#define VIP_FLAG ADMIN_LEVEL_H

new bool:is_vip[ 33 ]

new const g_ModelNames[ ][ ] = {
    "Bender1",
    "Bender2",
    "Bender3",
    "Bender4"
}

public plugin_precache( )
{
    new szModelPath[ 128 ]
    new i
    for( i = 0; i < sizeof g_ModelNames; i++ )
    {
        formatex( szModelPath, charsmax( szModelPath ), "models/player/%s/%s.mdl", g_ModelNames[ i ] )
        precache_model( szModelPath )
    }
}

public plugin_init( )
{
    register_plugin( PLUGIN, VERSION, AUTHOR )
    
    RegisterHam( Ham_Spawn, "player", "FwdPlayerSpawnPost", 1 )
}

public client_authorized( id )
{
    if( get_user_flags( id ) & VIP_FLAG )
        is_vip[ id ] = true
    
    else
        is_vip[ id ] = false
}

public FwdPlayerSpawnPost( id )
{
    if( is_user_alive( id ) && is_vip[ id ] )
    {
        new iNum = random( sizeof g_ModelNames )
        cs_set_user_model( id, g_ModelNames[ iNum ] )
    }
} 


[fysiks]

To make your code easier to modify, I suggest you use a loop when precaching using your g_ModelNames array. This way, when you add or remove a model, the only thing you have to do is change this one array.