[Kailo]

Originally Posted by DeagLe.Studio I tested with EmitSoundToClientAny and it didnt work :/

Tested in CS:GO. Working well.

PHP Code:

// © Maxim "Kailo" Telezhenko, 2017

#pragma semicolon 1
#pragma newdecls required

#include <emitsoundany>

stock const char g_sound[] = "ui/csgo_ui_crate_open.wav";

public void OnPluginStart()
{
    RegConsoleCmd("sm_emit", Cmd_Emit);
}

public void OnMapStart()
{
    PrecacheSoundAny(g_sound);
}

// Usage: sm_emit <0|1|2|3>
public Action Cmd_Emit(int client, int args)
{
    if (!args)
        return Plugin_Handled;

    char arg[4];
    GetCmdArg(1, arg, sizeof(arg));
    switch (StringToInt(arg)) {
        case 0:
            EmitSoundToClientAny(client, g_sound);
        case 1:
            EmitSoundToAllAny(g_sound);
        case 2: {
            float origin[3];
            GetClientAbsOrigin(client, origin);
            EmitAmbientSoundAny(g_sound, origin);
        }
        case 3:
            StopSoundAny(client, SNDCHAN_AUTO, g_sound);
    }

    return Plugin_Handled;
}