[SchlumPF*]

just had a quick look on this, this is what i found

-use Ham_Use for the timer + check the map for multiple start/stop buttons

PHP Code:

// unneccesarry

stock kz_float_to_float(Float:desde[3], Float:hasta[3])
{
    hasta[0] = desde[0]
    hasta[1] = desde[1]
    hasta[2] = desde[2]
}

// can be easily done in amxx 1.8 through this which will copy dimension by dimension
hasta = desde 


PHP Code:

// by connorr

stock fm_set_user_team(id, {CsTeams,_}:team, {CS_Internal_Models,_}:model = CS_DONTCHANGE)
{
    switch(team)
    {
        case CS_TEAM_T: set_pdata_int(id, 114, 1, OFFSET_LINUX);
        case CS_TEAM_CT: set_pdata_int(id, 114, 2, OFFSET_LINUX);
        case CS_TEAM_SPECTATOR: set_pdata_int(id, 114, 3, OFFSET_LINUX);
    }

    if(model)
    {
        switch(model)
        {
            case CS_CT_URBAN:set_pdata_int(id, 126, 1, OFFSET_LINUX);
            case CS_T_TERROR:set_pdata_int(id, 126, 2, OFFSET_LINUX);
            case CS_T_LEET:set_pdata_int(id, 126, 3, OFFSET_LINUX);
            case CS_T_ARCTIC:set_pdata_int(id, 126, 4, OFFSET_LINUX);
            case CS_CT_GSG9:set_pdata_int(id, 126, 5, OFFSET_LINUX);
            case CS_CT_GIGN:set_pdata_int(id, 126, 6, OFFSET_LINUX);
            case CS_CT_SAS:set_pdata_int(id, 126, 7, OFFSET_LINUX);
            case CS_T_GUERILLA:set_pdata_int(id, 126, 8, OFFSET_LINUX);
            case CS_CT_VIP:set_pdata_int(id, 126, 9, OFFSET_LINUX);
            case CZ_T_MILITIA:set_pdata_int(id, 126, 10, OFFSET_LINUX);
            case CZ_CT_SPETSNAZ:set_pdata_int(id, 126, 11, OFFSET_LINUX);
        }
    }

    dllfunc(DLLFunc_ClientUserInfoChanged, id);

    new teaminfo[32];
    switch(team)
    {
        case TEAM_UNASSIGNED: copy(teaminfo, 31, "UNASSIGNED")
        case TEAM_T: copy(teaminfo, 31, "TERRORIST")
        case TEAM_CT: copy(teaminfo, 31, "CT")
        case TEAM_SPECTATOR: copy(teaminfo, 31, "SPECTATOR")
        
    }
    
    message_begin(MSG_ALL, g_teaminfo);
    write_byte(id);
    write_string(teaminfo);
    message_end();

}

// ->

fm_cs_set_user_team( plr, { CsTeams, _ }:team, { CsInternalModel, _ }:model = CsInternalModel:CS_DONTCHANGE )
{
    /*if( team > CS_TEAM_SPECTATOR )
    {
        return 0;
    }*/
    
    set_pdata_int( plr, OFFSET_TEAM, _:team );

    if( model )
    {
        set_pdata_int( plr, OFFSET_INTERNALMODEL, _:model );
    }

    dllfunc( DLLFunc_ClientUserInfoChanged, plr, engfunc( EngFunc_GetInfoKeyBuffer, plr ) );

    static const teams[] = { "UNASSIGNED", "TERRORIST", "CT", "SPECTATOR" };

    emessage_begin( MSG_BROADCAST, g_iMessageTeamInfo );
    ewrite_byte( plr );
    ewrite_string( teams[_:team] );
    emessage_end( );
    
    return 1;
} 


PHP Code:

global_get(glb_time, engine_time);

//rather use this since global_get() runs a lot more c++ code than get_gametime():
get_gametime()