AlliedModders - [Solved] client_infochanged Efficiency

Page 1 of 2

Show 40 post(s) from this thread on one page

AlliedModders (https://forums.alliedmods.net/index.php)

- Scripting Help (https://forums.alliedmods.net/forumdisplay.php?f=11)

- - Solved client_infochanged Efficiency (https://forums.alliedmods.net/showthread.php?t=319352)

edon1337

10-26-2019 18:48

client_infochanged Efficiency

Hey, I'm trying to optimize my plugin to max, and I've cached Name, SteamID and IP on client_authorized instead of retrieving them hundreds of times.

Now I have to deal with name changing, so I have this

PHP Code:


		
			
new g_szName[ 33 ][ 32 ];



public client_infochanged( id )

{

    static szNewName[ MAX_NAME_LENGTH ];

    get_user_info( id, "name", szNewName, charsmax( szNewName ) );

    

    if( ! equal( g_szName[ id ], szNewName ) )

    {

        copy( g_szName[ id ], charsmax( g_szName[ ] ), szNewName );

    }

    return PLUGIN_CONTINUE;

}

Is there any optimization I could do to it? I was using this

PHP Code:


		
			
new g_szName[ 33 ][ 32 ];



public client_infochanged( id )

{

    new szNewName[ MAX_NAME_LENGTH ];

    get_user_info( id, "name", szNewName, charsmax( szNewName ) );

    

    copy( g_szName[ id ], charsmax( g_szName[ ] ), szNewName );

}

And my server was going crazy, everyone was overflowing, then I added the check and then static, which seems good.

Natsheh

10-26-2019 19:05

Re: client_infochanged Efficiency

since you asked for optimization

PHP Code:


		
			
new g_szName[ 33 ][ 32 ];

public client_infochanged( id )



    get_user_info( id, "name", g_szName[0], charsmax(g_szName[]) );

    

    copy( g_szName[ id ], charsmax( g_szName[ ] ), g_szName[0]);

}

not a big deal your code also looks fine not sure what do you mean with overflowing that shouldn't affect such issue.

georgik57

10-26-2019 19:09

Re: client_infochanged Efficiency

client_infochanged is a pre event and it triggers for other things too besides name.
get_user_info gets the "name" cvar from the client side, which can be different from the one server-sided.
Use this instead:

PHP Code:


		
			
    register_forward(FM_ClientUserInfoChanged, "fwFmClientUserInfoChanged", 1)

PHP Code:


		
			
public fwFmClientUserInfoChanged(const iID)//, const iIDBuffer
{
    if (!is_user_connected(iID))
        return;
    
    get_user_name(iID, g_szName[iID], charsmax(g_szName[]))
}

E1_531G

10-26-2019 19:39

Re: client_infochanged Efficiency

The main thing: infochanged is not only about the name.
You have to check if it is the name that was changed or other info.

Bugsy

10-26-2019 20:06

Re: client_infochanged Efficiency

Here's a potential solution. For some reason it will repeat the forward based on the number of times you've changed your name, but at least ClientUserInfoChanged wouldn't be getting spammed for just hooking name change.

PHP Code:


		
			

#include <amxmodx>
#include <fakemeta>

new const Version[] = "0.1";

#define MAX_PLAYERS 32

new g_szName[ MAX_PLAYERS + 1 ][ 32 ];
new g_iInfoChangedFwd;

public plugin_init() 
{
    register_plugin( "Name Change Hook" , Version , "bugsy" );
    
    register_message( get_user_msgid( "SayText" ) , "msg_SayText" );
}

public msg_SayText( msg_id , msg_dest , msg_entity ) 
{
    new szArg2[ 32 ];

    get_msg_arg_string( 2 , szArg2 , charsmax( szArg2 ) );
    
    if ( equal( szArg2 , "#Cstrike_Name_Change" ) )
    {
        g_iInfoChangedFwd = register_forward( FM_ClientUserInfoChanged , "ClientUserInfoChanged" , 1 );
    }
}

public ClientUserInfoChanged( id )
{
    if ( is_user_connected( id ) )
    {
        get_user_name( id , g_szName[ id ] , charsmax( g_szName[] ) );
        unregister_forward( FM_ClientUserInfoChanged , g_iInfoChangedFwd , 1 );
        
        client_print( id , print_chat , "*TEST* Name changed to [%s]" , g_szName[ id ] );
    }
}

edon1337

10-26-2019 20:22

Re: client_infochanged Efficiency

Quote:

Originally Posted by Natsheh (Post 2671062)

since you asked for optimization

PHP Code:


		
			
new g_szName[ 33 ][ 32 ];

public client_infochanged( id )



    get_user_info( id, "name", g_szName[0], charsmax(g_szName[]) );

    

    copy( g_szName[ id ], charsmax( g_szName[ ] ), g_szName[0]);

}

not a big deal your code also looks fine not sure what do you mean with overflowing that shouldn't affect such issue.

Try it, not sure if it'll overflow in a public server, but in Zombie Escape, it messed up the server.

Quote:

Originally Posted by georgik57 (Post 2671063)

Use this instead:

PHP Code:


		
			
    register_forward(FM_ClientUserInfoChanged, "fwFmClientUserInfoChanged", 1)

PHP Code:


		
			
public fwFmClientUserInfoChanged(const iID)//, const iIDBuffer

{

    if (!is_user_connected(iID))

        return;

    

    get_user_name(iID, g_szName[iID], charsmax(g_szName[]))

}

Thank you, I entirely forgot about this forward.

BTW, I'm using this in plugin #1 (I'm doing this so I can have old and new name in log)

PHP Code:


		
			
public fw_ClientUserInfoChanged( id )

{

    static szNewName[ MAX_NAME_LENGTH ];

    get_user_name( id, szNewName, charsmax( szNewName ) );

    

    if( g_iConfig[ NAME_CHANGE_LOG ] )

    {

        send_message( 0, LOG, false, "%L", LANG_PLAYER, "NAME_CHANGE_LOG", g_szName[ id ], g_szAuthid[ id ], g_szIp[ id ], szNewName );

    }

    copy( g_szName[ id ], charsmax( g_szName[ ] ), szNewName );

}

And this in plugin #2

PHP Code:


		
			
public fw_ClientUserInfoChanged( id )

{

    get_user_name( id, g_szName[ id ], charsmax( g_szName[ ] ) );

}

I'll report if it overflows again.

edon1337

10-27-2019 05:34

Re: client_infochanged Efficiency

Quote:

Originally Posted by Bugsy (Post 2671079)

PHP Code:


		
			

#include <amxmodx>
#include <fakemeta>

new const Version[] = "0.1";

#define MAX_PLAYERS 32

new g_szName[ MAX_PLAYERS + 1 ][ 32 ];
new g_iInfoChangedFwd;

public plugin_init() 
{
    register_plugin( "Name Change Hook" , Version , "bugsy" );
    
    register_message( get_user_msgid( "SayText" ) , "msg_SayText" );
}

public msg_SayText( msg_id , msg_dest , msg_entity ) 
{
    new szArg2[ 32 ];

    get_msg_arg_string( 2 , szArg2 , charsmax( szArg2 ) );
    
    if ( equal( szArg2 , "#Cstrike_Name_Change" ) )
    {
        g_iInfoChangedFwd = register_forward( FM_ClientUserInfoChanged , "ClientUserInfoChanged" , 1 );
    }
}

public ClientUserInfoChanged( id )
{
    if ( is_user_connected( id ) )
    {
        get_user_name( id , g_szName[ id ] , charsmax( g_szName[] ) );
        unregister_forward( FM_ClientUserInfoChanged , g_iInfoChangedFwd );
        
        client_print( id , print_chat , "*TEST* Name changed to [%s]" , g_szName[ id ] );
    }
}

This was the best solution, thanks.
Georgik's way was also good, but FM_ClientUserInfoChanged got called on connection, meanwhile your code only got called when player changed name.

OciXCrom

10-31-2019 09:52

Re: client_infochanged Efficiency

Quote:

Originally Posted by Bugsy

For some reason it will repeat the forward based on the number of times you've changed your name

The reason why this is happening is because you forgot to set the last argument in unregister_forward to 1. Right now it doesn't match with the original registered forward, so it's never getting unregistered in the first place, resulting in the function getting called multiple times.

Setting the argument to 1 fixes the problem.

Thanks for this, I implemented it in my rank system.

edon1337

11-02-2019 16:31

Re: client_infochanged Efficiency

Quote:

Originally Posted by OciXCrom (Post 2671477)

Actually, Bugsy's way is the only working way, I tried all of the options.

register_forward with last arg 1, unregister_forward with arg 1, name doesn't update.
register_forward with last arg 0, unregister_forward with arg 1, name doesn't update.
register_forward with last arg 0, unregister_forward with arg 0, name doesn't update.

register_forward with last arg 1, unregister_forward with arg 0, works.

Natsheh

11-02-2019 16:52

Re: client_infochanged Efficiency

3rd argument in unregister_forward should be removed it doesnt make any sense.

All times are GMT -4. The time now is 07:34.

Page 1 of 2

Show 40 post(s) from this thread on one page