#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

enum _:ModelsInfo
{
    Flag,
    CTModel[32]/*,
    TModel[32]*/
}

new const g_eModels[][ModelsInfo] =
{
    { ADMIN_LEVEL_A, "owner_ct" },
    { ADMIN_LEVEL_B, "admin_ct" }
}

new bool:g_bHasCustomSkin[33]

public plugin_init()
{
    register_plugin("Multiple Player Models", "1.0", "OciXCrom")
    RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
}

public plugin_precache()
{
    for(new i; i < sizeof(g_eModels); i++)
    {
        precache_player_model(g_eModels[i][CTModel])
        //precache_player_model(g_eModels[i][TModel])
    }
}

public client_putinserver(id)
    g_bHasCustomSkin[id] = false

public OnPlayerSpawn(id)
{
    if(is_user_alive(id))
    {
        new bool:bMatch

        for(new iFlags = get_user_flags(id), i; i < sizeof(g_eModels); i++)
        {
            if(iFlags & g_eModels[i][Flag])
            {
                switch(cs_get_user_team(id))
                {
                    case CS_TEAM_CT: set_model(id, g_eModels[i][CTModel])
                    //case CS_TEAM_T: set_model(id, g_eModels[i][TModel])
                }

                bMatch = true
                break
            }
        }

        if(!bMatch && g_bHasCustomSkin[id])
        {
            g_bHasCustomSkin[id] = false
            cs_reset_user_model(id)
        }
    }
}

set_model(const id, const szModel[])
{
    cs_set_user_model(id, szModel)
    g_bHasCustomSkin[id] = true
}

stock precache_player_model(const name[], &id = 0)
{
    new model[128]
    formatex(model, charsmax(model), "models/player/%s/%sT.mdl", name, name)

    if(file_exists(model))
        id = precache_generic(model)

    static const extension[] = "T.mdl"
    #pragma unused extension

    copy(model[strlen(model) - charsmax(extension)], charsmax(model), ".mdl")
    return precache_model(model)
}