AlliedModders - [INC] StudioHdr - Entity Model Information

AlliedModders (https://forums.alliedmods.net/index.php)

- Snippets and Tutorials (https://forums.alliedmods.net/forumdisplay.php?f=112)

- - [INC] StudioHdr - Entity Model Information (https://forums.alliedmods.net/showthread.php?t=333857)

[INC] StudioHdr - Entity Model Information

StudioHdr - Entity Model Information

Description:
StudioHdr is a SourcePawn library (.inc) that lets developers get information about entity models. :bee:

Credits:
Феникс#1337 (Phoenix): For the base code:

Spoiler

PHP Code:


		
			
methodmap CStudioHdr

{

    public int GetNumBodyGroups()

    {

        int m_pStudioHdr = LoadFromAddress(view_as<Address>(this), NumberType_Int32);

        

        return LoadFromAddress(view_as<Address>(m_pStudioHdr + 232), NumberType_Int32);

    }

    

    public int GetBodygroupCount(int iGroup)

    {

        int m_pStudioHdr = LoadFromAddress(view_as<Address>(this), NumberType_Int32);

        

        // if(iGroup < this.GetNumBodyGroups())

        if(iGroup < LoadFromAddress(view_as<Address>(m_pStudioHdr + 232), NumberType_Int32))

        {

            int pbodypart = m_pStudioHdr + LoadFromAddress(view_as<Address>(m_pStudioHdr + 236), NumberType_Int32) + 16 * iGroup;

            

            // nummodels - 4

            return LoadFromAddress(view_as<Address>(pbodypart + 4), NumberType_Int32);

        }

        

        return 0;

    }

    

    public void SetBodygroup(int& body, int iGroup, int iValue)

    {

        int m_pStudioHdr = LoadFromAddress(view_as<Address>(this), NumberType_Int32);

        

        // if(iGroup < this.GetNumBodyGroups())

        if(iGroup < LoadFromAddress(view_as<Address>(m_pStudioHdr + 232), NumberType_Int32))

        {

            int pbodypart = m_pStudioHdr + LoadFromAddress(view_as<Address>(m_pStudioHdr + 236), NumberType_Int32) + 16 * iGroup;

            

            // nummodels - 4

            int nummodels = LoadFromAddress(view_as<Address>(pbodypart + 4), NumberType_Int32);

            if(nummodels > iValue)

            {

                int base = LoadFromAddress(view_as<Address>(pbodypart + 8), NumberType_Int32);

                

                body += (iValue - body / base % nummodels) * base;

            }

        }

    }

}



CStudioHdr CBaseAnimating_GetModelPtr(int iEnt)

{

    // CBaseAnimating::GetModelPtr - по нормальному нужно вызывать

    // Но делаем так [url]https://github.com/qubka/Zombie-Plague/blob/67266c6b90d88180264745ccebff709531c722d0/gamedata/plugin.turret.txt#L8[/url]

    static int iStudioHdrOffs = 0;

    

    if(iStudioHdrOffs == 0)

    {

        iStudioHdrOffs = FindSendPropInfo("CBaseAnimating", "m_hLightingOrigin") + 68;

    }

    

    return view_as<CStudioHdr>(GetEntData(iEnt, iStudioHdrOffs));

}





{

    int iEnt;

    

    CStudioHdr pstudiohdr = CBaseAnimating_GetModelPtr(iEnt);

    

    int iBody, int iGroups = pstudiohdr.GetNumBodyGroups();

    

    for(int i = 0; i < iGroups; i++)

    {

        pstudiohdr.SetBodygroup(iBody, i, GetRandomInt(0, pstudiohdr.GetBodygroupCount(i) - 1));

    }

    

    SetEntProp(iEnt, Prop_Send, "m_nBody", iBody);

}

KoNLiG: For letting me scream at him while the code didn't work and crashed the server.

List of features:

Quote:

Spoiler

Body Parts
• `GetBodyPart()` - Get a specific body part object by index.
• `FindBodyPart()` - Find body part index by name.
• Get model 'NumBodyParts'.

Spoiler

Attachments
• `GetAttachment()` - Get a specific attachment object by index.
• `FindAttachment()` - Find an attachment index by name.
• Get model 'AttachmentCount'.

Spoiler

Pose Parameters
• `GetPoseParameter()` - Get a specific pose parameter object by index.
• `FindPoseParameter()` - Find a pose parameter index by name.
• Get model 'NumPoseParameters'.

Spoiler

Bone methodmap
• `GetName()` - Get the name of the body part.
• `GetPos()` - Get the position of the bone (relative to model).

Hitbox methodmap
• `bone` - The related bone of the specific hitbox.
• `group` - The intersection group of the specific hitbox.
bounding box, or the ends of the capsule if flCapsuleRadius > 0
• `bbmin`
• `bbmax`
• `GetAngOffsetOrientation()` - Gets the angle offset orientation.
• `flCapsuleRadius` - The radius of the capsule (if not a capsule = 0.0)

HitboxSet methodmap
• `GetHitbox()` - Get a specific hitbox object by index.
• `NumHitboxs` - Number of hitboxes in the hitbox set.

BodyPart methodmap
• `GetName()` - Get the name of the body part.
• `base` - The base value of the body part.
• `nummodels` - Number of sub-models.

Spoiler

Attachment methodmap
• `GetName()` - Get the name of the attachment.

Pose Parameter methodmap
• `GetName()` - Get the name of the pose parameter.
• `start` - The minimum value of the pose parameter.
• `end` - The maximum value of the pose parameter.

Note:
This include was tested only in CS:GO (Linux).
This should work in any source engine based game (i am pretty sure).
If you want to support other games (and you can test), please write here below or add me on Discord!

Links:

GitHub Repository

Re: [INC] StudioHdr - Entity Model Information

Some code examples:

PHP Code:


		
			
bool SetBodyGroup(int entity, int part, int value)
{
    // Get the current entity body.
    int body = GetEntProp(entity, Prop_Send, "m_nBody");
    
    // Get the StudioHDR
    StudioHdr studiohdr = GetEntityStudioHdr(entity);
    
    // Get the new body value
    if (!studiohdr.CalculateNewBodyGroup(body, part, value))
    {
        return false;
    }
    
    // Set the new body value
    SetEntProp(entity, Prop_Send, "m_nBody", body);
    
    return true;
}

int GetEntitySkinCount(int entity)
{
    return GetEntityStudioHdr(entity).SkinFamiliesCount;
}

bool GetEntityPoseParameterBounds(int entity, int pose_parameter_index, float bounds[2])
{
    // Get the StudioHDR
    StudioHdr studiohdr = GetEntityStudioHdr(entity);
    
    // Get entity pose parameter.
    PoseParameter pose_parameter = studiohdr.GetPoseParameter(pose_parameter_index);
    
    if (pose_parameter == NULL_POSE_PARAMETER)
    {
        return false;
    }
    
    bounds[0] = pose_parameter.start;
    bounds[1] = pose_parameter.end;
    
    return true;
}

bool GetEntityAttachmentName(int entity, int attachment_index, char[] name, int name_length)
{
    // Get the StudioHDR
    StudioHdr studiohdr = GetEntityStudioHdr(entity);
    
    // Get attachment
    Attachment attachment = studiohdr.GetAttachment(attachment_index);
    
    // if the `.GetName` function executed successfully.
    return attachment.GetName(name, name_length);
}

void ResetPoseParameters(int entity)
{
    // Get the StudioHDR
    StudioHdr studiohdr = GetEntityStudioHdr(entity);
    
    // Buffers
    char name[64];
    PoseParameter pose_parameter;
    
    for (int current_pose, max_pose = studio_hdr.NumPoseParameters; current_pose < max_pose; current_pose++)
    {
        // Get pose parameter by 
        pose_parameter = studio_hdr.GetPoseParameter(current_pose);
        
        // Set pose parameter to the start value.
        SetEntPropFloat(entity, Prop_Data, "m_flPoseParameter", pose_parameter.start, current_pose);
    }
}

PoseParameter GetPoseParameterByName(int entity, const char[] pose_parameter_name)
{
    // Get the StudioHDR
    StudioHdr studiohdr = GetEntityStudioHdr(entity);
    
    // Find it by the name.
    int index = studio_hdr.FindPoseParameter(pose_parameter_name);
    if (index == -1)
    {
        return NULL_POSE_PARAMETER;
    }
    
    return studio_hdr.GetPoseParameter(index);
}

Re: [INC] StudioHdr - Entity Model Information

That's saves my life haha, nice release

Re: [INC] StudioHdr - Entity Model Information

This looks cool. Nice one, LuqS!

Re: [INC] StudioHdr - Entity Model Information

Quote:

Originally Posted by Benito (Post 2754992)

That's saves my life haha, nice release

Quote:

Originally Posted by Psyk0tik (Post 2754998)

This looks cool. Nice one, LuqS!

Thanks!

Re: [INC] StudioHdr - Entity Model Information

18/8/2021 Update:

Quote:

StudioHdr methodmap
Bones
• `GetBone()` - Get a specific bone object by index.
• `FindBone()` - Find bone index by name.
• Get model 'NumBones'.

Hitbox Sets
• `GetHitboxSet()` - Get a specific hitbox set object by index.
• Get model 'NumHitboxSets'.

Bone methodmap
• `GetName()` - Get the name of the body part.
• `GetPos()` - Get the position of the bone (relative to model).

HitboxSet methodmap
• `GetHitbox()` - Get a specific hitbox object by index.
• `NumHitboxs` - Number of hitboxes in the hitbox set.

Hitbox methodmap
• `bone` - The related bone of the specific hitbox.
• `group` - The intersection group of the specific hitbox.
bounding box, or the ends of the capsule if flCapsuleRadius > 0
• `bbmin`
• `bbmax`
• `GetAngOffsetOrientation()` - Gets the angle offset orientation.
• `flCapsuleRadius` - The radius of the capsule (if not a capsule = 0.0)

Re: [INC] StudioHdr - Entity Model Information

Quote:

Originally Posted by LuqS (Post 2755469)

18/8/2021 Update:

Nice one, good job !

Re: [INC] StudioHdr - Entity Model Information

Coming soon :wink:

https://i.imgur.com/ICCRdAA.png

Re: [INC] StudioHdr - Entity Model Information

wow, that is really great!