AlliedModders - [CS][Forward] client

AlliedModders (https://forums.alliedmods.net/index.php)

- Code Snippets/Tutorials (https://forums.alliedmods.net/forumdisplay.php?f=83)

- - [CS][Forward] client_buy (https://forums.alliedmods.net/showthread.php?t=149380)

[CS][Forward] client_buy

client_buy Forward

.: Description :.

The plugin offers a forward that allow you to hook any buy attempt.

.: Forward :.

client_buy < player index > < item type >

Returns : PLUGIN_CONTINUE , PLUGIN_HANDLED

.: Item indexes :.

For weapons, index is the weapon type, so CSW_AK47 or CSW_MP5NAVY for example.
For vest and helmet, this is amxx defines : CSW_VEST and CSW_VESTHELM.
I had to introduce new indexes for the plugin, here they are :
CSW_DEFUSER : defusal kit

CSW_NVGS : nightvision

CSW_SHIELD : shield

CSW_PRIMAMMO : primary ammo

CSW_SECAMMO : secondary ammo

Spoiler

PHP Code:


		
			
#include <amxmodx>

#include <fakemeta>

#include <cstrike>



#define VERSION "0.1.1"

#define PLUGIN "client_buy forward"



enum {

    CSW_DEFUSER = 33,

    CSW_NVGS,

    CSW_SHIELD,

    CSW_PRIMAMMO,

    CSW_SECAMMO

}



enum _:iMenus {

    Menu_Buy = 4,

    Menu_BuyPistol = 5,

    Menu_BuyRifle = 6,

    Menu_BuyMachineGun = 7,

    Menu_BuyShotgun = 8,

    Menu_BuySubMachineGun = 9,

    Menu_BuyItem = 10

}



#define XO_PLAYER 5

#define m_iMenu 205

#define cs_get_user_menu(%0)    get_pdata_int(%0, m_iMenu, XO_PLAYER)



new const g_iMenuItemsTe[][] = {

    {0, 0, 0, 0, 0, 0, CSW_PRIMAMMO, CSW_SECAMMO, 0}, /* Menu_Buy */

    {0, CSW_GLOCK18, CSW_USP, CSW_P228, CSW_DEAGLE, CSW_ELITE, 0, 0, 0}, /* Menu_BuyPistol */

    {0, CSW_GALIL, CSW_AK47, CSW_SCOUT, CSW_SG552, CSW_AWP, CSW_G3SG1, 0, 0}, /* Menu_BuyRifle */

    {0, CSW_M249, 0, 0, 0, 0, 0, 0, 0}, /* Menu_BuyMachineGun */

    {0, CSW_M3, CSW_XM1014, 0, 0, 0, 0, 0, 0}, /* Menu_BuyShotgun */

    {0, CSW_MAC10, CSW_MP5NAVY, CSW_UMP45, CSW_P90, 0, 0, 0, 0}, /* Menu_BuySubMachineGun */

    {0, CSW_VEST, CSW_VESTHELM, CSW_FLASHBANG, CSW_HEGRENADE, CSW_SMOKEGRENADE, CSW_NVGS, 0, 0} /* Menu_BuyItem */

}



new const g_iMenuItemsCt[][] = {

    {0, 0, 0, 0, 0, 0, CSW_PRIMAMMO, CSW_SECAMMO, 0}, /* Menu_Buy */

    {0, CSW_GLOCK18, CSW_USP, CSW_P228, CSW_DEAGLE, CSW_FIVESEVEN, 0, 0, 0}, /* Menu_BuyPistol */

    {0, CSW_FAMAS, CSW_SCOUT, CSW_M4A1, CSW_AUG, CSW_SG550, CSW_AWP, 0, 0}, /* Menu_BuyRifle */

    {0, CSW_M249, 0, 0, 0, 0, 0, 0, 0}, /* Menu_BuyMachineGun */

    {0, CSW_M3, CSW_XM1014, 0, 0, 0, 0, 0, 0}, /* Menu_BuyShotgun */

    {0, CSW_TMP, CSW_MP5NAVY, CSW_UMP45, CSW_P90, 0, 0, 0, 0}, /* Menu_BuySubMachineGun */

    {0, CSW_VEST, CSW_VESTHELM, CSW_FLASHBANG, CSW_HEGRENADE, CSW_SMOKEGRENADE, CSW_NVGS, CSW_DEFUSER, CSW_SHIELD} /* Menu_BuyItem */

}



new g_iBuyForward, g_iReturn



public plugin_init()

{

    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")

}



public plugin_cfg()

{

    new pluginsNum = get_pluginsnum()

    for(new pluginIndex; pluginIndex<pluginsNum; pluginIndex++)

    {

        if( get_func_id("client_buy", pluginIndex) != -1 )

        {

            register_clcmd("menuselect", "ClCmd_MenuSelect")

            g_iBuyForward = CreateMultiForward("client_buy", ET_STOP, FP_CELL, FP_CELL)

            break

        }

    }

    

    if( !g_iBuyForward )

    {

        log_amx("client_buy forward is not used by any other plugin, pausing plugin.")

        pause("ad")

    }

}



public plugin_natives()

{

    register_library("cl_buy")

}



public client_command(id)

{

    if( is_user_alive(id) )

    {

        new szCommand[13] // autoshotgun

        if( read_argv(0, szCommand, charsmax(szCommand)) < 12 )

        {

            return CheckBuyCmd(id, szCommand)

        }

    }

    return PLUGIN_CONTINUE

}



public CS_InternalCommand(id, const szCommand[])

{

    if( is_user_alive(id) )

    {

        new szCmd[13]

        if( copy(szCmd, charsmax(szCmd), szCommand) < 12 )

        {

            return CheckBuyCmd(id, szCmd)

        }

    }

    return PLUGIN_CONTINUE

}



CheckBuyCmd(id , szCmd[])

{

    new iItem = GetAliasId( szCmd )

    if( iItem )

    {

        return CanBuyItem(id, iItem)

    }

    return PLUGIN_CONTINUE

}



public ClCmd_MenuSelect( id )

{

    if( !is_user_alive(id) )

    {

        return PLUGIN_CONTINUE

    }

    new szSlot[3]

    if( read_argv(1, szSlot, charsmax(szSlot)) == 1 )

    {

        new iSlot = szSlot[0] - '0'

        if( 1 <= iSlot <= 8 )

        {

            new iMenu = cs_get_user_menu(id)

            if( Menu_Buy <= iMenu <= Menu_BuyItem )

            {

                new iItem

                switch( cs_get_user_team(id) )

                {

                    case CS_TEAM_T:iItem = g_iMenuItemsTe[iMenu-4][iSlot]

                    case CS_TEAM_CT:iItem = g_iMenuItemsCt[iMenu-4][iSlot]

                }

                if( iItem )

                {

                    return CanBuyItem(id, iItem)

                }

            }

        }

    }

    return PLUGIN_CONTINUE

}



CanBuyItem(id, iItem)

{

    ExecuteForward(g_iBuyForward, g_iReturn, id, iItem)

    if( g_iReturn != PLUGIN_CONTINUE )

    {

        return PLUGIN_HANDLED

    }

    return PLUGIN_CONTINUE

}



GetAliasId( szAlias[] )

{

    static Trie:tAliasesIds = Invalid_Trie

    if( tAliasesIds == Invalid_Trie )

    {

        tAliasesIds = TrieCreate()

        TrieSetCell(tAliasesIds, "p228",        CSW_P228)

        TrieSetCell(tAliasesIds, "228compact",    CSW_P228)

        TrieSetCell(tAliasesIds, "scout",        CSW_SCOUT)

        TrieSetCell(tAliasesIds, "hegren",        CSW_HEGRENADE)

        TrieSetCell(tAliasesIds, "xm1014",        CSW_XM1014)

        TrieSetCell(tAliasesIds, "autoshotgun",    CSW_XM1014)

        TrieSetCell(tAliasesIds, "mac10",        CSW_MAC10)

        TrieSetCell(tAliasesIds, "aug",            CSW_AUG)

        TrieSetCell(tAliasesIds, "bullpup",        CSW_AUG)

        TrieSetCell(tAliasesIds, "sgren",        CSW_SMOKEGRENADE)

        TrieSetCell(tAliasesIds, "elites",        CSW_ELITE)

        TrieSetCell(tAliasesIds, "fn57",        CSW_FIVESEVEN)

        TrieSetCell(tAliasesIds, "fiveseven",    CSW_FIVESEVEN)

        TrieSetCell(tAliasesIds, "ump45",        CSW_UMP45)

        TrieSetCell(tAliasesIds, "sg550",        CSW_SG550)

        TrieSetCell(tAliasesIds, "krieg550",    CSW_SG550)

        TrieSetCell(tAliasesIds, "galil",        CSW_GALIL)

        TrieSetCell(tAliasesIds, "defender",    CSW_GALIL)

        TrieSetCell(tAliasesIds, "famas",        CSW_FAMAS)

        TrieSetCell(tAliasesIds, "clarion",        CSW_FAMAS)

        TrieSetCell(tAliasesIds, "usp",            CSW_USP)

        TrieSetCell(tAliasesIds, "km45",        CSW_USP)

        TrieSetCell(tAliasesIds, "glock",        CSW_GLOCK18)

        TrieSetCell(tAliasesIds, "9x19mm",        CSW_GLOCK18)

        TrieSetCell(tAliasesIds, "awp",            CSW_AWP)

        TrieSetCell(tAliasesIds, "magnum",        CSW_AWP)

        TrieSetCell(tAliasesIds, "mp5",            CSW_MP5NAVY)

        TrieSetCell(tAliasesIds, "smg",            CSW_MP5NAVY)

        TrieSetCell(tAliasesIds, "m249",        CSW_M249)

        TrieSetCell(tAliasesIds, "m3",            CSW_M3)

        TrieSetCell(tAliasesIds, "12gauge",        CSW_M3)

        TrieSetCell(tAliasesIds, "m4a1",        CSW_M4A1)

        TrieSetCell(tAliasesIds, "tmp",            CSW_TMP)

        TrieSetCell(tAliasesIds, "mp",            CSW_TMP)

        TrieSetCell(tAliasesIds, "g3sg1",        CSW_G3SG1)

        TrieSetCell(tAliasesIds, "d3au1",        CSW_G3SG1)

        TrieSetCell(tAliasesIds, "flash",        CSW_FLASHBANG)

        TrieSetCell(tAliasesIds, "deagle",        CSW_DEAGLE)

        TrieSetCell(tAliasesIds, "nighthawk",    CSW_DEAGLE)

        TrieSetCell(tAliasesIds, "sg552",        CSW_SG552)

        TrieSetCell(tAliasesIds, "krieg552",    CSW_SG552)

        TrieSetCell(tAliasesIds, "ak47",        CSW_AK47)

        TrieSetCell(tAliasesIds, "cv47",        CSW_AK47)

        TrieSetCell(tAliasesIds, "p90",            CSW_P90)

        TrieSetCell(tAliasesIds, "c90",            CSW_P90)



        TrieSetCell(tAliasesIds, "vest",        CSW_VEST)

        TrieSetCell(tAliasesIds, "vesthelm",    CSW_VESTHELM)



        TrieSetCell(tAliasesIds, "defuser",        CSW_DEFUSER)

        TrieSetCell(tAliasesIds, "nvgs",        CSW_NVGS)

        TrieSetCell(tAliasesIds, "shield",        CSW_SHIELD)

        TrieSetCell(tAliasesIds, "buyammo1",    CSW_PRIMAMMO)

        TrieSetCell(tAliasesIds, "primammo",    CSW_PRIMAMMO)

        TrieSetCell(tAliasesIds, "buyammo2",    CSW_SECAMMO)

        TrieSetCell(tAliasesIds, "secammo",        CSW_SECAMMO)

    }



    strtolower(szAlias)



    new iId

    if( TrieGetCell(tAliasesIds, szAlias, iId) )

    {

        return iId

    }

    return 0

}

Re: [CS][Forward] client_buy

Plugin example :

AWP Restriction

PHP Code:


		
			
#include <amxmodx>
#include <cl_buy>

#define VERSION "0.0.1"
#define PLUGIN "No Awp"

new g_iTextMsg

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
    g_iTextMsg = get_user_msgid("TextMsg")
}

public client_buy(id, iItem)
{
    if( iItem == CSW_AWP && !user_has_weapon(id, CSW_AWP) )
    {
        message_begin( MSG_ONE_UNRELIABLE, g_iTextMsg, .player=id )
        {
            write_byte( print_center )
            write_string( "#Alias_Not_Avail" )
            write_string( "#ArcticWarfareMagnum" )
        }
        message_end()

        return PLUGIN_HANDLED
    }
    return PLUGIN_CONTINUE
}

Re: [CS][Forward] client_buy

Some misc things you could find usefull :

PHP Code:


		
			
new const g_szLabelsShort[][] = {
    "",
    "#P228Compact",
    "",
    "#Schmidt",
    "#HE_Grenade",
    "#AutoShotgun",
    "", // CSW_C4
    "#Mac10_Short",
    "#Aug",
    "#Smoke_Grenade",
    "#Dual40",
    "#ESFiveSeven",
    "#KMUMP45",
    "#Krieg550",
    "#Galil",
    "#Famas",
    "#KM45Tactical",
    "#Sidearm9X19mm",
    "#Magnum",
    "#SubMachineGun",
    "#ESM249",
    "#Leone12",
    "#M4A1_Short",
    "#SchmidtMP",
    "#D3AU1",
    "#Flashbang",
    "#NightHawk",
    "#Krieg552",
    "#AK47",
    "", // CSW_KNIFE
    "#ESC90",
    "#Kevlar",
    "#Kevlar_Helmet",
    "#Defusal_Kit",
    "#NightVision",
    "#TactShield",
    "Prim. Ammo",
    "Sec. Ammo"
}

PHP Code:


		
			
new const g_szLabels[][] = {
    "",
    "#P228",
    "",
    "#Scout",
    "#HE_Grenade",
    "#xm1014",
    "", // CSW_C4
    "#MAC10",
    "#Aug",
    "#Smoke_Grenade",
    "#Beretta96G",
    "#FiveSeven",
    "#UMP45",
    "#SG550",
    "#Galil",
    "#Famas",
    "#USP45",
    "#Glock18",
    "#ArcticWarfareMagnum",
    "#mp5navy",
    "#M249",
    "#Super90",
    "#M4A1",
    "#Tmp",
    "#G3SG1",
    "#Flashbang",
    "#DesertEagle",
    "#SG552",
    "#AK47",
    "", // CSW_KNIFE
    "#FNP90",
    "#Kevlar",
    "#Kevlar_Helmet",
    "#Defusal_Kit",
    "#NightVision",
    "#TactShield",
    "Prim. Ammo",
    "Sec. Ammo"
}

PHP Code:


		
			
new const g_szItemNames[][] = {
    "",
    "228 Compact",
    "",
    "Schmidt Scout",
    "HE Grenade",
    "Auto Shotgun",
    "", // CSW_C4
    "Mac-10",
    "Bullpup",
    "Smoke Grenade",
    ".40 Dual",
    "Five-Seven",
    "K&M UMP45",
    "Krieg 550",
    "IDF Defender",
    "Clarion 5.56",
    "K&M .45",
    "9X19mm",
    "Magnum",
    "SMG",
    "ES M249",
    "12 Gauge",
    "M4A1",
    "Schmidt MP",
    "D3AU1",
    "Flashbang", // "#Cstrike_Flashbang"
    "Night Hawk",
    "Krieg 552",
    "CV-47",
    "", // CSW_KNIFE
    "ES C90",
    "Kevlar",
    "Kevlar+Helmet",
    "Defusal Kit",
    "NightVision",
    "Tactical Shield",
    "Prim. Ammo",
    "Sec. Ammo"
}

PHP Code:


		
			
user_has_item(id, iItem)
{
    switch( iItem )
    {
        case CSW_VEST, CSW_VESTHELM :
        {
            new CsArmorType:iArmorType
            cs_get_user_armor(id, iArmorType)
            return iArmorType == (iItem == CSW_VEST ? CS_ARMOR_KEVLAR : CS_ARMOR_VESTHELM)
        }
        case CSW_DEFUSER:
        {
            return cs_get_user_defuse(id)
        }
        case CSW_NVGS:
        {
            return cs_get_user_nvg(id)
        }
        case CSW_SHIELD:
        {
            cs_get_user_shield(id)
        }
        case CSW_PRIMAMMO, CSW_SECAMMO:
        {
            return 0
        }
    }
    return user_has_weapon(id, iItem)
}

PHP Code:


		
			
Message_Alias_Not_Avail(id, iId)
{
    if( !user_has_item(id, iId) )
    {
        message_begin(MSG_ONE_UNRELIABLE, g_iTextMsg, .player=id) // have to set g_iTextMsg = get_user_msgid("TextMsg") at plugin_init
        write_byte( print_center )
        write_string( "#Alias_Not_Avail" )
        write_string( g_szLabels[iId] )
        message_end()
    }
}

Re: [CS][Forward] client_buy

Thanks for this contribution, it will help me a lot.
By the way, Good job.

Greetings.

Re: [CS][Forward] client_buy

Since it's always interesting to show severals ways of something, I post just another way using Orpheu. No harcoding. Also, to piss Connor off. :twisted:

PHP Code:


		
			
#include <amxmodx>

#include <orpheu>

#include <fakemeta>



enum

{

    CSW_DEFUSER = 33,

    CSW_NVGS,

    CSW_SHIELD,

    CSW_PRIMAMMO,

    CSW_SECAMMO

};



const BitsPistols = ( 1 << CSW_GLOCK18 | 1 << CSW_USP | 1 << CSW_P228 | 1 << CSW_DEAGLE | 1 << CSW_ELITE | 1 << CSW_FIVESEVEN );



new const itemSlotToWeaponId[] = { -1, CSW_VEST, CSW_VESTHELM, CSW_FLASHBANG, CSW_HEGRENADE, CSW_SMOKEGRENADE, CSW_NVGS, CSW_DEFUSER, CSW_SHIELD };

new const ammoToWeaponId    [] = { CSW_PRIMAMMO, CSW_SECAMMO };



const m_iId = 43;



new HandleForwardBuy;



public plugin_natives()

{

    register_library( "cl_buy" );

}



public plugin_init()

{

    register_plugin( "Can Buy Item", "1.0.0", "Arkshine" );



    OrpheuRegisterHook( OrpheuGetFunction( "CanBuyThis" ), "CanBuyThis" ); // Weapons

    OrpheuRegisterHook( OrpheuGetFunction( "BuyItem" )   , "BuyItem"    ); // Items

    OrpheuRegisterHook( OrpheuGetFunction( "BuyGunAmmo" ), "BuyGunAmmo" ); // Ammos

    

    HandleForwardBuy = CreateMultiForward( "client_buy", ET_STOP, FP_CELL, FP_CELL );

}



public OrpheuHookReturn:CanBuyThis( const player, const weaponId )

{

    return CanBuyItem( player, weaponId );

}



public OrpheuHookReturn:BuyItem( const player, const slot )

{

    return CanBuyItem( player, itemSlotToWeaponId[ slot ] );

}



public OrpheuHookReturn:BuyGunAmmo( const player, const item, const bool:displayMsg )

{

    return CanBuyItem( player, ammoToWeaponId[ !( get_pdata_int( item, m_iId, 4 ) & BitsPistols ) ] );

}



OrpheuHookReturn:CanBuyItem( const player, const itemId )

{

    static pluginReturn;

    ExecuteForward( HandleForwardBuy, pluginReturn, player, itemId );



    return ( pluginReturn != PLUGIN_CONTINUE ) ? OrpheuSupercede : OrpheuIgnored;

}

Plugin not really tested. I won't develop more, it was just to see how it can be handled with orpheu. Feel free to Connor to do what he wants with it. :P

Signatures attached.

Re: [CS][Forward] client_buy

:mrgreen:

Will use this for sure in the future.

Re: [CS][Forward] client_buy

Good job connor and arkshine

Re: [CS][Forward] client_buy

I read everything and could not understand anything. :down:

Re: [CS][Forward] client_buy

Quote:

Originally Posted by rx1983 (Post 1408578)

I read everything and could not understand anything. :down:

Isn't the right section. And if you do not understand, you don't need to show like that this forward is bad for you. (meant your smile, yes)