AlliedModders
Page 1 of 2 1 2
Show 40 post(s) from this thread on one page

AlliedModders (https://forums.alliedmods.net/index.php)
-   Suggestions / Requests (https://forums.alliedmods.net/forumdisplay.php?f=12)
-   -   How can I do that...? (https://forums.alliedmods.net/showthread.php?t=315386)

EFFx 04-05-2019 13:12
How can I do that...?
 
I found that stock some weeks ago but I couldn't find it anymore. What I want to know is how can I force an entity/player aim at a certain origin?

thEsp 04-05-2019 13:34
Re: How can I do that...?
 
PHP Code:
entity_set_vector(index,EV_VEC_angles,angle[3])
entity_set_int(index,EV_INT_fixangle,1) 
PHP Code:
set_pev(index,pev_v_angle,dest) 
Not sure about the first, I found it in a post a long time ago, and re-found it again (May be wrong post..)
EDIT: First one works just fine, but you need to convert aiming vector/float to angle.

EFFx 04-05-2019 14:07
Re: How can I do that...?
 
I think you misunderstood what I said, lemme give more details:

I have the end position of where I'm aiming at, I just wanna make another player aim where my end position from my crosshair is.

Natsheh 04-05-2019 14:19
Re: How can I do that...?
 
PHP Code:
stock LookAtOrigin(const id, const Float:fOrigin_dest[3])
{
    static Float:fOrigin[3];
    pev(id, pev_origin, fOrigin);
    
    if(fOrigin[0] == fOrigin_dest[0] && // center
        fOrigin[1] == fOrigin_dest[1]) // center
            return;
    
    static Float:fLook[3];
    xs_vec_sub(fOrigin_dest, fOrigin, fOrigin);
    xs_vec_normalize(fOrigin, fOrigin);
    vector_to_angle(fOrigin, fLook);
    
    set_pev(id, pev_angles, fLook);
    set_pev(id, pev_fixangle, 1);
} 

EFFx 04-05-2019 14:33
Re: How can I do that...?
 
I dunno if either the stock is wrong or the way it works with that plugin is wrong. But when I'd spray with the AK or any weapon with recoil, the camera goes crazy.

The reason I asked for such stock is that I might fix the wrong aim problem by making the player follow the end origin that the camera is looking at, but somehow it didn't work correctly, what could be wrong?

PHP Code:
#include <amxmodx> 
#include <fakemeta> 
#include <fakemeta_util> 
#include <hamsandwich> 
#include <xs> 

#define VERSION "0.0.2" 

#define MAX_PLAYERS    32 
#define USE_TOGGLE 3 

new CAMERA_FORWARD
new CAMERA_RIGHT 
new CAMERA_UP
new CAMERA_FRACTION

new g_iPlayerCamera[MAX_PLAYERS+1] 

new g_iMaxPlayers 

public plugin_init() 
{ 
    register_plugin("Camera View AUTOMATIC", VERSION, "ConnorMcLeod") 
    
    CAMERA_FORWARD = register_cvar("camera_forward", "-100.0")
    CAMERA_RIGHT = register_cvar("camera_right", "0.0")
    CAMERA_UP = register_cvar("camera_up", "25.0")
    CAMERA_FRACTION = register_cvar("camera_fraction", "-35.0")
    
    RegisterHam(Ham_Spawn, "player", "CBasePlayer_Spawn_Post", 1) 
    register_forward(FM_SetView, "SetView") 
    RegisterHam(Ham_Think, "trigger_camera", "Camera_Think") 
    
    g_iMaxPlayers = get_maxplayers() 
} 

public CBasePlayer_Spawn_Post(id) 
{ 
    if(!is_user_alive(id)) 
    { 
        return 
    } 
    
    new iEnt = g_iPlayerCamera[id] 
    if(!pev_valid(iEnt)) 
    { 
        static iszTriggerCamera 
        if(!iszTriggerCamera) 
        { 
            iszTriggerCamera = engfunc(EngFunc_AllocString, "trigger_camera") 
        } 
        iEnt = engfunc(EngFunc_CreateNamedEntity, iszTriggerCamera) 
        set_kvd(0, KV_ClassName, "trigger_camera") 
        set_kvd(0, KV_fHandled, 0) 
        set_kvd(0, KV_KeyName, "wait") 
        set_kvd(0, KV_Value, "999999") 
        dllfunc(DLLFunc_KeyValue, iEnt, 0) 
        
        set_pev(iEnt, pev_spawnflags, SF_CAMERA_PLAYER_TARGET|SF_CAMERA_PLAYER_POSITION) 
        set_pev(iEnt, pev_flags, pev(iEnt, pev_flags) | FL_ALWAYSTHINK) 
        
        dllfunc(DLLFunc_Spawn, iEnt) 
        
        g_iPlayerCamera[id] = iEnt 
        
        new Float:flMaxSpeed, iFlags = pev(id, pev_flags) 
        pev(id, pev_maxspeed, flMaxSpeed) 
        
        ExecuteHam(Ham_Use, iEnt, id, id, USE_TOGGLE, 1.0) 
        
        set_pev(id, pev_flags, iFlags) 
        engfunc(EngFunc_SetClientMaxspeed, id, flMaxSpeed) 
        set_pev(id, pev_maxspeed, flMaxSpeed) 
    } 
} 

public SetView(id, iEnt) 
{ 
    if(is_user_alive(id)) 
    { 
        new iCamera = g_iPlayerCamera[id] 
        if(iCamera && iEnt != iCamera) 
        { 
            new szClassName[16] 
            pev(iEnt, pev_classname, szClassName, charsmax(szClassName)) 
            if(!equal(szClassName, "trigger_camera")) // should let real cams enabled 
            { 
                engfunc(EngFunc_SetView, id, iCamera) // shouldn't be always needed 
                return FMRES_SUPERCEDE 
            } 
        } 
    } 
    return FMRES_IGNORED 
} 

public client_disconnect(id) 
{ 
    new iEnt = g_iPlayerCamera[id] 
    if(pev_valid(iEnt)) 
    { 
        engfunc(EngFunc_RemoveEntity, iEnt) 
    } 
    g_iPlayerCamera[id] = 0 
} 

public client_putinserver(id) 
{ 
    g_iPlayerCamera[id] = 0 
} 

public get_cam_owner(iEnt) 
{ 
    static id 
    for(id = 1; id<=g_iMaxPlayers; id++) 
    { 
        if(g_iPlayerCamera[id] == iEnt) 
        { 
            return id 
        } 
    } 
    return 0 
} 

public Camera_Think(iEnt) 
{ 
    static id 
    if(!(id = get_cam_owner(iEnt))) 
    { 
        return 
    } 
    
    static Float:fVecPlayerOrigin[3], Float:fVecCameraOrigin[3], Float:fVecAngles[3],  
    Float:fVecForward[3], Float:fVecRight[3], Float:fVecUp[3]
    
    pev(id, pev_origin, fVecPlayerOrigin) 
    pev(id, pev_view_ofs, fVecAngles) 
    fVecPlayerOrigin[2] += fVecAngles[2] 
    pev(id, pev_v_angle, fVecAngles) 
    
    angle_vector(fVecAngles, ANGLEVECTOR_FORWARD, fVecForward) 
    angle_vector(fVecAngles, ANGLEVECTOR_RIGHT, fVecRight) 
    angle_vector(fVecAngles, ANGLEVECTOR_UP, fVecUp) 
    
    fVecCameraOrigin[0] = fVecPlayerOrigin[0] + fVecForward[0] * get_pcvar_float(CAMERA_FORWARD) + fVecRight[0] * get_pcvar_float(CAMERA_RIGHT) + fVecUp[0] * get_pcvar_float(CAMERA_UP) 
    fVecCameraOrigin[1] = fVecPlayerOrigin[1] + fVecForward[1] * get_pcvar_float(CAMERA_FORWARD) + fVecRight[1] * get_pcvar_float(CAMERA_RIGHT) + fVecUp[1] * get_pcvar_float(CAMERA_UP) 
    fVecCameraOrigin[2] = fVecPlayerOrigin[2] + fVecForward[2] * get_pcvar_float(CAMERA_FORWARD) + fVecRight[2] * get_pcvar_float(CAMERA_RIGHT) + fVecUp[2] * get_pcvar_float(CAMERA_UP) 
    
    engfunc(EngFunc_TraceLine, fVecPlayerOrigin, fVecCameraOrigin, IGNORE_MONSTERS, id, 0) 
    
    static Float:flFraction 
    get_tr2(0, TR_flFraction, flFraction) 
    if(flFraction != 1.0) // adjust camera place if close to a wall 
    { 
        flFraction *= get_pcvar_float(CAMERA_FRACTION)
        
        //fVecCameraOrigin[0] = fVecPlayerOrigin[0] + fVecForward[0] * flFraction + fVecRight[0] * flFraction + fVecUp[0] * flFraction 
        //fVecCameraOrigin[1] = fVecPlayerOrigin[1] + fVecForward[1] * flFraction + fVecRight[1] * flFraction + fVecUp[1] * flFraction 
        //fVecCameraOrigin[2] = fVecPlayerOrigin[2] + fVecForward[2] * flFraction + fVecRight[2] * flFraction + fVecUp[2] * flFraction 
        
        fVecCameraOrigin[0] = fVecPlayerOrigin[0] + (fVecForward[0] * flFraction) 
        fVecCameraOrigin[1] = fVecPlayerOrigin[1] + (fVecForward[1] * flFraction) 
        fVecCameraOrigin[2] = fVecPlayerOrigin[2] + (fVecForward[2] * flFraction) 
    } 
    
    set_pev(iEnt, pev_origin, fVecCameraOrigin)
    set_pev(iEnt, pev_angles, fVecAngles)
    set_pev(id, pev_angles, fVecAngles)
    
    new Float:fEntityEndPosition[3]
    getAimEndPosition(iEnt, fEntityEndPosition)
    lookAtOrigin(id, fEntityEndPosition)
}  

getAimEndPosition(id, Float:fOrigin[3]) 
{
    new Float:fStart[3], Float:fViewOfs[3]
    pev(id, pev_origin, fStart)
    pev(id, pev_view_ofs, fViewOfs)
    xs_vec_add(fStart, fViewOfs, fStart)

    new Float:fDest[3]
    pev(id, pev_v_angle, fDest)
    engfunc(EngFunc_MakeVectors, fDest)
    global_get(glb_v_forward, fDest)
    xs_vec_mul_scalar(fDest, 9999.0, fDest)
    xs_vec_add(fStart, fDest, fDest)

    engfunc(EngFunc_TraceLine, fStart, fDest, 0, id, 0)
    get_tr2(0, TR_vecEndPos, fOrigin)
} 

lookAtOrigin(const id, const Float:fOrigin_dest[3])
{
    static Float:fOrigin[3]
    pev(id, pev_origin, fOrigin)
    
    if(fOrigin[0] == fOrigin_dest[0] && fOrigin[1] == fOrigin_dest[1])
        return
    
    static Float:fLook[3]
    xs_vec_sub(fOrigin_dest, fOrigin, fOrigin)
    xs_vec_normalize(fOrigin, fOrigin)
    vector_to_angle(fOrigin, fLook)
    
    set_pev(id, is_user_connected(id) ? pev_v_angle:pev_angles, fLook)
    set_pev(id, pev_fixangle, 1)
} 


Edit: I've found this, but the player is not following the end position of the camera - https://forums.alliedmods.net/showpo...40&postcount=3

Natsheh 04-06-2019 15:57
Re: How can I do that...?
 
here you go after few tests...

PHP Code:
#include <amxmodx> 
#include <fakemeta> 
#include <fakemeta_util> 
#include <hamsandwich> 
#include <xs> 

#define VERSION "0.0.2" 

#define MAX_PLAYERS    32 
#define USE_TOGGLE 3 

new CAMERA_FORWARD
new CAMERA_RIGHT 
new CAMERA_UP
new CAMERA_FRACTION

new g_iPlayerCamera[MAX_PLAYERS+1] 

new g_iMaxPlayers;

new sprite_index;

public plugin_precache() sprite_index = precache_model("sprites/laserbeam.spr");

public plugin_init() 
{ 
    register_plugin("Camera View AUTOMATIC", VERSION, "ConnorMcLeod") 
    
    CAMERA_FORWARD = register_cvar("camera_forward", "-100.0")
    CAMERA_RIGHT = register_cvar("camera_right", "0.0")
    CAMERA_UP = register_cvar("camera_up", "25.0")
    CAMERA_FRACTION = register_cvar("camera_fraction", "-35.0")
    
    RegisterHam(Ham_Spawn, "player", "CBasePlayer_Spawn_Post", 1) 
    register_forward(FM_SetView, "SetView") 
    RegisterHam(Ham_Think, "trigger_camera", "Camera_Think")
    
    g_iMaxPlayers = get_maxplayers();
}

public CBasePlayer_Spawn_Post(id) 
{ 
    if(!is_user_alive(id)) 
    { 
        return 
    } 
    
    new iEnt = g_iPlayerCamera[id] 
    if(!pev_valid(iEnt)) 
    { 
        static iszTriggerCamera 
        if(!iszTriggerCamera) 
        { 
            iszTriggerCamera = engfunc(EngFunc_AllocString, "trigger_camera") 
        } 
        iEnt = engfunc(EngFunc_CreateNamedEntity, iszTriggerCamera) 
        set_kvd(0, KV_ClassName, "trigger_camera") 
        set_kvd(0, KV_fHandled, 0) 
        set_kvd(0, KV_KeyName, "wait") 
        set_kvd(0, KV_Value, "999999") 
        dllfunc(DLLFunc_KeyValue, iEnt, 0) 
        
        set_pev(iEnt, pev_spawnflags, SF_CAMERA_PLAYER_TARGET|SF_CAMERA_PLAYER_POSITION) 
        set_pev(iEnt, pev_flags, pev(iEnt, pev_flags) | FL_ALWAYSTHINK) 
        
        dllfunc(DLLFunc_Spawn, iEnt) 
        
        g_iPlayerCamera[id] = iEnt 
        
        new Float:flMaxSpeed, iFlags = pev(id, pev_flags) 
        pev(id, pev_maxspeed, flMaxSpeed) 
        
        ExecuteHam(Ham_Use, iEnt, id, id, USE_TOGGLE, 1.0) 
        
        set_pev(id, pev_flags, iFlags) 
        engfunc(EngFunc_SetClientMaxspeed, id, flMaxSpeed) 
        set_pev(id, pev_maxspeed, flMaxSpeed) 
    } 
} 

public SetView(id, iEnt) 
{ 
    if(is_user_alive(id)) 
    { 
        new iCamera = g_iPlayerCamera[id] 
        if(iCamera && iEnt != iCamera) 
        { 
            new szClassName[16] 
            pev(iEnt, pev_classname, szClassName, charsmax(szClassName)) 
            if(!equal(szClassName, "trigger_camera")) // should let real cams enabled 
            { 
                engfunc(EngFunc_SetView, id, iCamera) // shouldn't be always needed 
                return FMRES_SUPERCEDE;
            } 
        } 
    } 
    return FMRES_IGNORED 
} 

public client_disconnect(id) 
{ 
    new iEnt = g_iPlayerCamera[id] 
    if(pev_valid(iEnt)) 
    { 
        engfunc(EngFunc_RemoveEntity, iEnt) 
    }
    
    g_iPlayerCamera[id] = 0 
}

public get_cam_owner(iEnt) 
{ 
    static id 
    for(id = 1; id<=g_iMaxPlayers; id++) 
    { 
        if(g_iPlayerCamera[id] == iEnt) 
        { 
            return id 
        } 
    } 
    return 0 
} 

public Camera_Think(iEnt) 
{ 
    static id 
    if(!(id = get_cam_owner(iEnt))) 
    { 
        return 
    } 
    
    static Float:fVecPlayerOrigin[3], Float:fVecCameraOrigin[3], Float:fVecAngles[3],  
    Float:fVecForward[3], Float:fVecRight[3], Float:fVecUp[3]
    
    static iOrigin[3];
    get_user_origin(id, iOrigin, 1);
    IVecFVec(iOrigin, fVecPlayerOrigin);
    pev(id, pev_v_angle, fVecAngles) 
    
    angle_vector(fVecAngles, ANGLEVECTOR_FORWARD, fVecForward) 
    angle_vector(fVecAngles, ANGLEVECTOR_RIGHT, fVecRight) 
    angle_vector(fVecAngles, ANGLEVECTOR_UP, fVecUp) 
    
    fVecCameraOrigin[0] = fVecPlayerOrigin[0] + fVecForward[0] * get_pcvar_float(CAMERA_FORWARD) + fVecRight[0] * get_pcvar_float(CAMERA_RIGHT);
    fVecCameraOrigin[1] = fVecPlayerOrigin[1] + fVecForward[1] * get_pcvar_float(CAMERA_FORWARD) + fVecRight[1] * get_pcvar_float(CAMERA_RIGHT); 
    fVecCameraOrigin[2] = fVecPlayerOrigin[2] + fVecUp[2] * get_pcvar_float(CAMERA_UP) ;
    
    engfunc(EngFunc_TraceLine, fVecPlayerOrigin, fVecCameraOrigin, DONT_IGNORE_MONSTERS, id, 0) 
    
    static Float:flFraction 
    get_tr2(0, TR_flFraction, flFraction) 
    if(flFraction != 1.0) // adjust camera place if close to a wall 
    { 
        flFraction *= get_pcvar_float(CAMERA_FRACTION)
        
        fVecCameraOrigin[0] = fVecPlayerOrigin[0] + (fVecForward[0] * flFraction);
        fVecCameraOrigin[1] = fVecPlayerOrigin[1] + (fVecForward[1] * flFraction)
        fVecCameraOrigin[2] = fVecPlayerOrigin[2] + (fVecForward[2] * flFraction) 
    } 
    
    set_pev(iEnt, pev_origin, fVecCameraOrigin)
    
    static Float:fEntityEndPosition[3];
    
    getAimEndPosition(id, fEntityEndPosition)
    lookAtOrigin(iEnt, fEntityEndPosition)
    
    beam_bet_2origin(fVecPlayerOrigin, fEntityEndPosition);
}

beam_bet_2origin(Float:fOrigin1[3], Float:fOrigin2[3])
{
    message_begin(MSG_ALL, SVC_TEMPENTITY, _, 0)
    write_byte(TE_BEAMPOINTS)
    engfunc(EngFunc_WriteCoord, fOrigin1[0])
    engfunc(EngFunc_WriteCoord, fOrigin1[1])
    engfunc(EngFunc_WriteCoord, fOrigin1[2])
    engfunc(EngFunc_WriteCoord, fOrigin2[0])
    engfunc(EngFunc_WriteCoord, fOrigin2[1])
    engfunc(EngFunc_WriteCoord, fOrigin2[2])
    write_short(sprite_index) 
    write_byte(0) 
    write_byte(10) 
    write_byte(1) 
    write_byte(5) 
    write_byte(1) 
    write_byte(0)
    write_byte(255)
    write_byte(0)
    write_byte(255)
    write_byte(1)
    message_end()
}

getAimEndPosition(id, Float:fOrigin[3]) 
{
    static Float:fStart[3], Float:fDest[3], tr2;
    pev(id, pev_origin, fStart);
    pev(id, pev_view_ofs, fDest);
    xs_vec_add(fStart, fDest, fStart);   

    pev(id, pev_v_angle, fDest)
    angle_vector(fDest, ANGLEVECTOR_FORWARD, fDest);
    xs_vec_mul_scalar(fDest, 4000.0, fDest);
    
    tr2 = create_tr2();
    engfunc(EngFunc_TraceLine, fStart, fDest, IGNORE_MONSTERS, id, tr2);
    get_tr2(tr2, TR_vecEndPos, fOrigin);
    free_tr2(tr2);
} 

lookAtOrigin(const id, const Float:fOrigin_dest[3])
{
    static Float:fOrigin[3]
    pev(id, pev_origin, fOrigin)
    
    if( 1 <= id && id <= 32 )
    {
        static Float:fVec[3];
    pev(id, pev_view_ofs, fVec);
    xs_vec_add(fOrigin, fVec, fOrigin);
    }
    
    static Float:fLook[3], Float:fLen;
    xs_vec_sub(fOrigin_dest, fOrigin, fOrigin) 
    fLen = xs_vec_len(fOrigin);
    
    fOrigin[0] /= fLen;
    fOrigin[1] /= fLen;
    fOrigin[2] /= fLen;
    
    vector_to_angle(fOrigin, fLook)
    
    fLook[0] *= -1;
    
    set_pev(id, pev_angles, fLook);
    set_pev(id, pev_fixangle, 1);
} 
just the bullets decals are invalid but the traceattacks are quite right you need to redirect the bullets hole decals, i failed to do it since the decals are client side but u can block them and make new ones but im not sure how.

EFFx 04-06-2019 21:04
Re: How can I do that...?
 
Nah, it isn't just the bullet decals. When I'd shoot a player right at him it doesn't hit. You're only creating the beam between the camera view to the end position, but it is not the same aiment of the player's. Also, the pev_fixangle makes the camera weird so many times.

I think I just need a code that makes the camera follow the player's aim end position, so doesn't matter which position I set it, it'll still follow exactly where i'm aimint at.

Natsheh 04-06-2019 23:29
Re: How can I do that...?
 
In getAimEndPosition replace the trace flag with DONT_IGNORE_MONSTERS See if this solve the problem.

Also in camera think replace get_user_origin with with pev_origin then add to the origin player view of...


But I can assure that the camera aims where at the players aiming the problem' just with the bullet decals.

EFFx 04-07-2019 07:08
Re: How can I do that...?
 
The camera moves automatically due the pev_fixangle, so I need to fix where i'm aiming at everytime. Like, if i'm aiming close to an enemy and he starts going to my crosshair, the camera instantly changes the angle to the enemy. Looks like an aimbot.

Anyway, I tested and it actually just make the bullet decals wrong, but the shoots goes right. I've blocked the bullet decal but it stills making the sparkles which I've removed with FM_UpdateClientData, but looks like I'll need to recreate all weapon's sound animations.

thEsp 04-27-2019 17:21
Re: How can I do that...?
 
Quote:
Originally Posted by EFFx (Post 2646652)
The camera moves automatically due the pev_fixangle, so I need to fix where i'm aiming at everytime. Like, if i'm aiming close to an enemy and he starts going to my crosshair, the camera instantly changes the angle to the enemy. Looks like an aimbot.

Anyway, I tested and it actually just make the bullet decals wrong, but the shoots goes right. I've blocked the bullet decal but it stills making the sparkles which I've removed with FM_UpdateClientData, but looks like I'll need to recreate all weapon's sound animations.
Could you please show the code you used to block bullet decals and other properties (sounds,animation) :) ?


All times are GMT -4. The time now is 10:41.
Page 1 of 2 1 2
Show 40 post(s) from this thread on one page

Powered by vBulletin®
Copyright ©2000 - 2024, vBulletin Solutions, Inc.