[SM9]

Hi everyone, im trying to remove the team join messages, but don't seem to be having any luck.
I want to avoid setting broadcast false inside a join team hook because this has some undesirable effects in CSGO such as breaking defuse kits for CT.

Here's my current code, although it does not seem to do anything..

PHP Code:

#include <sourcemod>

public Plugin myinfo = 
{
    name = "Remove Team Join Messages", 
    author = "SM9", 
};

public void OnPluginStart()
{
    HookUserMessage(GetUserMessageId("TextMsg"), MsgHook_Messages, true);
}

public Action MsgHook_Messages(UserMsg msg_id, Handle msg, const players[], playersNum, bool reliable, bool init)
{
    decl String:buffer[64];
    PbReadString(msg, "params", buffer, sizeof(buffer), 0);
    
    if (StrEqual(buffer, "#Cstrike_TitlesTXT_Game_join_ct"))
    {
        return Plugin_Handled;
    }
    
    if (StrEqual(buffer, "#Cstrike_TitlesTXT_Game_join_ct_auto"))
    {
        return Plugin_Handled;
    }
    
    if (StrEqual(buffer, "#Cstrike_TitlesTXT_Game_join_terrorist"))
    {
        return Plugin_Handled;
    }
    
    if (StrEqual(buffer, "#Cstrike_TitlesTXT_Game_join_terrorist_auto"))
    {
        return Plugin_Handled;
    }
    
    if (StrEqual(buffer, "#Cstrike_game_join_spectators"))
    {
        return Plugin_Handled;
    }
    
    if (StrEqual(buffer, "#Cstrike_game_join_terrorist"))
    {
        return Plugin_Handled;
    }
    
    if (StrEqual(buffer, "#Cstrike_game_join_ct"))
    {
        return Plugin_Handled;
    }
    
    return Plugin_Continue;
} 


Thanks.

[Darkness_]

Are you talking about the message: Player X is joining the Terrorist Force?

Edit: Nevermind, the method I used is the one you want to avoid using.

[Dr. Api]

PHP Code:

/***********************************************************/
/********************** PLAYER CONNECT *********************/
/***********************************************************/
public Action PlayerConnect(Handle event, const char[] name, bool dontBroadcast)
{
    if(B_active_zombie_riot)
    {
        if(!dontBroadcast)
        {
            char S_name[32], networkID[22], address[26];
            GetEventString(event, "name", S_name, sizeof(S_name)-1);
            GetEventString(event, "networkid", networkID, sizeof(networkID)-1);
            GetEventString(event, "address", address, sizeof(address)-1);
            
            Handle new_event = CreateEvent("player_connect", true);
            SetEventString(new_event, "name", S_name);
            SetEventInt(new_event, "index", GetEventInt(event, "index"));
            SetEventInt(new_event, "userid", GetEventInt(event, "userid"));
            SetEventString(new_event, "networkid", networkID);
            SetEventString(new_event, "address", address);
            
            FireEvent(new_event, true);
            
            return Plugin_Handled;
        }
    }
    return Plugin_Continue;
}

/***********************************************************/
/********************* PLAYER DISCONNECT *******************/
/***********************************************************/
public Action PlayerDisconnect(Handle event, const char[] name, bool dontBroadcast)
{
    if(B_active_zombie_riot)
    {
        if(!dontBroadcast)
        {
            char S_name[32], networkID[22], address[26];
            GetEventString(event, "name", S_name, sizeof(S_name)-1);
            GetEventString(event, "networkid", networkID, sizeof(networkID)-1);
            GetEventString(event, "address", address, sizeof(address)-1);
            
            Handle new_event = CreateEvent("player_disconnect", true);
            SetEventString(new_event, "name", S_name);
            SetEventInt(new_event, "index", GetEventInt(event, "index"));
            SetEventInt(new_event, "userid", GetEventInt(event, "userid"));
            SetEventString(new_event, "networkid", networkID);
            SetEventString(new_event, "address", address);
            
            FireEvent(new_event, true);
            
            return Plugin_Handled;
        }
    }
    return Plugin_Continue;
} 


[SM9]

Thanks for your reply Dr Api, although im wanting to block the team messages and not the connect ones.

[Dr. Api]

Originally Posted by xCoderx Thanks for your reply Dr Api, although im wanting to block the team messages and not the connect ones.

You can do exactly the same for team join.

[Dr. Api]

PHP Code:

/***********************************************************/
/*********************** PLAYER TEAM PRE********************/
/***********************************************************/
public Action PlayerTeam_Pre(Handle event, const char[] name, bool dontBroadcast)
{
    if(B_active_zombie_riot)
    {
        
        if(!dontBroadcast)
        {
            Handle new_event = CreateEvent("player_team", true);
            
            SetEventInt(new_event, "userid", GetEventInt(event, "userid"));
            SetEventInt(new_event, "team", GetEventInt(event, "team"));
            SetEventInt(new_event, "oldteam", GetEventInt(event, "oldteam"));
            SetEventBool(new_event, "disconnect", GetEventBool(event, "disconnect"));
            
            FireEvent(new_event, true);
            
            return Plugin_Handled;
        }
    }
    return Plugin_Continue;
} 


[Powerlord]

Have you tried logging what data you're getting from TextMsg to see what might be going on?

[SM9]

Originally Posted by Dr. Api PHP Code: /***********************************************************/ /*********************** PLAYER TEAM PRE********************/ /***********************************************************/ public Action PlayerTeam_Pre(Handle event, const char[] name, bool dontBroadcast) {     if(B_active_zombie_riot)     {                  if(!dontBroadcast)         {             Handle new_event = CreateEvent("player_team", true);                          SetEventInt(new_event, "userid", GetEventInt(event, "userid"));             SetEventInt(new_event, "team", GetEventInt(event, "team"));             SetEventInt(new_event, "oldteam", GetEventInt(event, "oldteam"));             SetEventBool(new_event, "disconnect", GetEventBool(event, "disconnect"));                          FireEvent(new_event, true);                          return Plugin_Handled;         }     }     return Plugin_Continue; }

That worked thanks

['-_-'<3zok<3'-_-']

Hey, need some help with this code.. Tried fixing it but I have no idea of what I'm missing.

//// hideteamchange.sp // // C:\steamcmd\csgo\csgo\addons\sourcemod\script ing\hideteamchange.sp(11) : erro r 130: cannot coerce functions to values // C:\steamcmd\csgo\csgo\addons\sourcemod\script ing\hideteamchange.sp(29) : warn ing 217: loose indentation // // 1 Error. // // Compilation Time: 0,08 sec // ---------------------------------------- Press enter to exit ...

PHP Code:

#include <sourcemod>

public Plugin myinfo = 
{
    name = "Remove Team Join Messages", 
    author = "SM9", 
};

public void OnPluginStart()
{
    GetFunctionByName(PlayerTeam_Pre);
}

public Action PlayerTeam_Pre(Handle event, const char[] name, bool dontBroadcast) 
{ 
        if(!dontBroadcast) 
        { 
            Handle new_event = CreateEvent("player_team", true); 
             
            SetEventInt(new_event, "userid", GetEventInt(event, "userid")); 
            SetEventInt(new_event, "team", GetEventInt(event, "team")); 
            SetEventInt(new_event, "oldteam", GetEventInt(event, "oldteam")); 
            SetEventBool(new_event, "disconnect", GetEventBool(event, "disconnect")); 
             
            FireEvent(new_event, true); 
             
            return Plugin_Handled; 
        } 
    return Plugin_Continue; 
}