[Bacardi]

well, can you see difference (sv_showimpacts) between server and client from log file, with this plugin example ?

PHP Code:

ConVar sv_showimpacts;

public void OnPluginStart()
{
    sv_showimpacts = FindConVar("sv_showimpacts");
    
    if(sv_showimpacts == null) SetFailState("Can't find cvar sv_showimpacts");
}


public void OnClientPutInServer(int client)
{
    if(IsFakeClient(client))
        return;

    CreateTimer(10.0, delay, GetClientUserId(client), TIMER_FLAG_NO_MAPCHANGE);
}

public Action delay(Handle timer, any data)
{
    int client = GetClientOfUserId(data);

    if(client == 0 || !IsClientInGame(client))
        return Plugin_Continue;




    QueryCookie cookie = QueryClientConVar(client, "sv_showimpacts", queryfinished, sv_showimpacts.IntValue);

    if(cookie == QUERYCOOKIE_FAILED)
    {
        LogAction(-1, -1, "%L QUERYCOOKIE_FAILED sv_showimpacts", client);
    }

    return Plugin_Continue;
}

public void queryfinished(QueryCookie cookie, int client, ConVarQueryResult result, const char[] cvarName, const char[] cvarValue, any value)
{
    if(result == ConVarQuery_Okay)
    {
        LogAction(-1, -1, "%L, %s: server=%i, client=%s", client, cvarName, value, cvarValue);
    }
    else
    {
        LogAction(-1, -1, "%L, Failed %s: ConVarQueryResult %i", client, cvarName, result);
    }
}