[Bugsy]

This will slay if the player is within 10 units of where he spawned after 30 seconds.

PHP Code:


#include <amxmodx> 
#include <fakemeta>

new const Version[] = "0.1";

const TaskID = 3412231;

new Float:g_fOrigin[ MAX_PLAYERS + 1 ][ 3 ];  
new g_pSlayTime;

public plugin_init()  
{  
    register_plugin( "AFK Slay" , Version , "bugsy" );
    
    register_logevent( "RoundStart" , 2 , "1=Round_Start" );
    register_logevent( "RoundEnd" , 2 , "1=Round_End" );
    
    g_pSlayTime = register_cvar( "as_slaytime" , "30" );
}  

public RoundStart()  
{
    new iPlayers[ 32 ] , iNum , iPlayer;
        
    get_players( iPlayers , iNum , "ae" , "CT" );
    
    for ( new i = 0 ; i < iNum ; i++ )
    {
        iPlayer = iPlayers[ i ];
        pev( iPlayer , pev_origin , g_fOrigin[ iPlayer ] );
    }
    
    set_task( get_pcvar_float( g_pSlayTime ) , "CheckAFK" , TaskID );
}  

public RoundEnd()
{
    remove_task( TaskID );
}

public CheckAFK()  
{  
    new iPlayers[ 32 ] , iNum , iPlayer , Float:fOrigin[ 3 ];
        
    get_players( iPlayers , iNum , "ae" , "CT" );
    
    for ( new i = 0 ; i < iNum ; i++ )
    {
        iPlayer = iPlayers[ i ];
        
        pev( iPlayer , pev_origin , fOrigin );
        
        if ( get_distance_f( g_fOrigin[ iPlayer ] , fOrigin ) <= 10.0 )
            user_kill( iPlayer )
    }
}