[H.RED.ZONE]

[TUT] How to create VIP Zombie Class for ZP 5.0
(This is a tutorial on how to make VIP zombie class.)

Spoiler

NOTE: You need to have RZ VIP Plugin installed on your server.

I will be showing how to do this inside default zombie plague classes,
every other zombie class that is for zombie plague 5.0 can be set to be VIP
class.

1. Adding the include file
Open default zombie class "zp50_class_zombie_classic.sma" inside find INCLUDE files.
in this class it will be like this. (Always on the top of the plugin)

#include <amxmodx>
#include <zp50_class_zombie>

Add "#include <rz_vip_core>" so it will look like this.

#include <amxmodx>
#include <zp50_class_zombie>
#include <rz_vip_core>

2. Adding Forward
Next step is to add forward to are code that is called when determining whether a class should be available to a player.

You can search for this line "public zp_fw_class_zombie_select_pre" in this case this class does not have one so lets set it up like this.

Add

public zp_fw_class_zombie_select_pre(id, classid) {

}

3. Getting Zombie class ID
Next we add check if its this class we want to set to.
We need to find ID of the class we go to find "zp_class_zombie_register" on the left side we will find it for this zombie class it looks like this "g_ZombieClassID = zp_class_zombie_register"

4. Setting Zombie ID Check
Now that we have ID we need to check if this is the zombie class we want this zombie to be VIP Class.

public zp_fw_class_zombie_select_pre(id, classid){
    if( classid == g_ZombieClassID ) {

        return ZP_CLASS_NOT_AVAILABLE // Return class unavailable
    }
    return ZP_CLASS_AVAILABLE // Return class available
}

So now we have a code that tells us we will set other classes to normal
"ZP_CLASS_AVAILABLE" but only this class "ZP_CLASS_NOT_AVAILABLE"


5. VIP Only
Now that no one can use it we can set inside that only VIP players can use it. Like this:

public zp_fw_class_zombie_select_pre(id, classid){
    if( classid == g_ZombieClassID ) {
        
        if(rz_is_user_vip(id)) {
            return ZP_CLASS_AVAILABLE
        }
        return ZP_CLASS_NOT_AVAILABLE
    }
    return ZP_CLASS_AVAILABLE
}

6. Add Text [tag]
Now this will be the whole code but lets add something else to it so it looks nice..
a tag [VIP] after class description.

public zp_fw_class_zombie_select_pre(id, classid){
    if( classid == g_ZombieClassID ) {
        
        static text[32]
        formatex (text , charsmax ( text ) , "[VIP]")
        zp_class_zombie_menu_text_add( text )
        
        if(rz_is_user_vip(id)) {
            return ZP_CLASS_AVAILABLE
        }
        return ZP_CLASS_NOT_AVAILABLE
    }
    return ZP_CLASS_AVAILABLE
}

7. Full Code
Now that this is done this is how the whole code should look like

/*================================================================================
    
    -----------------------------------
    -*- [ZP] Class: Zombie: Classic -*-
    -----------------------------------
    
    This plugin is part of Zombie Plague Mod and is distributed under the
    terms of the GNU General Public License. Check ZP_ReadMe.txt for details.
    
================================================================================*/

#include <amxmodx>
#include <zp50_class_zombie>
#include <rz_vip_core>

// Classic Zombie Attributes
new const zombieclass1_name[] = "Classic Zombie"
new const zombieclass1_info[] = "=Balanced="
new const zombieclass1_models[][] = { "zombie_source" }
new const zombieclass1_clawmodels[][] = { "models/zombie_plague/v_knife_zombie.mdl" }
const zombieclass1_health = 1800
const Float:zombieclass1_speed = 0.75
const Float:zombieclass1_gravity = 1.0
const Float:zombieclass1_knockback = 1.0

new g_ZombieClassID

public plugin_precache()
{
    register_plugin("[ZP] Class: Zombie: Classic", ZP_VERSION_STRING, "ZP Dev Team")
    
    new index
    
    g_ZombieClassID = zp_class_zombie_register(zombieclass1_name, zombieclass1_info, zombieclass1_health, zombieclass1_speed, zombieclass1_gravity)
    zp_class_zombie_register_kb(g_ZombieClassID, zombieclass1_knockback)
    for (index = 0; index < sizeof zombieclass1_models; index++)
        zp_class_zombie_register_model(g_ZombieClassID, zombieclass1_models[index])
    for (index = 0; index < sizeof zombieclass1_clawmodels; index++)
        zp_class_zombie_register_claw(g_ZombieClassID, zombieclass1_clawmodels[index])
}

public zp_fw_class_zombie_select_pre(id, classid){
    if( classid == g_ZombieClassID ) {
        
        static text[32]
        formatex (text , charsmax ( text ) , "[VIP]")
        zp_class_zombie_menu_text_add( text )
        
        if(rz_is_user_vip(id)) {
            return ZP_CLASS_AVAILABLE
        }
        return ZP_CLASS_NOT_AVAILABLE
    }
    return ZP_CLASS_AVAILABLE
}

In case you don't know how to create ZP VIP Class post in this thread and i will help you.

[TUT] How to create VIP Extra Item for ZP 5.0
(You will be able to make any zp5.0 item for VIP.)

Spoiler

NOTE: You need to have RZ VIP Plugin installed on your server.

I will be showing how to do this inside my Gas Mask plugin extra item,
every other extra item that is for zombie plague 5.0 can be set to be VIP
extra item.

1. Adding the include file
First we open "zp50_gas_mask.sma" inside we can find INCLUDE files.
We need to add RZ VIP plugin include so we find this:

#include < amxmodx >
#include < hamsandwich >
#include < engine >

#include <zp50_core>
#include <zp50_items>
#include <zp50_ammopacks>

And now we add our RZ VIP include

#include < amxmodx >
#include < hamsandwich >
#include < engine >

#include <zp50_core>
#include <zp50_items>
#include <zp50_ammopacks>
#include <rz_vip_core>

2. Forward For Extra Items
Every extra item has forward that checks who can buy item you can find it easy it looks like this:

public zp_fw_items_select_pre

NOTE: There is "pre" and there is "post" DON'T MAKE MISTAKE! We are looking for "pre".

Now inside we will find check if this is the item that we are using it checks if ID of item is really "Gas Mask item" To help you look at it here is the code:

if (itemid == g_itemid_buyremoverh) {

"g_itemid_buyremoverh" This is diffrent for every item because Item ID is diffrent.

Inside of this check we will add our line that is needed:

public zp_fw_items_select_pre(id, itemid) {
    if (itemid == g_itemid_buyremoverh) {
        if (zp_core_is_zombie(id))
            return ZP_ITEM_DONT_SHOW;
        
        // This is what we add.
        if(!rz_is_user_vip(id)) 
            return ZP_ITEM_NOT_AVAILABLE;

        
        static text[32]
        formatex ( text , charsmax ( text ) , "[%d/%d]" , g_Limit , get_pcvar_num ( _pcvar_limit ) )
        zp_items_menu_text_add ( text )
    
        if ( g_Limit >= get_pcvar_num ( _pcvar_limit ) )
            return ZP_ITEM_NOT_AVAILABLE;
        
        return ZP_ITEM_AVAILABLE;
    }
    return ZP_ITEM_AVAILABLE;
}

This will be hard because every code is diffrent so you need to be able to read this forward to know what to do. I will tell you that there is a problem with ITEM AVAILABLE and NOT AVAILABLE so in the line i added i checked if user is not (!) VIP that item is NOT AVAILABLE


3. You Need To Know
You need to know what to set in case that ID check ends with return ZP_ITEM_AVAILABLE
Like this here:

public zp_fw_items_select_pre(id, itemid) {
    if (itemid == g_itemid_buyremoverh) {
        if (zp_core_is_zombie(id))
            return ZP_ITEM_DONT_SHOW;
        
        // This is what we add.
        if(!rz_is_user_vip(id)) 
            return ZP_ITEM_NOT_AVAILABLE;

        
        static text[32]
        formatex ( text , charsmax ( text ) , "[%d/%d]" , g_Limit , get_pcvar_num ( _pcvar_limit ) )
        zp_items_menu_text_add ( text )
    
        if ( g_Limit >= get_pcvar_num ( _pcvar_limit ) )
            return ZP_ITEM_NOT_AVAILABLE;
        
        return ZP_ITEM_AVAILABLE;
    }
    return ZP_ITEM_AVAILABLE;
}

we add it like this:

        // This is what we add.
        if(!rz_is_user_vip(id)) 
            return ZP_ITEM_NOT_AVAILABLE;

in case that it ends like this:

public zp_fw_items_select_pre(id, itemid) {
    if (itemid == g_itemid_buyremoverh) {
        if (!zp_core_is_zombie(id))
            return ZP_ITEM_DONT_SHOW;
        
        // This is what we add.
        if(rz_is_user_vip(id)) 
            return ZP_ITEM_AVAILABLE;

        
        static text[32]
        formatex ( text , charsmax ( text ) , "[%d/%d]" , g_Limit , get_pcvar_num ( _pcvar_limit ) )
        zp_items_menu_text_add ( text )
    
        if ( g_Limit >= get_pcvar_num ( _pcvar_limit ) )
            return ZP_ITEM_NOT_AVAILABLE;
        
        return ZP_ITEM_NOT_AVAILABLE;
    }
    return ZP_ITEM_AVAILABLE;
}

We add it like this:

        // This is what we add.
        if(rz_is_user_vip(id)) 
            return ZP_ITEM_AVAILABLE;

4. Add VIP [TAG]
To add a tag [VIP] you just need to add this line here:

        static text2[32]
        formatex ( text2 , charsmax ( text2 ) , "[VIP]" )
        zp_items_menu_text_add ( text2 )

So in the end the forward looks like this:

public zp_fw_items_select_pre(id, itemid) {
    if (itemid == g_itemid_buyremoverh) {
        if (zp_core_is_zombie(id))
            return ZP_ITEM_DONT_SHOW;
        
        // This is what we add.
        if(!rz_is_user_vip(id)) 
            return ZP_ITEM_NOT_AVAILABLE;

        
        static text[32]
        formatex ( text , charsmax ( text ) , "[%d/%d]" , g_Limit , get_pcvar_num ( _pcvar_limit ) )
        zp_items_menu_text_add ( text )
    
        static text2[32]
        formatex ( text2 , charsmax ( text2 ) , "[VIP]" )
        zp_items_menu_text_add ( text2 )
    
        if ( g_Limit >= get_pcvar_num ( _pcvar_limit ) )
            return ZP_ITEM_NOT_AVAILABLE;
        
        return ZP_ITEM_AVAILABLE;
    }
    return ZP_ITEM_AVAILABLE;
}

That is the end compile locally. Sma is inside this thread.