[Bugsy]

Here, work with this. Untested

PHP Code:


#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

new const Version[] = "0.1";

new g_NumRevives[ MAX_PLAYERS + 1 ];
new g_pTotalRevives , g_pRequiredFlags;

public plugin_init() 
{
    register_plugin( "Revive" , Version , "bugsy" );
    
    g_pTotalRevives = register_cvar( "allowed_revives" , "3" );
    g_pRequiredFlags = register_cvar( "revive_flags" , "o" );
    
    register_event( "HLTV" , "NewRound" , "a" , "1=0" , "2=0" );
    
    register_clcmd( "say /revive" , "Revive" );
    register_clcmd( "say_team /revive" , "Revive" );
}

public NewRound()
{
    arrayset( g_NumRevives , 0 , sizeof( g_NumRevives ) );
}

public Revive( id )
{    
    new iTotalRevives , szFlags[ 26 ] , iFlags;
    
    iTotalRevives = get_pcvar_num( g_pTotalRevives );
    get_pcvar_string( g_pRequiredFlags , szFlags , charsmax( szFlags ) );
    iFlags = read_flags( szFlags );
    
    if ( ( ( get_user_flags( id ) & iFlags ) == iFlags ) && ( cs_get_user_team( id ) == CS_TEAM_CT ) )
    {
        if ( g_NumRevives[ id ] < iTotalRevives )
        {
            if ( !is_user_alive( id ) )
            {
                ExecuteHamB( Ham_CS_RoundRespawn , id );
                g_NumRevives[ id ]++;
                
                client_print( id , print_chat , "* You have now used %d of %d allowed revives" , g_NumRevives[ id ] , iTotalRevives );
            }
        }
        else
        {
            client_print( id , print_chat , "* You have already used %d of %d revives" , iTotalRevives , iTotalRevives );
        }
    }
    
    return PLUGIN_HANDLED;
}