AlliedModders

AlliedModders (https://forums.alliedmods.net/index.php)
-   Scripting Help (https://forums.alliedmods.net/forumdisplay.php?f=11)
-   -   [Help] Rate Admin (+rep , -rep) (https://forums.alliedmods.net/showthread.php?t=292191)

youssef_randy 12-31-2016 12:13
[Help] Rate Admin (+rep , -rep)
 
Hello guys! This Plugin is awsome,& i find cool idea to make it perfect & helpfull to all cs 1.6 server players, it's +rep -rep system, it controlls the reputable of any admin in your server and by typing "say /report" you can vote for an admin, please i want to make the admin that has +12 x -rep, to lose his admin acces automaticly or relate it to a file that show me the list of reported admins :
PHP Code:
 /* Plugin generated by AMXX-Studio */

#include <amxmodx>

#define PLUGIN "Admin rate"
#define VERSION "0.1"
#define AUTHOR "¢"
#define FLAG_ADM ADMIN_IMMUNITY

new g_maxplayers, g_menutarget[33], g_rate[33][33];

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    register_clcmd("say /report", "cmd_ratemenu");
    g_maxplayers = get_maxplayers();
    if( !dir_exists("admins_y") )
    {
        mkdir("admins_y");
    }
}

public client_authorized(id)
{
    if(get_user_flags(id) & FLAG_ADM)
    {
        new name[32], text[64];
        get_user_name(id, name, charsmax(name));
        formatex(text, charsmax(text), "admins_y/%s.txt", name);
        if( !file_exists(text) )
        {
            new FILE = fopen(text, "w");
            fputs(FILE, "0^n");
            fclose(FILE);
        }
    }
}

public cmd_ratemenu(id)
{
    new menu = menu_create("\r[AW] \wAdmin Rate menu", "menu_handler");
    for( new i = 1; i < g_maxplayers; i++)
    {
        new name[32], text[34], num[4];
        get_user_name(i, name, charsmax(name));
        formatex(text, charsmax(text), "%s%s", (get_user_flags(i) & FLAG_ADM)?"\w":"\d", name);
        num_to_str(i, num, charsmax(num));
        menu_additem(menu, text, num);
    }
    menu_display(id, menu);
}

public menu_handler(id, menu, key)
{
    if( key == MENU_EXIT )
    {
        menu_destroy(menu);
        return;
    }
    key+=1;
    if( !(get_user_flags(key) & ADMIN_IMMUNITY) )
    {
        menu_display(id, menu);
        return;
    }
    g_menutarget[id]=key;
    menu_rate(id);
    
}

public menu_rate(id)
{
    if( g_menutarget[id] == id )
    {
        client_print(id, print_chat, "^4[AW]^3 You can't rate yourself!");
        return;
    }
    if( get_user_flags(g_menutarget[id]) & FLAG_ADM )
    {
        new name[32], menu;
        get_user_name(g_menutarget[id], name, charsmax(name));
        menu = menu_create(name, "rate_handler");
        menu_additem(menu, "\r+Rep \yGood Admin", "0");
        menu_additem(menu, "\r-Rep \yBad Admin", "1");
        menu_display(id, menu);
    }
}

public rate_handler(id, menu, key)
{
    if( key == MENU_EXIT )
    {
        menu_destroy(menu);
        return;
    }
    new i;
    for( i = 0; i < g_maxplayers; i++ )
    {
        if(g_rate[id][i] == g_menutarget[id])
        {
            client_print(id, print_chat, "^4[AW]^3 You have already rated this Player");
            return;
        }
    }
    for( i = 0; i < g_maxplayers; i++ )
    {
        if( !g_rate[id][i] )
        {
            g_rate[id][i]=g_menutarget[id];
            break;
        }
    }
    new name[32], text[64], a[4],b;
    get_user_name(g_menutarget[id], name, charsmax(name));
    formatex(text, charsmax(text), "admins_y/%s.txt", name);
    new FILE = fopen(text, "r");
    fgets(FILE, a, charsmax(a));
    fclose(FILE);
    b=str_to_num(a);
    if( key == 0 )
    {
        b++;
        client_print(id, print_chat, "%s's rate plus", name);
    }
    if( key == 1 )
    {
        b--;
        client_print(id, print_chat, "%s's rate minus", name);
    }
    FILE = fopen(text, "w");
    num_to_str(b, a, charsmax(a));
    fputs(FILE, a);
    fputs(FILE, "^n");
    fclose(FILE);
} 

OciXCrom 12-31-2016 13:16
Re: [Help] Rate Admin (+rep , -rep)
 
Rep = reputation, not report. :s

edon1337 12-31-2016 13:31
Re: [Help] Rate Admin (+rep , -rep)
 
Quote:
Originally Posted by OciXCrom (Post 2482292)
Rep = reputation, not report. :s
Agree, "re" would look better.

youssef_randy 01-01-2017 13:37
Re: [Help] Rate Admin (+rep , -rep)
 
Quote:
Originally Posted by OciXCrom (Post 2482292)
Rep = reputation, not report. :s
i'm not stupid ^.^

Bugsy 01-01-2017 18:50
Re: [Help] Rate Admin (+rep , -rep)
 
A clean way to do this would be to not have the plugin modify users.ini automatically, while it will still remove the users admin flags each time he connects. This removal will be in a log file and you can check this (in a MOTD if you want) periodically and if you decide you then want to remove him from users.ini, you can.

youssef_randy 01-02-2017 06:58
Re: [Help] Rate Admin (+rep , -rep)
 
Quote:
Originally Posted by Bugsy (Post 2482543)
A clean way to do this would be to not have the plugin modify users.ini automatically, while it will still remove the users admin flags each time he connects. This removal will be in a log file and you can check this (in a MOTD if you want) periodically and if you decide you then want to remove him from users.ini, you can.
Thanks i'll try it ! ^^

Bugsy 01-03-2017 21:37
Re: [Help] Rate Admin (+rep , -rep)
 
Here's the first draft. Once an admin accumulates 12 minus votes, his admin power will be removed the next time he connects. The calculation is done using [minus votes] - [plus votes]; so if he has 15 minus votes and 5 plus votes (10 total minus), he is ok and keeps admin, but if has 15 minus and 2 plus (13 minus), he loses admin. Each vote on the admin is remembered between admin connections so you can keep track of votes over time. Each vote is stored in a log file so you can see if the same player re-votes for a specific admin. I'm thinking of bringing in nVault Utility to show a MOTD displaying each admin and their vote counts.

What I think would be better is to only allow each player to vote a specific admin 1 time. It does do this per-connection, but if the player disconnects/re-connects, he can again vote the same admin.

You will need nVault Array
PHP Code:

#include <amxmodx>
#include <nvault_array>

new const Version[] = "0.1";

#define MAX_PLAYERS 32

const AdminFlag = ADMIN_IMMUNITY;

enum PlayerData
{
    szName[ 32 ],
    szAuthID[ 32 ],
    bool:bIsAdmin,
    iNumGood,
    iNumBad,
    bool:bVoted[ MAX_PLAYERS + 1 ]
}
new g_pdData[ MAX_PLAYERS + 1 ][ PlayerData ];

new g_Vault , g_pMinusVotes;

public plugin_init() 
{
    register_plugin( "Rate Admins" , Version , "bugsy" );
    
    register_clcmd( "say /eport" , "ShowRateMenu" );
    
    g_pMinusVotes = register_cvar( "ra_minusvotes" , "12" );
    
    if ( ( g_Vault = nvault_open( "RateAdmins" ) ) == INVALID_HANDLE )
        set_fail_state( "Error opening vault" );
}

public plugin_end() 
{
    nvault_close( g_Vault );
}

public client_authorized( id )
{
    get_user_authid( id , g_pdData[ id ][ szAuthID ] , charsmax( g_pdData[][ szAuthID ] ) );
    
    if ( ( g_pdData[ id ][ bIsAdmin ] = bool:( get_user_flags( id ) & AdminFlag ) ) )
    {
        nvault_get_array( g_Vault , g_pdData[ id ][ szAuthID ] , g_pdData[ id ][ szName ][ 0 ] , sizeof( g_pdData[] ) );
        
        if ( ( g_pdData[ id ][ iNumBad ] - g_pdData[ id ][ iNumGood ] ) >= get_pcvar_num( g_pMinusVotes ) )
        {
            set_user_flags( id , ADMIN_USER );
        }
    }
    
    get_user_name( id , g_pdData[ id ][ szName ] , charsmax( g_pdData[][ szName ] ) );
    
    arrayset( g_pdData[ id ][ bVoted ] , false , sizeof( g_pdData[][ bVoted ] ) ); 
}

public client_disconnect( id )
{
    if ( g_pdData[ id ][ bIsAdmin ] )
    {
        nvault_set_array( g_Vault , g_pdData[ id ][ szAuthID ] , g_pdData[ id ][ szName ][ 0 ] , sizeof( g_pdData[] ) );
    }
}

public ShowRateMenu( id )
{
    new iMenu = menu_create( "\r[AW] \wAdmin Rate menu" , "AdminHandler" );
    new szID[ 3 ] , iAdminsLoaded;
    
    for( new i = 1 ; i <= MAX_PLAYERS ; i++ )
    {
        if ( ( i != id ) && ( g_pdData[ i ][ bIsAdmin ] == true ) )
        {
            num_to_str( i , szID , charsmax( szID ) );
            menu_additem( iMenu , g_pdData[ i ][ szName ] , szID );
            iAdminsLoaded++;
        }
    }
    
    if ( iAdminsLoaded )
    {
        menu_display( id , iMenu );
    }
    else
    {
        client_print( id , print_chat , "^4[AW]^3 There are no admins to vote." );
    }
    
    return PLUGIN_HANDLED;
}

public AdminHandler( id , iMenu , iKey )
{
    new iNewMenu , szID[ 3 ] , iDummy;
    
    menu_item_getinfo( iMenu , iKey , iDummy , szID , charsmax( szID ) , "" , 0 , iDummy );  
    
    iNewMenu = menu_create( g_pdData[ str_to_num( szID ) ][ szName ] , "RateHandler");
    
    menu_additem( iNewMenu , "\r+Rep \yGood Admin" , szID );
    menu_additem( iNewMenu , "\r-Rep \yBad Admin" , szID );
    
    menu_display( id , iNewMenu );
}

public RateHandler( id , iMenu , iKey )
{
    new szID[ 3 ] , iDummy , iAdminID;
    
    if( iKey == MENU_EXIT )
    {
        menu_destroy( iMenu );
        return;
    }
    
    menu_item_getinfo( iMenu , iKey , iDummy , szID , charsmax( szID ) , "" , 0 , iDummy );  
    
    iAdminID = str_to_num( szID );
    
    if ( g_pdData[ id ][ bVoted ][ iAdminID ] == true ) 
    {
        client_print(id, print_chat, "^4[AW]^3 You have already rated this Player");
    }
    else
    {
        g_pdData[ id ][ bVoted ][ iAdminID ] = true;
        
        client_print( id , print_chat , "%s's rate %s" , g_pdData[ iAdminID ][ szName ] , iKey == 0 ? "plus" : "minus" );
        
        log_to_file( "AdminRate.log" , "%s (%s) voted %s for %s (%s)" , g_pdData[ id ][ szName ] , g_pdData[ id ][ szAuthID ] , iKey == 0 ? "PLUS" : "MINUS" , g_pdData[ iAdminID ][ szName ] , g_pdData[ iAdminID ][ szAuthID ] );
        
        if ( iKey == 0 )
        {
            g_pdData[ iAdminID ][ iNumGood ]++;
        }
        else
        {
            g_pdData[ iAdminID ][ iNumBad ]++;
        }
    }
} 

youssef_randy 01-04-2017 15:14
Re: [Help] Rate Admin (+rep , -rep)
 
Quote:
Originally Posted by Bugsy (Post 2483260)
Here's the first draft. Once an admin accumulates 12 minus votes, his admin power will be removed the next time he connects. The calculation is done using [minus votes] - [plus votes]; so if he has 15 minus votes and 5 plus votes (10 total minus), he is ok and keeps admin, but if has 15 minus and 2 plus (13 minus), he loses admin. Each vote on the admin is remembered between admin connections so you can keep track of votes over time. Each vote is stored in a log file so you can see if the same player re-votes for a specific admin. I'm thinking of bringing in nVault Utility to show a MOTD displaying each admin and their vote counts.

What I think would be better is to only allow each player to vote a specific admin 1 time. It does do this per-connection, but if the player disconnects/re-connects, he can again vote the same admin.

You will need nVault Array
PHP Code:

#include <amxmodx>
#include <nvault_array>

new const Version[] = "0.1";

#define MAX_PLAYERS 32

const AdminFlag = ADMIN_IMMUNITY;

enum PlayerData
{
    szName[ 32 ],
    szAuthID[ 32 ],
    bool:bIsAdmin,
    iNumGood,
    iNumBad,
    bool:bVoted[ MAX_PLAYERS + 1 ]
}
new g_pdData[ MAX_PLAYERS + 1 ][ PlayerData ];

new g_Vault , g_pMinusVotes;

public plugin_init() 
{
    register_plugin( "Rate Admins" , Version , "bugsy" );
    
    register_clcmd( "say /eport" , "ShowRateMenu" );
    
    g_pMinusVotes = register_cvar( "ra_minusvotes" , "12" );
    
    if ( ( g_Vault = nvault_open( "RateAdmins" ) ) == INVALID_HANDLE )
        set_fail_state( "Error opening vault" );
}

public plugin_end() 
{
    nvault_close( g_Vault );
}

public client_authorized( id )
{
    get_user_authid( id , g_pdData[ id ][ szAuthID ] , charsmax( g_pdData[][ szAuthID ] ) );
    
    if ( ( g_pdData[ id ][ bIsAdmin ] = bool:( get_user_flags( id ) & AdminFlag ) ) )
    {
        nvault_get_array( g_Vault , g_pdData[ id ][ szAuthID ] , g_pdData[ id ][ szName ][ 0 ] , sizeof( g_pdData[] ) );
        
        if ( ( g_pdData[ id ][ iNumBad ] - g_pdData[ id ][ iNumGood ] ) >= get_pcvar_num( g_pMinusVotes ) )
        {
            set_user_flags( id , ADMIN_USER );
        }
    }
    
    get_user_name( id , g_pdData[ id ][ szName ] , charsmax( g_pdData[][ szName ] ) );
    
    arrayset( g_pdData[ id ][ bVoted ] , false , sizeof( g_pdData[][ bVoted ] ) ); 
}

public client_disconnect( id )
{
    if ( g_pdData[ id ][ bIsAdmin ] )
    {
        nvault_set_array( g_Vault , g_pdData[ id ][ szAuthID ] , g_pdData[ id ][ szName ][ 0 ] , sizeof( g_pdData[] ) );
    }
}

public ShowRateMenu( id )
{
    new iMenu = menu_create( "\r[AW] \wAdmin Rate menu" , "AdminHandler" );
    new szID[ 3 ] , iAdminsLoaded;
    
    for( new i = 1 ; i <= MAX_PLAYERS ; i++ )
    {
        if ( ( i != id ) && ( g_pdData[ i ][ bIsAdmin ] == true ) )
        {
            num_to_str( i , szID , charsmax( szID ) );
            menu_additem( iMenu , g_pdData[ i ][ szName ] , szID );
            iAdminsLoaded++;
        }
    }
    
    if ( iAdminsLoaded )
    {
        menu_display( id , iMenu );
    }
    else
    {
        client_print( id , print_chat , "^4[AW]^3 There are no admins to vote." );
    }
    
    return PLUGIN_HANDLED;
}

public AdminHandler( id , iMenu , iKey )
{
    new iNewMenu , szID[ 3 ] , iDummy;
    
    menu_item_getinfo( iMenu , iKey , iDummy , szID , charsmax( szID ) , "" , 0 , iDummy );  
    
    iNewMenu = menu_create( g_pdData[ str_to_num( szID ) ][ szName ] , "RateHandler");
    
    menu_additem( iNewMenu , "\r+Rep \yGood Admin" , szID );
    menu_additem( iNewMenu , "\r-Rep \yBad Admin" , szID );
    
    menu_display( id , iNewMenu );
}

public RateHandler( id , iMenu , iKey )
{
    new szID[ 3 ] , iDummy , iAdminID;
    
    if( iKey == MENU_EXIT )
    {
        menu_destroy( iMenu );
        return;
    }
    
    menu_item_getinfo( iMenu , iKey , iDummy , szID , charsmax( szID ) , "" , 0 , iDummy );  
    
    iAdminID = str_to_num( szID );
    
    if ( g_pdData[ id ][ bVoted ][ iAdminID ] == true ) 
    {
        client_print(id, print_chat, "^4[AW]^3 You have already rated this Player");
    }
    else
    {
        g_pdData[ id ][ bVoted ][ iAdminID ] = true;
        
        client_print( id , print_chat , "%s's rate %s" , g_pdData[ iAdminID ][ szName ] , iKey == 0 ? "plus" : "minus" );
        
        log_to_file( "AdminRate.log" , "%s (%s) voted %s for %s (%s)" , g_pdData[ id ][ szName ] , g_pdData[ id ][ szAuthID ] , iKey == 0 ? "PLUS" : "MINUS" , g_pdData[ iAdminID ][ szName ] , g_pdData[ iAdminID ][ szAuthID ] );
        
        if ( iKey == 0 )
        {
            g_pdData[ iAdminID ][ iNumGood ]++;
        }
        else
        {
            g_pdData[ iAdminID ][ iNumBad ]++;
        }
    }
} 
Wow man thank you so mush!

SomewhereLost 01-05-2017 06:14
Re: [Help] Rate Admin (+rep , -rep)
 
Quote:
I'm thinking of bringing in nVault Utility to show a MOTD displaying each admin and their vote counts.
This would be great


All times are GMT -4. The time now is 10:07.

Powered by vBulletin®
Copyright ©2000 - 2024, vBulletin Solutions, Inc.