AlliedModders - How to activate func

AlliedModders (https://forums.alliedmods.net/index.php)

- Scripting (https://forums.alliedmods.net/forumdisplay.php?f=107)

- - How to activate func_button (https://forums.alliedmods.net/showthread.php?t=313708)

How to activate func_button

Hello.

How i can activate func_button "target name" with command ? I find that code but it crash server when i type command

PHP Code:


		
			
#pragma semicolon 1

#include <sourcemod>
#include <sdktools>

public OnPluginStart()
{
      RegAdminCmd( "sm_activatebutton", Cmdbutton, ADMFLAG_ROOT);
}

public Action:Cmdbutton( client, args )
{
    decl String:TargetName[128];
    new CurEnt = FindEntityByClassname(-1, "func_button");
    while (CurEnt >= 0) 
    {
        GetEntPropString(CurEnt, Prop_Data, "m_iName", TargetName, 128);
        if (StrEqual(TargetName, "button_name")) 
        {
            LogMessage("%d : %s", CurEnt, TargetName);
            ActivateEntity(CurEnt);
        }
        CurEnt = FindEntityByClassname(CurEnt, "func_button");
    }
}

Re: How to activate func_button

PHP Code:


		
			

#pragma semicolon 1

#include <sourcemod>
#include <sdktools>

public void OnPluginStart()
{
      RegAdminCmd("sm_activatebutton", Cmdbutton, ADMFLAG_ROOT);
}

public Action Cmdbutton(int client, int args)
{
    char targetName[128];
    GetCmdArg(1, targetName, sizeof(targetName));

    int ent = -1;

    while ((ent = FindEntityByClassname(ent, "func_button")) != -1) 
    {
        char buttonName[128];
        GetEntPropString(ent, Prop_Data, "m_iName", buttonName, sizeof(buttonName));
       
        if (StrEqual(targetName, buttonName) 
        {
            AcceptEntityInput(ent, "Press");
            return Plugin_Handled;
        }
    }

    return Plugin_Handled;
}

Your server crash because because of this code:

PHP Code:


		
			

    new CurEnt = FindEntityByClassname(-1, "func_button"); // CurEnt = entity if exists
    while (CurEnt >= 0) {} // if an entity "func_button" exists, then this is an infinite loop

Re: How to activate func_button

Quote:

Originally Posted by Ilusion9 (Post 2635484)

PHP Code:


		
			


#pragma semicolon 1



#include <sourcemod>

#include <sdktools>



public void OnPluginStart()

{

      RegAdminCmd("sm_activatebutton", Cmdbutton, ADMFLAG_ROOT);

}



public Action Cmdbutton(int client, int args)

{

    char targetName[128];

    GetCmdArg(1, targetName, sizeof(targetName));



    int ent = -1;



    while ((ent = FindEntityByClassname(ent, "func_button")) != -1) 

    {

        char buttonName[128];

        GetEntPropString(ent, Prop_Data, "m_iName", buttonName, sizeof(buttonName));

       

        if (StrEqual(targetName, buttonName) 

        {

            AcceptEntityInput(ent, "Press");

            return Plugin_Handled;

        }

    }



    return Plugin_Handled;

}

Your server crash because because of this code:

PHP Code:


		
			


    new CurEnt = FindEntityByClassname(-1, "func_button"); // CurEnt = entity if exists

    while (CurEnt >= 0) {} // if an entity "func_button" exists, then this is an infinite loop

Thanks for noticing.
Still crashing the server.

Perhaps a stupid question: where do i set the name of the button here? Maybe I'm doing it wrong

Re: How to activate func_button

You haven't used my code because it doesn't even compile.
It's easy to talk that your server crashes because you are still using your code.

Use this:

PHP Code:


		
			


#pragma semicolon 1 



#include <sourcemod> 

#include <sdktools> 



public void OnPluginStart() 

{ 

    RegAdminCmd("sm_activatebutton", Command_ActivateButton, ADMFLAG_ROOT, "sm_activatebutton <name>"); 

} 



public Action Command_ActivateButton(int client, int args) 

{

    if (args < 1)

    {

        ReplyToCommand(client, "[SM] Usage: sm_activatebutton <name>");

        return Plugin_Handled; 

    }

    

    char arg[65]; 

    GetCmdArg(1, arg, sizeof(arg)); 



    int entity = -1; 

    while ((entity = FindEntityByClassname(entity, "func_button")) != -1)

    {

        char name[65]; 

        GetEntPropString(entity, Prop_Data, "m_iName", name, sizeof(name)); 

        

        if (StrEqual(arg, name))

        { 

            AcceptEntityInput(entity, "Press"); 

            return Plugin_Handled; 

        } 

    } 



    return Plugin_Handled; 

}

Re: How to activate func_button

Quote:

Originally Posted by Ilusion9 (Post 2635493)

You haven't used my code because it doesn't even compile.
It's easy to talk that your server crashes because you are still using your code.

Use this:

PHP Code:


		
			

#pragma semicolon 1 

#include <sourcemod> 
#include <sdktools> 

public void OnPluginStart() 
{ 
    RegAdminCmd("sm_activatebutton", Command_ActivateButton, ADMFLAG_ROOT, "sm_activatebutton <name>"); 
} 

public Action Command_ActivateButton(int client, int args) 
{
    if (args < 1)
    {
        ReplyToCommand(client, "[SM] Usage: sm_activatebutton <name>");
        return Plugin_Handled; 
    }
    
    char arg[65]; 
    GetCmdArg(1, arg, sizeof(arg)); 

    int entity = -1; 
    while ((entity = FindEntityByClassname(entity, "func_button")) != -1)
    {
        char name[65]; 
        GetEntPropString(entity, Prop_Data, "m_iName", name, sizeof(name)); 
        
        if (StrEqual(arg, name))
        { 
            AcceptEntityInput(entity, "Press"); 
            return Plugin_Handled; 
        } 
    } 

    return Plugin_Handled; 
}

Thanks you. Everything works fine.

Sorry to appeal to you again, but it’s not working the way I would like. I would like to do this: the administrator writes the command “sm_activatebutton 1 (or 2, 3, etc.)” And, for example, 1 - button_open, 2 - button_close, 3 - button_slay etc.
Not to write every time the name of the buttons like "sm_activatebutton button_open"

Re: How to activate func_button

AcceptEntityInput(ent, "Use", client);
ent being the button, client being the one pressing the button

Re: How to activate func_button

Quote:

Originally Posted by Mitchell (Post 2635512)

AcceptEntityInput(ent, "Use", client);
ent being the button, client being the one pressing the button

Similarly, I've used the following to trigger buttons:

Code:

AcceptEntityInput(iEntID, "Press", client, iEntID);