[fezh]

Descripción:
Traza el punto donde el movimiento de alguna entidad terminará. Si por alguna razón el movimiento de la entidad es bloqueada por otra (o por worldspawn), TraceToss detectará la situación.

Uso:

engfunc(EngFunc_TraceToss, ent, skipent, tr);

Parámetros:
ent = La entidad cuyo movimiento queremos trazar.
skipent = La entidad que omitiremos en el trazo.
tr = Resultado (trace result).

Post original: http://forums.alliedmods.net/showpos...&postcount=138

Grenade Prediction:
Es un plugin simple que hace que cuando un jugador tira una granada se cree un efecto de chispas donde se sabe que va a golpear.

Video

La idea original es de joaquimandrade.

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

const m_bIsC4 = 96;

public plugin_init( )
{
    register_plugin( "Grenade Prediction", "1.0.1", "DruX" );
    
    RegisterHam( Ham_Think, "grenade", "Ham_Think_Pre", 0 );
}

public Ham_Think_Pre( iEnt )
{
    if ( get_pdata_int( iEnt, m_bIsC4, 5 ) & ( 1<<8 ) )
    {
        return HAM_IGNORED;
    }
    
    static iTrace; iTrace = create_tr2( );
    
    static Float:fOrigin[ 3 ];
    
    engfunc( EngFunc_TraceToss, iEnt, IGNORE_MONSTERS, iTrace );
    
    get_tr2( iTrace, TR_vecEndPos, fOrigin );
    
    engfunc( EngFunc_MessageBegin, MSG_BROADCAST, SVC_TEMPENTITY, fOrigin, 0 );
    write_byte( TE_SPARKS );
    engfunc( EngFunc_WriteCoord, fOrigin[ 0 ] );
    engfunc( EngFunc_WriteCoord, fOrigin[ 1 ] );
    engfunc( EngFunc_WriteCoord, fOrigin[ 2 ] );
    message_end( );
    
    free_tr2( iTrace );
    
    return HAM_IGNORED;
}