[Napoleon_be]

Okay, now i see. Just a simple question, are you learning to code or do u just want the code to be remade?

EDIT: Here's something i made in a rush, it's not tested.

PHP Code:

#include <amxmodx>
#include <fun>
#include <cstrike>
#include <hamsandwich>
#include <cromchat>

#pragma semicolon 1

#define ADMIN_VIP             ADMIN_LEVEL_B
#define CS_TEAM_FURIEN        CS_TEAM_CT

new const g_szVersion[] = "0.1";

enum g_eWeaponInfo 
{
    g_szWeaponName[16],
    g_szModelPathV[128],
    g_iWeaponId,
    g_iWeaponAmmo
};

new g_lWeaponInfo[][g_eWeaponInfo] =
{
    { "weapon_m4a1", "models/vipmenu/v_gold_m4a1.mdl", CSW_M4A1, 254 },
    { "weapon_ak47", "models/vipmenu/v_gold_ak47.mdl", CSW_AK47, 254 },
    { "weapon_xm1014", "models/vipmenu/v_gold_xm1014.mdl", CSW_XM1014, 254 },
    { "weapon_deagle", "models/vipmenu/v_gold_deagle.mdl", CSW_DEAGLE, 254 }
};

new bool:g_bGotWeapon[MAX_PLAYERS + 1];

new g_szPrefix[MAX_PLAYERS + 1];

new g_pPrefix;

public plugin_init() 
{
    register_plugin("Vip Menu For Anti-Furiens", g_szVersion, "NapoleoN#");

    register_clcmd("say /vmenu", "ShowMenu");
    register_clcmd("say_team /vmenu", "ShowMenu");

    RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage");

    register_event("CurWeapon", "CurrentWeapon", "be", "1=1");

    g_pPrefix = register_cvar("vm_prefix", "[^4ANTI-FURIEN^1]");
    get_pcvar_string(g_pPrefix, g_szPrefix, charsmax(g_szPrefix)); // Change map to complete the changes.

}

public plugin_precache()
{
    for(new iModel; iModel < sizeof(g_lWeaponInfo[]); iModel++)
    {
        precache_model(g_lWeaponInfo[iModel][g_szModelPathV]);
    }
}

public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, iDmgBits)
{
    if(!is_user_connected(iAttacker) || iAttacker != iInflictor || !g_bGotWeapon[iAttacker])
    {
        return HAM_IGNORED;
    }

    new iWeapon = cs_get_user_weapon(iAttacker);


    if(iWeapon == g_lWeaponInfo[3][g_iWeaponId])
    {
        SetHamParamFloat(4, fDamage * 1.5);
    }

    else 
    {
        SetHamParamFloat(4, fDamage * 1.4);
    }
    return HAM_HANDLED;
}

public CurrentWeapon(id)
{
    if(!is_user_alive(id))
    {
        return PLUGIN_CONTINUE;
    }

    new iWeapon = cs_get_user_weapon(id);

    for(new i; i < sizeof(g_lWeaponInfo[]); i++)
    {
        if(iWeapon == g_lWeaponInfo[i][g_iWeaponId])
        {
            set_pev(id, pev_viewmodel2, g_lWeaponInfo[i][g_szModelPathV]);
            break;
        }
    }
    return PLUGIN_CONTINUE;
}

public ShowMenu(id)
{
    if(is_user_alive(id))
    {
        if(get_user_flags(id) & ADMIN_VIP)
        {
            if(cs_get_user_team(id) == CS_TEAM_FURIEN) 
            {
                new vMenu = menu_create("\w[\yFURIEN.NPOWERED.RO\w] \rVIP Menu \yANTI-FURIEN", "MenuHandler");
            
                menu_additem(vMenu, "\rM4A1 \w+ \rDeagle \y[GOLD]");
                menu_additem(vMenu, "\rAK47 \w+ \rDeagle \y[GOLD]");
                menu_additem(vMenu, "\rXM1014 \w+ \rDeagle \y[GOLD]");

                menu_display(id, vMenu);
            }

            else
            {
                ColorChat(id, NORMAL, "%s^3 Only^1 Furien players", g_szPrefix);
                return PLUGIN_HANDLED;
            }
        }

        else 
        {
            ColorChat(id, NORMAL, "%s^3 Only^1 V.I.P. Members", g_szPrefix);
            return PLUGIN_HANDLED;
        }
    }

    else
    {
        ColorChat(id, NORMAL, "%s^3 Only^1 alive players.", g_szPrefix);
        return PLUGIN_HANDLED;
    }
    return PLUGIN_HANDLED;
}

public MenuHandler(id, vMenu, iItem)
{
    if(is_user_alive(id) && cs_get_user_team(id) == CS_TEAM_FURIEN && iItem != MENU_EXIT)
    {
        strip_user_weapons(id);
        give_item(id, g_lWeaponInfo[iItem][g_szWeaponName]);
        give_item(id, "weapon_knife");
        cs_set_user_bpammo(id, g_lWeaponInfo[iItem][g_iWeaponId], g_lWeaponInfo[iItem][g_iWeaponAmmo]);
        g_bGotWeapon[id] = true;
    }

    menu_destroy(vMenu);
    return PLUGIN_HANDLED;
}