AlliedModders - (Request) Is still impossible to pick up more than 1 weapon?

AlliedModders (https://forums.alliedmods.net/index.php)

- Suggestions / Requests (https://forums.alliedmods.net/forumdisplay.php?f=12)

- - (Request) Is still impossible to pick up more than 1 weapon? (https://forums.alliedmods.net/showthread.php?t=337539)

(Request) Is still impossible to pick up more than 1 weapon?

With amx 1.9 and later, i was wondering if more than 1 primary weapon was still impossible to make?

this plugin does not work properly:

https://forums.alliedmods.net/showthread.php?t=50926

Re: (Request) Is still impossible to pick up more than 1 weapon?

Possible

PHP Code:


		
			

#include <amxmodx>
#include <hamsandwich>
#include <fun>

public plugin_init()
{
    RegisterHam( Ham_Spawn , "player" , "Spawn" , true );
}

public Spawn( iPlayer )
{
    if ( is_user_alive( iPlayer ) )
    {
        give_item( iPlayer , "weapon_awp" );
        give_item( iPlayer , "weapon_m4a1" );
    }
}

Re: (Request) Is still impossible to pick up more than 1 weapon?

Quote:

Originally Posted by Bugsy (Post 2778050)

Possible

PHP Code:


		
			


#include <amxmodx>

#include <hamsandwich>

#include <fun>



public plugin_init()

{

    RegisterHam( Ham_Spawn , "player" , "Spawn" , true );

}



public Spawn( iPlayer )

{

    if ( is_user_alive( iPlayer ) )

    {

        give_item( iPlayer , "weapon_awp" );

        give_item( iPlayer , "weapon_m4a1" );

    }

}

Thats seems great! but i was refering to be able to pick up whatever weapon is on the floor and have two primary and two secondary weapons as max.

Re: (Request) Is still impossible to pick up more than 1 weapon?

Yes, I've written this before, try searching

Re: (Request) Is still impossible to pick up more than 1 weapon?

Quote:

Originally Posted by Bugsy (Post 2778114)

Yes, I've written this before, try searching

haha don't punish me i always search, the thing is it is not a main plugin you developed and cannot see it on your profile, but i will look in the advanced search, if you say you developed then there must be out there. :)

Re: (Request) Is still impossible to pick up more than 1 weapon?

Quote:

Originally Posted by Bugsy (Post 2778135)

https://forums.alliedmods.net/showpo...1&postcount=19

Tested it a little bit! seems awesome!

Only problem i don't seem to be able to pick up C4 once i drop it! terrible bug :(

Edit: how to limit pickups to 2 primary and 2 secondary?

Re: (Request) Is still impossible to pick up more than 1 weapon?

I'll fix the c4 issue and add cvars so you can set primary/secondary limits

Re: (Request) Is still impossible to pick up more than 1 weapon?

Quote:

Originally Posted by Bugsy (Post 2778178)

I'll fix the c4 issue and add cvars so you can set primary/secondary limits

Thank you :)

Re: (Request) Is still impossible to pick up more than 1 weapon?

Some credit to Arkshine for his weapon from weaponbox to player code. Not thoroughly tested, and not sure off the top of my head what the slot maximums are. I tested only up to 3 in slots 1 and 2.

Edit: Fixed shield issue

PHP Code:


		
			
#include <amxmodx>
#include <fakemeta>
#include <cstrike>
#include <engine>
#include <hamsandwich>

new const Version[] = "0.3";

enum WeaponSlots
{
    Slot1 = 1,
    Slot2
}
new g_pMaxWeapons[ WeaponSlots ];

public plugin_init() 
{
    register_plugin( "Multiple Weapons" , Version , "bugsy" );
   
    register_touch( "weaponbox" , "player" , "TouchWeaponbox" );
    register_forward( FM_SetModel , "SetModel" );
    
    g_pMaxWeapons[ Slot1 ] = register_cvar( "mw_maxslot1" , "2" );
    g_pMaxWeapons[ Slot2 ] = register_cvar( "mw_maxslot2" , "2" );
}

public SetModel( iEntity , const szModel[] )
{
    new szClassname[ 32 ] , iWeaponEntID;
    
    pev( iEntity , pev_classname , szClassname , charsmax( szClassname ) );
    
    if ( equal ( szClassname , "weaponbox" ) )
    {
        if ( pev_valid( ( iWeaponEntID = GetWeaponEntityFromWeaponbox( iEntity ) ) ) )
        {
            set_pev( iEntity , pev_iuser2 , cs_get_user_bpammo( pev( iEntity , pev_owner ) , cs_get_weapon_id( iWeaponEntID ) ) );
        }
    }
} 

public TouchWeaponbox( iEntity , id )
{    
    if ( !( pev( iEntity , pev_flags ) & FL_ONGROUND ) ) 
        return PLUGIN_CONTINUE;
        
    new iWeaponIndex , WeaponSlots:iSlot , iWeaponEntID;

    if ( ( iWeaponEntID = GetWeaponEntityFromWeaponbox( iEntity ) ) > 0 )
    {
        iWeaponIndex = cs_get_weapon_id( iWeaponEntID );
        
        if ( ( CSW_P228 <= iWeaponIndex <= CSW_P90 ) && ( iWeaponIndex != CSW_C4 ) && !cs_get_user_shield( id ) && !user_has_weapon( id , iWeaponIndex ) )
        {
            iSlot = WeaponSlots:ExecuteHam( Ham_Item_ItemSlot , iWeaponEntID );

            if ( GetWeaponCountBySlot( id , iSlot ) < get_pcvar_num( g_pMaxWeapons[ iSlot ] ) )
            {
                if ( ExecuteHam( Ham_AddPlayerItem , id , iWeaponEntID ) )
                {
                    ExecuteHam( Ham_Item_AttachToPlayer , iWeaponEntID , id );
                    cs_set_user_bpammo( id , iWeaponIndex , pev( iEntity , pev_iuser2 ) );
                    emit_sound( id , CHAN_ITEM , "items/gunpickup2.wav" , VOL_NORM , ATTN_NORM , 0 , PITCH_NORM );
                    set_pev( iEntity , pev_flags, pev( iEntity , pev_flags ) | FL_KILLME );
                }
            }
            
            return PLUGIN_HANDLED;
        }
    }
    
    return PLUGIN_CONTINUE;
}

GetWeaponCountBySlot( id , WeaponSlots:iSlot )
{    
    new iWeapons , iEntity;
    new const m_rgpPlayerItems_Player[ 6 ] = { 367 , 368 , 369 , 370 , 371 , 372 };
    const m_pNext = 42;
    
    iEntity = get_pdata_cbase( id , m_rgpPlayerItems_Player[ _:iSlot ] );

    while ( iEntity > 0 )
    {
        iWeapons++;
        iEntity = get_pdata_cbase( iEntity , m_pNext );
    }
    
    return iWeapons;
}

GetWeaponEntityFromWeaponbox( iWeaponBox )
{
    new const m_rgpPlayerItems_Weaponbox[ 6 ] = { 34 , 35 , ... };
    new iWeaponEntID;

    for ( new WeaponSlots:iSlot = Slot1 ; iSlot <= Slot2 ; iSlot++ )
    {
        if ( ( iWeaponEntID = get_pdata_cbase( iWeaponBox , m_rgpPlayerItems_Weaponbox[ 0 ] + _:iSlot ) ) > 0 )
            break;
    }    
    
    return ( iWeaponEntID > 0 ) ? iWeaponEntID : 0;
}