[asherkin]

0.8.0 has been released.

Changelog:

• Added Steam_SetGameDescription native to replace the broken (and now-removed) SDKHooks functionality.
• Added HTTP interface.

The HTTP interface is currently undocumented, but here is an example of the common functionality:

PHP Code:

#pragma semicolon 1

#include <sourcemod>
#include <steamtools>

new HTTPRequestHandle:g_HTTPRequest = INVALID_HTTP_HANDLE;

public Steam_FullyLoaded()
{
    g_HTTPRequest = Steam_CreateHTTPRequest(HTTPMethod_GET, "http://dl.dropbox.com/u/6938670/avatar.png");
    Steam_SendHTTPRequest(g_HTTPRequest, OnDownloadComplete);
}

public OnGameFrame()
{
    static Float:lastPctDone = 0.0;
    
    if (g_HTTPRequest == INVALID_HTTP_HANDLE)
    {
        lastPctDone = 0.0;
        return;
    }
    
    new Float:pctDone = Steam_GetHTTPDownloadProgressPercent(g_HTTPRequest);
    
    if (pctDone <= lastPctDone)
        return;
    
    PrintToServer("[SM] Download progress: %.2f%%", pctDone);
    
    lastPctDone = pctDone;
}

public OnDownloadComplete(HTTPRequestHandle:HTTPRequest, bool:requestSuccessful, HTTPStatusCode:statusCode)
{
    if (HTTPRequest != g_HTTPRequest || !requestSuccessful || statusCode != HTTPStatusCode_OK)
        return;
    
    Steam_WriteHTTPResponseBody(g_HTTPRequest, "avatar.png");
    
    Steam_ReleaseHTTPRequest(g_HTTPRequest);
    g_HTTPRequest = INVALID_HTTP_HANDLE;
}