[KiLLeR.]

Instead of explaining, it was a faster to edit the plugin you have gave in first post. So, here is it:

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

#define NAME "show teammate's money"
#define VERSION "1.3.1"
#define AUTHOR "K.K.Lv"

new g_max_players, g_sync_creat_statustext;

new bool:g_teammate[33]

new cvar_plugin_on
new cvar_status_on

public plugin_init()
{
    register_plugin(NAME, VERSION, AUTHOR)
    
    RegisterHam(Ham_Spawn, "player", "player_spawn", 1)
    
    register_clcmd("say /money", "clcmd_money")
    
    register_event("StatusValue", "show_teammate_money", "be", "1=2", "2!0")
    register_event("StatusValue", "set_team", "be", "1=1")
    
    cvar_plugin_on = register_cvar("stm_on", "1")
    cvar_status_on = register_cvar("stm_st_on", "1")
    
    g_max_players = get_maxplayers()
    g_sync_creat_statustext = CreateHudSyncObj()
}

public clcmd_money(client)
{
    if (!get_pcvar_num(cvar_plugin_on))
    {
        client_print(client, print_chat, "[AMXX]: Show Teammate's Money was off.")
        return PLUGIN_HANDLED
    }
    show_money(client)
    return PLUGIN_CONTINUE
}

public player_spawn(client)
{
    remove_task(client)
    if (is_user_alive(client) && get_pcvar_num(cvar_plugin_on))
    {
        set_task(1.0, "show_money", client)
    }
}

public show_money(client)
{
    static name[32];
    
    new money, id;
    
    client_print(client, print_chat, "The teammate's money:");
    for (id = 1; id <= g_max_players; id++)
    {
        if (id != client && is_user_connected(id) && cs_get_user_team(id) == cs_get_user_team(client))
        {
            money = cs_get_user_money(id);
            get_user_name(id, name, 31);
            client_print(client, print_chat, "%-22.22s: $%d", name, money);
        }
    }
}

public set_team(id)
    g_teammate[id] = bool:(read_data(2) == 1);

public show_teammate_money(id)
{
    if (!get_pcvar_num(cvar_plugin_on))
        return PLUGIN_HANDLED
    if(!is_user_bot(id) && is_user_connected(id) && get_pcvar_num(cvar_status_on))
    {
        static name[32]
        
        new pid = read_data(2)
        new red = 0, blue = 0
        
        if (cs_get_user_team(pid) == CS_TEAM_T)
            red = 255
        else if(cs_get_user_team(pid) == CS_TEAM_CT)
            blue = 255
        
        get_user_name(pid, name, charsmax(name))
        new money = cs_get_user_money(pid)
        if (g_teammate[id])
        {
            set_hudmessage(red, 50, blue, -1.0, 0.60, 1, 0.01, 0.6, 0.01, 0.01, 8)
            ShowSyncHudMsg(id, g_sync_creat_statustext, "Friend:%s -- Money:%d", name, money)
        }
        else {
            set_hudmessage(red, 50, blue, -1.0, 0.60, 1, 0.01, 0.6, 0.01, 0.01, 8)
            ShowSyncHudMsg(id, g_sync_creat_statustext, "Enemy:%s", name)
        }
    }
    return PLUGIN_CONTINUE
}

public client_disconnect(client)
{
    remove_task(client)
}

But I think this is useless and ugly, because chat will be flooded if there is more players in the server when someone write "/money" in chat.