AlliedModders - Edit this plugin

AlliedModders (https://forums.alliedmods.net/index.php)

- Suggestions / Requests (https://forums.alliedmods.net/forumdisplay.php?f=12)

- - Edit this plugin (https://forums.alliedmods.net/showthread.php?t=347435)

Edit this plugin

I use this plugin for my 35hp server but I don't know why all people with ADMIN_IMMUNITY can select any knife whether they have the required level or not. How can I solve this?

PHP Code:


		
			
public KnifeSkinsMenu(id) { 
    
    new szItem[256], szAlien[50], szEllium[50], szDark[50], szTransparent[50], szGenuine[50], szHunt[50], szShadow[50], szSlaughterer[50], szKatana[50], szAssasins[50],
    szLightsaber[50], szWolverine[50], szProton[50];
    
    new level = iLevel[id] > 0 ? iLevel[id] : 1;
    
    new xp = level * StartedLevel;
    
    if( iLevel[id] > 0 )
    {
        xp +=  ( xp * 4 / 2 );
    }
    
    formatex(szItem, charsmax(szItem), "\w[ \r%s \w] \yKnife Skins Menu \rv%s^n\yYour Level: \r%d \w- \yYour XP: \r%d\w/\r%d\w.^n\yPage:\r", g_VAULTNAME, VERSION,iLevel[id],iXp[id], xp);
    formatex(szAlien, charsmax(szAlien),"%s", iLevel[id] >= 1 ? "\wAlien Knife [\yUNLOCKED\w]" : "\d???? ????? [\rLEVEL 1 REQUIRE\d]");
    formatex(szEllium, charsmax(szEllium),"%s", iLevel[id] >= 2 ? "\wEllium Knife [\yUNLOCKED\w]" : "\d?????? ?????? [\rLEVEL 2 REQUIRE\d]");
    formatex(szDark, charsmax(szDark),"%s", iLevel[id] >= 3 ? "\wDark Dagger [\yUNLOCKED\w]" : "\d???? ?????? [\rLEVEL 3 REQUIRE\d]");
    formatex(szTransparent, charsmax(szTransparent),"%s", iLevel[id] >= 4 ? "\wTransparent Knife [\yUNLOCKED\w]" : "\d??????????? ????? [\rLEVEL 4 REQUIRE\d]");
    formatex(szGenuine, charsmax(szGenuine),"%s", iLevel[id] >= 5 ? "\wGenuine Dagger [\yUNLOCKED\w]" : "\d??????? ?????? [\rLEVEL 5 REQUIRE\d]");
    formatex(szHunt, charsmax(szHunt),"%s", iLevel[id] >= 6 ? "\wHunt Blade [\yUNLOCKED\w]" : "\d???? ????? [\rLEVEL 6 REQUIRE\d]");
    formatex(szShadow, charsmax(szShadow),"%s", iLevel[id] >= 7 ? "\wShadow Blade [\yUNLOCKED\w]" : "\d?????? ????? [\rLEVEL 7 REQUIRE\d]");
    formatex(szSlaughterer, charsmax(szSlaughterer),"%s", iLevel[id] >= 8 ? "\wSlaughterer Axe [\yUNLOCKED\w]" : "\d??????????? ??? [\rLEVEL 8 REQUIRE\d]");
    formatex(szKatana, charsmax(szKatana),"%s", iLevel[id] >= 9 ? "\wGolden Katana [\yUNLOCKED\w]" : "\d?????? ?????? [\rLEVEL 9 REQUIRE\d]");
    formatex(szAssasins, charsmax(szAssasins),"%s", iLevel[id] >= 10 ? "\wAssasin's Blade [\yUNLOCKED\w]" : "\d???????? ????? [\rLEVEL 10 REQUIRE\d]");
    formatex(szLightsaber, charsmax(szLightsaber),"%s", iLevel[id] >= 11 ? "\wLightsaber [\yUNLOCKED\w]" : "\d?????????? [\rLEVEL 11 REQUIRE\d]");
    formatex(szWolverine, charsmax(szWolverine),"%s", iLevel[id] >= 12 ? "\wBloody Wolverine Claws [\yUNLOCKED\w]" : "\d?????? ????????? ????? [\rLEVEL 12 REQUIRE\d]");
    formatex(szProton, charsmax(szProton),"%s", iLevel[id] >= 13 ? "\wProton Axe [\yUNLOCKED\w]" : "\d?????? ??? [\rLEVEL 13 REQUIRE\d]");
    
    new menu = menu_create( szItem, "KnifeSkinsMenu_Handler" ); 
    menu_additem(menu, "\wNormal Knife [\yUNLOCKED\w]", "", 0 );
    menu_additem(menu, szAlien, "", iLevel[id] >= 1 ? 0 : 1);
    menu_additem(menu, szEllium, "", iLevel[id] >= 2 ? 0 : 1);
    menu_additem(menu, szDark, "", iLevel[id] >= 3 ? 0 : 1);
    menu_additem(menu, szTransparent, "", iLevel[id] >= 4 ? 0 : 1);
    menu_additem(menu, szGenuine, "", iLevel[id] >= 5 ? 0 : 1);
    menu_additem(menu, szHunt, "", iLevel[id] >= 6 ? 0 : 1);
    menu_additem(menu, szShadow, "", iLevel[id] >= 7 ? 0 : 1);
    menu_additem(menu, szSlaughterer, "", iLevel[id] >= 8 ? 0 : 1);
    menu_additem(menu, szKatana, "", iLevel[id] >= 9 ? 0 : 1);
    menu_additem(menu, szAssasins, "", iLevel[id] >= 10 ? 0 : 1);
    menu_additem(menu, szLightsaber, "", iLevel[id] >= 11 ? 0 : 1);
    menu_additem(menu, szWolverine, "", iLevel[id] >= 12 ? 0 : 1);
    menu_additem(menu, szProton, "", iLevel[id] >= 13 ? 0 : 1);
    
    menu_setprop(menu, MPROP_EXIT, MEXIT_ALL );
    menu_display(id, menu, 0 );
    
    return PLUGIN_HANDLED;
}

Re: Edit this plugin

PHP Code:


		
			
#include <amxmodx>

new _menu_items[][] =
{
    "\wAlien Knife [\yUNLOCKED\w]",
    "\wEllium Knife [\yUNLOCKED\w]",
    "\wDark Dagger [\yUNLOCKED\w]",
    "\wTransparent Knife [\yUNLOCKED\w]",
    "\wGenuine Dagger [\yUNLOCKED\w]",
    "\wHunt Blade [\yUNLOCKED\w]",
    "\wShadow Blade [\yUNLOCKED\w]",
    "\wSlaughterer Axe [\yUNLOCKED\w]",
    "\wGolden Katana [\yUNLOCKED\w]",
    "\wAssasin's Blade [\yUNLOCKED\w]",
    "\wLightsaber [\yUNLOCKED\w]",
    "\wBloody Wolverine Claws [\yUNLOCKED\w]",
    "\wProton Axe [\yUNLOCKED\w]"
}

public KnifeSkinsMenu(id)
{
    new szItem[256], xp = max(1, iLevel[id]) * StartedLevel
    
    if(iLevel[id])
        xp += ( xp * 4 / 2 )
    
    formatex(szItem, charsmax(szItem), "\w[ \r%s \w] \yKnife Skins Menu \rv%s^n\yYour Level: \r%d \w- \yYour XP: \r%d\w/\r%d\w.^n\yPage:\r", g_VAULTNAME, VERSION,iLevel[id],iXp[id], xp);
    
    new menu = menu_create( szItem, "KnifeSkinsMenu_Handler" ); 
    menu_additem(menu, "\wNormal Knife [\yUNLOCKED\w]");
    
    for (new i = 0; i < sizeof(_menu_items); i++)
        menu_additem(menu, iLevel[id] >= i + 1 ? _menu_items[i] : fmt("\d???? ????? [\rLEVEL %d REQUIRE\d]", i + 1))
    
    menu_display(id, menu, 0)
}

Re: Edit this plugin

The problem is that you're misunderstanding how the "paccess" parameter in menu_additem() works. A value of 1 for this parameter allows anybody with immunity to access that item. The values that are intended to be used in this parameter are found in amxconst.inc here. You can see that the admin immunity flag (ADMIN_IMMUNITY) is a value of 1.

To do what you want, you're actually looking for callbacks. Callbacks are used to determine if you want an item enabled or disabled when this menu is shown to the player. So, in this case, you want "paccess" to always be zero and then create your callback:

PHP Code:


		
			
public showMyMenu(id)
{
    new menu = menu_create()
    new cbLevelCheck = menu_makecallback("cbLevelCheck")

    menu_additem(menu, "Name(1)", "Info", 0, cbLevelCheck)
    .
    .
    .
    menu_additem(menu, "Name(n)", "Info", 0, cbLevelCheck)
    menu_display(id, menu, 0)
}

public cbLevelCheck(id, menu, item)
{
    // Use any logic here to determine if the item should be enabled or disabled
    if( iLevel[id] >= item )
    {
        return ITEM_ENABLED
    }

    return ITEM_DISABLED
}

Quote:

Originally Posted by bigdaddy424 (Post 2821618)

PHP Code:


		
			
#include <amxmodx>

new _menu_items[][] =
{
    "\wAlien Knife [\yUNLOCKED\w]",
    "\wEllium Knife [\yUNLOCKED\w]",
    "\wDark Dagger [\yUNLOCKED\w]",
    "\wTransparent Knife [\yUNLOCKED\w]",
    "\wGenuine Dagger [\yUNLOCKED\w]",
    "\wHunt Blade [\yUNLOCKED\w]",
    "\wShadow Blade [\yUNLOCKED\w]",
    "\wSlaughterer Axe [\yUNLOCKED\w]",
    "\wGolden Katana [\yUNLOCKED\w]",
    "\wAssasin's Blade [\yUNLOCKED\w]",
    "\wLightsaber [\yUNLOCKED\w]",
    "\wBloody Wolverine Claws [\yUNLOCKED\w]",
    "\wProton Axe [\yUNLOCKED\w]"
}

public KnifeSkinsMenu(id)
{
    new szItem[256], xp = max(1, iLevel[id]) * StartedLevel
    
    if(iLevel[id])
        xp += ( xp * 4 / 2 )
    
    formatex(szItem, charsmax(szItem), "\w[ \r%s \w] \yKnife Skins Menu \rv%s^n\yYour Level: \r%d \w- \yYour XP: \r%d\w/\r%d\w.^n\yPage:\r", g_VAULTNAME, VERSION,iLevel[id],iXp[id], xp);
    
    new menu = menu_create( szItem, "KnifeSkinsMenu_Handler" ); 
    menu_additem(menu, "\wNormal Knife [\yUNLOCKED\w]");
    
    for (new i = 0; i < sizeof(_menu_items); i++)
        menu_additem(menu, iLevel[id] >= i + 1 ? _menu_items[i] : fmt("\d???? ????? [\rLEVEL %d REQUIRE\d]", i + 1))
    
    menu_display(id, menu, 0)
}

I think you should probably do some testing first (e.g. learn how the menu_additem() function works). Also, you didn't even attempt to answer his question. At least explain that nothing you're posting has anything to do with the actual question.

Also, "if( iLevel[id] > 0 )" and "if(iLevel[id])" are two very different functionality.

Re: Edit this plugin

Quote:

Originally Posted by fysiks (Post 2821630)

PHP Code:


		
			
public showMyMenu(id)

{

    new menu = menu_create()

    new cbLevelCheck = menu_makecallback("cbLevelCheck")



    menu_additem(menu, "Name(1)", "Info", 0, cbLevelCheck)

    .

    .

    .

    menu_additem(menu, "Name(n)", "Info", 0, cbLevelCheck)

    menu_display(id, menu, 0)

}



public cbLevelCheck(id, menu, item)

{

    // Use any logic here to determine if the item should be enabled or disabled

    if( iLevel[id] >= item )

    {

        return ITEM_ENABLED

    }



    return ITEM_DISABLED

}

You can take a look at the New Menus Tutorial to learn more neat features.

P.S. You need to make your title descriptive (it's a rule here) so that people can have a general idea of what your post is about without having to read the entire post.

I think you should probably do some testing first (e.g. learn how the menu_additem() function works). Also, you didn't even attempt to answer his question. At least explain that nothing you're posting has anything to do with the actual question.

Also, "if( iLevel[id] > 0 )" and "if(iLevel[id])" are two very different functionality.

I will try to do it that way. Also, I promise to be more descriptive the next time. Thank you very much for the help!