AlliedModders - Revive a player in a certain radius

AlliedModders (https://forums.alliedmods.net/index.php)

- Suggestions / Requests (https://forums.alliedmods.net/forumdisplay.php?f=12)

- - Revive a player in a certain radius (https://forums.alliedmods.net/showthread.php?t=324779)

Revive a player in a certain radius

Hello everyone, I found this plugin that makes a player to revive a teammate by approaching the corpse and holding CTRL + E, a bar will appear and when you complete that bar the player revives where he died, the problem with this is that you have to get close to the exact point where he died and it is very difficult to find the exact point. Someone could make it possible to revive the partner over a certain radio and have a cvar of that (so it would be easier to revive it) please? ... ths in advance

PHP Code:


		
			
/* 

    - Credits: 
        # Alucard (Get_origin)
        # Black Rose (Check buttoms)
*/    

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <hamsandwich>
#include <fun>
#include <cstrike>

#define PLUGIN "CPR Revive"
#define VERSION "1.0"
#define AUTHOR "wiD"

new Float:fOrigin[33][3] // Poss of victim
new gCheck[33]
new Float:fPoss[33][3] // Poss of reviver
new checkid
new g_msgBarTime;
new gMessage[33]

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_event("DeathMsg",                    "event_DeathMsg", "a")
    
    register_forward(FM_CmdStart, "OnCmdStart", false)
    
    g_msgBarTime = get_user_msgid( "BarTime" );
}

public get_origin(id)
{
    new Float:fDeath[3]
    pev(id , pev_origin , fDeath)
    
    fOrigin[id][0] = fDeath[0]
    fOrigin[id][1] = fDeath[1]
    fOrigin[id][2] = fDeath[2]
    
    return PLUGIN_HANDLED
}

public event_DeathMsg()
{
    new attacker = read_data(1) 
    new victim = read_data(2) 
    
    if (!(is_user_connected(attacker)) || (attacker == victim)) 
        return;
        
    get_origin(victim)
}

public OnCmdStart(id, uc_handle, seed) 
{
    
    if (!is_user_alive(id))
        return;
    
    static buttons;
    buttons = get_uc(uc_handle, UC_Buttons);
    
    if ((buttons & IN_DUCK) && (buttons & IN_USE)) 
    {
        if (!gCheck[id] && CheckOrigin(id)) 
        {
            set_task(10.0, "RevivePlayer", id)
            gCheck[id] = true;
            if(!gMessage[id])
            {
                startBar(id)
                gMessage[id] = true
            }
        }
    }
    else 
    {
        stopBar(id)
        remove_task(id);
        gCheck[id] = false;
        gMessage[id] = false;
    }
    
    return;
}

public CheckOrigin(id)
{
    new bool:checking
    new Float:fPosition[3]
    pev(id , pev_origin , fPosition)
    
    fPoss[id][0] = fPosition[0]
    fPoss[id][1] = fPosition[1]
    fPoss[id][2] = fPosition[2]
    
    for(new i = 1; i <= get_maxplayers( ); i++ )
    {
        if((fOrigin[i][0] == fPoss[id][0]) && (fOrigin[i][1] == fPoss[id][1]) && (fOrigin[i][2] == fPoss[id][2]) && (cs_get_user_team(id) == cs_get_user_team(i)))
        {
            checking = true
            checkid = i
            break;
        }
    }
    
    return checking;
}
    

public RevivePlayer(id)
{
    ExecuteHamB(Ham_CS_RoundRespawn, checkid)
    new Float:fSetOrigin[3]
    fSetOrigin[0] = fPoss[id][0]
    fSetOrigin[1] = fPoss[id][1]
    fSetOrigin[2] = fPoss[id][2]
    set_user_origin(checkid, fSetOrigin)
    client_print(0, print_chat, "[CPR] User %s respawned target %s", id, checkid)
}

public startBar(id)
{
    message_begin( MSG_ONE , g_msgBarTime , {0,0,0} , id );
    write_short( 10 );
    message_end();

}
 
public stopBar(id)
{
    message_begin(MSG_ONE, g_msgBarTime, _, id)
    write_short(0)
    message_end()
}

Re: Revive a player in a certain radius

Well, i know that this line is causing you the trouble.

PHP Code:


		
			
if((fOrigin[i][0] == fPoss[id][0]) && (fOrigin[i][1] == fPoss[id][1]) && (fOrigin[i][2] == fPoss[id][2])

This code is actually telling us, that the reviver needs to be on the EXACT SAME SPOT the victim died, if not, the reviving function will not work.

I would suggest using random_float() for this.

Re: Revive a player in a certain radius

Can you give me an example pls

Re: Revive a player in a certain radius

Not thoroughly tested

Added cvars
Code cleanup
Made a little smarter

It finds closest if multiple players are close enough for revive.
Stops revive if you move too far away while reviving

CVars:

cpr_distance - Maximum distance in units to allow revive
cpr_reviveseconds - Seconds to revive someone

PHP Code:


		
			
/* 

    - Credits: 
        # Alucard (Get_origin)
        # Black Rose (Check buttoms)
        # bugsy (added functionality, code cleanup, fixes and added cvars)
*/    

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <cstrike>

new const Version[] = "0.3";

const RespawnButtons = ( IN_DUCK | IN_USE );

enum CPRData
{
    Float:CorpseOrigin[ 3 ],
    ReviverID
}
    
new g_rdData[ MAX_PLAYERS + 1 ][ CPRData ];
new g_msgBarTime;
new g_pDistance , g_gReviveSeconds;

public plugin_init() 
{
    register_plugin( "CPR Revive" , Version , "Alu-rose-sy" );

    register_event( "DeathMsg" , "DeathMsg" , "a" , "1>0" );

    register_forward( FM_CmdStart , "CmdStart" );

    g_msgBarTime = get_user_msgid( "BarTime" );
    
    g_pDistance = register_cvar( "cpr_distance" , "50" );
    g_gReviveSeconds = register_cvar( "cpr_reviveseconds" , "10" );
}

public DeathMsg()
{
    new iVictim = read_data( 2 );
    pev( iVictim , pev_origin , g_rdData[ iVictim ][ CorpseOrigin ] );
}

public CmdStart( id , uc_handle , seed ) 
{
    if ( !is_user_alive( id ) )
        return;
    
    static iRespawnID , bool:bRespawning[ MAX_PLAYERS + 1 ] , bBarStarted[ MAX_PLAYERS + 1 ] , Float:fOrigin[ 3 ];

    if ( ( get_uc( uc_handle , UC_Buttons ) & RespawnButtons ) == RespawnButtons ) 
    {
        if ( !bRespawning[ id ] )
        {
            if ( ( iRespawnID = CheckOrigin( id ) ) ) 
            {
                g_rdData[ iRespawnID ][ ReviverID ] = id;
                set_pev( id , pev_iuser2 , iRespawnID );
                set_task( get_pcvar_float( g_gReviveSeconds ) , "RevivePlayer" , iRespawnID );
                bRespawning[ id ] = true;
                
                if ( !bBarStarted[ id ] )
                {
                    StartBar( id );
                    bBarStarted[ id ] = true;
                }
            }
        }
        else
        {
            pev( id , pev_origin , fOrigin );
            iRespawnID = pev( id , pev_iuser2 );
            
            if ( get_distance_f_x( fOrigin , g_rdData[ iRespawnID ][ CorpseOrigin ] ) > get_pcvar_float( g_pDistance ) )
            {
                remove_task( iRespawnID );
                StopBar( id );
                bRespawning[ id ] = false;
                bBarStarted[ id ] = false;
                
                if ( !is_user_alive( iRespawnID  )
                    client_print( id , print_chat , "* You moved too far away from player to revive" );

                set_pev( id , pev_iuser2 , 0 );
            }
        }
    }
    else if ( bRespawning[ id ] )
    {
        StopBar( id );
        remove_task( iRespawnID );
        bRespawning[ id ] = false;
        bBarStarted[ id ] = false;
    }
    
    return;
}

public CheckOrigin( id )
{
    new iPlayers[ 32 ] , iNum , Float:fOrigin[ 3 ] , Float:fDistanceThreshold , Float:fDistance , iNearestPlayer , iPlayer , Float:fNearestDistance;
    
    pev( id , pev_origin , fOrigin );
    get_players( iPlayers , iNum , "be" , cs_get_user_team( id ) == CS_TEAM_T ? "TERRORIST" : "CT" );
    fDistanceThreshold = get_pcvar_float( g_pDistance );
    
    for ( new i = 0 ; i < iNum ; i++ )
    {
        iPlayer = iPlayers[ i ];
        
        fDistance = get_distance_f_x( fOrigin , g_rdData[ iPlayer ][ CorpseOrigin ] );
        
        if ( !fNearestDistance || ( fNearestDistance && ( fDistance < fNearestDistance ) ) ) 
        {
            fNearestDistance = fDistance;
            iNearestPlayer = iPlayer;
        }
    }
    
    return ( fNearestDistance <= fDistanceThreshold ) ? iNearestPlayer : 0;
}
    
public RevivePlayer( id )
{
    new szRespawnName[ 33 ] , szRespawnerName[ 33 ];
    get_user_name( id , szRespawnName , charsmax( szRespawnName ) );
    get_user_name( g_rdData[ id ][ ReviverID ] , szRespawnerName , charsmax( szRespawnerName ) );
    
    ExecuteHamB( Ham_CS_RoundRespawn , id );
    set_pev( id , pev_origin , g_rdData[ id ][ CorpseOrigin ] );
    client_print( 0 , print_chat , "[CPR] User %s respawned target %s" , szRespawnerName , szRespawnName );
}

public StartBar( id )
{
    message_begin( MSG_ONE , g_msgBarTime , {0,0,0} , id );
    write_short( get_pcvar_num( g_gReviveSeconds ) );
    message_end();
}
 
public StopBar( id )
{
    message_begin( MSG_ONE , g_msgBarTime , _, id );
    write_short( 0 );
    message_end();
}

//Workaround due to AMX-X compile error using array from enumerator in get_distance_f()
Float:get_distance_f_x( Float:fOrigin1[] , Float:fOrigin2[] )
{
    new Float:f1[ 3 ] , Float:f2[3];
    f1[0] = fOrigin1[0];
    f1[1] = fOrigin1[1];
    f1[2] = fOrigin1[2];
    f2[0] = fOrigin2[0];
    f2[1] = fOrigin2[1];
    f2[2] = fOrigin2[2];
    
    return get_distance_f( f1 , f2 );
}

Re: Revive a player in a certain radius

Thanks bugsy, what kind of work would the code need?

Re: Revive a player in a certain radius

I made edits, look above

Re: Revive a player in a certain radius

ok thanks i will test it later but i have a question if there are two or more corpses in the same radio it will revive everyone? oh they would be revive one by one

Re: Revive a player in a certain radius

Only one at a time, starting with the closest. The chances of them being at an exact distance away is slim.

Re: Revive a player in a certain radius

Why not drop the bar, and origin (unless there is a marker); then just trigger it off spectating bots like Global Offensive?

Re: Revive a player in a certain radius

At the moment it works fine thanks, I have a question is it possible to remove the corpse model after reviving the partner?