[D3nyo]

Hi, can someone translate this from Turkish in English? Only those chat messages i need. Thanks

#pragma semicolon 1

#include <amxmodx>
#include <reapi>

#define PLUGIN_NAME		"No Scope & Quick Scope Detector"
#define PLUGIN_VERS		"1.1"
#define PLUGIN_AUTH		"PurposeLess,Suriyelikene"

native bmParaCektir(iN_ID);
native bmParaDuzenle(iN_ID,iN_Value);

new Float:ScopeData[MAX_CLIENTS + 1];

enum _: cvar_name
{
	NOSCOPE,
	QUICKSCOPE
};
new g_cvar[cvar_name];

public plugin_init() {
	register_plugin(PLUGIN_NAME, AMXX_VERSION_STR, PLUGIN_AUTH);

	register_event("SetFOV", "@event_SetFOV", "be", "1<90");

	RegisterHookChain(RG_CBasePlayer_Killed, "@CBasePlayer_Killed", .post=false);

	bind_pcvar_num(create_cvar("nqs_no_scope", "10", _, _, true, 0.0, true, 16000.0), g_cvar[NOSCOPE]);
	bind_pcvar_num(create_cvar("nqs_quick_scope", "7", _, _, true, 0.0, true, 16000.0), g_cvar[QUICKSCOPE]);
}

@event_SetFOV(const id)
{
	ScopeData[id] = get_gametime();
}

@CBasePlayer_Killed(const victim, const attacker)
{
	new weaponname[6];

	if(victim == attacker || !is_weapon_has_scope(attacker, weaponname))
	{
		return;
	}

	new bool:hs = bool:(get_member(victim, m_LastHitGroup) == HITGROUP_HEAD);

	if(get_member(attacker, m_iClientFOV) == 90)
	{
		client_print_color(0, 0, "^4%n ^1adli oyuncu ^4%n ^1adli oyuncuyu ^3%0.0f ^1m uzakliktan ^4%s ^1vurdu. [^3%s^1]",
		attacker, victim, get_distance_k(victim, attacker), hs ? "Zoomsuz Kafadan" : "Zoomsuz", weaponname);

		if(g_cvar[NOSCOPE])
		{
			bmParaDuzenle(attacker,bmParaCektir(attacker) + g_cvar[NOSCOPE]);
			rg_add_account(attacker, g_cvar[NOSCOPE], AS_ADD);
			client_print_color(attacker, attacker, "^4+%i$: Csgo Parasi ^1%s vurdugunuz icin kazandiniz.", g_cvar[NOSCOPE], hs ? "Zoomsuz Kafadan" : "Zoomsuz");
		}
	}
	else if(get_gametime() - ScopeData[attacker] <= 0.20)
	{
		client_print_color(0, 0, "^4%n ^1adli oyuncu ^4%n ^1adli oyuncuyu ^3%0.0f ^1m uzakliktan ^4%s ^1vurdu. [^3%s^1]",
		attacker, victim, get_distance_k(victim, attacker), hs ? "QuickScope Kafadan" : "QuickScope", weaponname);

		if(g_cvar[QUICKSCOPE])
		{
			bmParaDuzenle(attacker,bmParaCektir(attacker) + g_cvar[QUICKSCOPE]);
			rg_add_account(attacker, g_cvar[QUICKSCOPE], AS_ADD);
			client_print_color(attacker, attacker, "^4+%i$: Csgo Parasi^1%s vurdugunuz icin kazandiniz.", g_cvar[QUICKSCOPE], hs ? "QuickScope Kafadan" : "QuickScope");
		}
	}	
}

bool:is_weapon_has_scope(const attacker, weaponname[6])
{
	if(!is_user_connected(attacker)) {
		return false;
	}

	new weapon = get_user_weapon(attacker);

	switch(weapon)
	{
		case 3: {
			formatex(weaponname, charsmax(weaponname), "Scout");
		}
		case 18: {
			formatex(weaponname, charsmax(weaponname), "AWP");
		}
		default: {
			return false;
		}
	}
	return true;
}

Float:get_distance_k(const victim, const attacker)
{
	new Float:origin[3], Float:porigin[3];
	get_entvar(victim, var_origin, origin);
	get_entvar(attacker, var_origin, porigin);
	return (get_distance_f(origin, porigin) * 0.0254);
}