AlliedModders - [INC] Menu stocks

AlliedModders (https://forums.alliedmods.net/index.php)

- Snippets and Tutorials (https://forums.alliedmods.net/forumdisplay.php?f=112)

- - [INC] Menu stocks (https://forums.alliedmods.net/showthread.php?t=265325)

[INC] Menu stocks

This include allows you to pass a value (cell, float or string) to menu callback.

Just look at the example ;-) Download & GitHub.

PHP Code:


		
			
ShowMyMenu(iClient, iSecretValue)
{
    new Handle:hMenu = CreateMenu(MyMenu_Handler);

    SetMenuTitle(hMenu, "Choose your weapon:");
    AddMenuItem(hMenu, "weapon_m4a1", "M4A1");
    AddMenuItem(hMenu, "weapon_ak47", "AK-47");
    AddMenuItem(hMenu, "weapon_scout", "Scout");

    // here is the magic
    PushMenuCell(hMenu, "-MySecretValue-", iSecretValue);

    SetMenuExitBackButton(hMenu, true);
    DisplayMenu(hMenu, iClient, 30);
}

public MyMenu_Handler(Handle:hMenu, MenuAction:iAction, iClient, iKey)
{
    switch (iAction) {
        case MenuAction_Select: {
            new String:sWeapon[64];
            GetMenuItem(hMenu, iKey, sWeapon, sizeof(sWeapon));
            GivePlayerItem(iClient, sWeapon);

            // here is the magic
            new iSecretValue = GetMenuCell(hMenu, "-MySecretValue-");       

            PrintToConsole("Player %N has secret value = %d.", iClient, iSecretValue);
        }
        case MenuAction_End: {
            CloseHandle(hMenu);
        }
    }
}

Let's say, you need to pass a value from one menu to another

PHP Code:


		
			
public MyMenu_Handler(Handle:hMenu, MenuAction:iAction, iClient, iKey)
{
    switch (iAction) {
        case MenuAction_Select: {
            new String:sWeapon[64];
            GetMenuItem(hMenu, iKey, sWeapon, sizeof(sWeapon));
            GivePlayerItem(iClient, sWeapon);

            new Handle:hSubMenu = CreateMenu(MySubMenu_Handler);
            SetMenuTitle(hSubMenu, "Choose your HP:");
            AddMenuItem(hSubMenu, "35", "35 HP");
            AddMenuItem(hSubMenu, "100", "100 HP");
            AddMenuItem(hSubMenu, "300", "300 HP");

            // here is the magic
            CopyMenuAny(hMenu, hSubMenu, "-MySecretValue-");

            SetMenuExitBackButton(hSubMenu, true);
            DisplayMenu(hSubMenu, iClient, 30);
        }
        case MenuAction_End: {
            CloseHandle(hMenu);
        }
    }
}

Also notice function AddMenuItemFormat, which allows you to do

PHP Code:


		
			
AddMenuItemFormat(hMenu, "weapon_ak47", _, "AK-47 + %d ammo", 90);

// instead of

new String:sDisplay[64];
Format(sDisplay, sizeof(sDisplay), "AK-47 + %d ammo", 90);
AddMenuItem(hMenu, "weapon_ak47", sDisplay);

Re: [INC] Menu stocks

Vinnice made a 1.7 syntax version, I am gonna put that in GIT repository as another branch, but till then -> https://github.com/TryHardDood/Menu-stocks

Re: [INC] Menu stocks

Quote:

Originally Posted by redwerewolf (Post 2440103)

https://github.com/Drixevel/Menu-sto...enu-stocks.inc

Syntax update.

wrong branch~ https://github.com/Drixevel/Menu-sto...enu-stocks.inc

Re: [INC] Menu stocks

Quote:

Originally Posted by shavit (Post 2440231)

wrong branch~ https://github.com/Drixevel/Menu-sto...enu-stocks.inc

Fixed, thanks.

Re: [INC] Menu stocks

It's not truly 1.7 syntax, as it's still using Handle and AddMenuItem, but I'm just being picky since combining the 2 different syntax' annoys me

Re: [INC] Menu stocks

If it compiles with

PHP Code:


		
			
#pragma newdecls required

then it is new syntax compliant.

Re: [INC] Menu stocks

What about something like this? (not tested, but it compiles. Also, not sure what result retagging a typdef yields, but again, it compiles)

Spoiler

EDIT: I went ahead and tested it and it seems to be working perfectly, so i decided to port all of the stocks.

Spoiler

Code:

typedef SmartMenuHandler = function int(SmartMenu menu, MenuAction action, int param1, int param2);

methodmap SmartMenu __nullable__ < Menu {
    public SmartMenu(SmartMenuHandler handler) {
        return view_as<SmartMenu>(new Menu(view_as<MenuHandler>(handler)));
    }

    public void PushCell(const char[] id, any data) {
        char buffer[64];
        IntToString(view_as<int>(data), buffer, sizeof(buffer));
        this.AddItem(id, buffer, ITEMDRAW_IGNORE);
    }

    public any GetCell(const char[] id, any def_value = 0) {
        char info[64], data[64];
        for(int i = 0; i < this.ItemCount; i++) {
            this.GetItem(i, info, sizeof(info), _, data, sizeof(data));

            if(StrEqual(id, info)) {
                return StringToInt(data);
            }
        }

        return def_value;
    }

    public void PushFloat(const char[] id, float data) {
        char buffer[64];
        FloatToString(data, buffer, sizeof(buffer));
        this.AddItem(id, budder, ITEMDRAW_IGNORE);
    }

    public float GetFloat(const char[] id, float def_value) {
        char info[64], data[64];
        for(int i = 0; i < this.ItemCount; i++) {
            this.GetItem(i, info, sizeof(info), _, data, sizeof(data));

            if(StrEqual(id, info)) {
                return StringToFloat(data);
            }
        }

        return def_value;
    }

    public void PushString(const char[] id, const char[] data) {
        this.AddItem(id, data);
    }

    public bool GetString(const char[] id, char[] buffer, int maxlen, const char[] def_value = NULL_STRING) {
        char info[64], data[64];
        for(int i = 0; i < this.ItemCount; i++) {
            this.GetItem(i, info, sizeof(info), _, data, sizeof(data));

            if(StrEqual(info, id)) {
                strcopy(buffer, maxlen, data);
                return true;
            }
        }

        strcopy(buffer, maxlen, def_value);
        return false;
    }

    public bool AddItemFormat(const char[] info, int style = ITEMDRAW_DEFAULT, const char[] format, any ...) {
        char display[128];
        VFormat(display, sizeof(display), format, 4);

        return this.AddItem(info, display, style);
    }

    public void CopyAny(SmartMenu dest, const char[] id) {
        char info[64], data[64];
        for(int i = 0; i < this.ItemCount; i++) {
            this.GetItem(i, info, sizeof(info), _, data, sizeof(data));

            if(StrEqual(info, id)) {
                dest.AddItem(id, data, ITEMDRAW_IGNORE);
            }
        }
    }
}

It's used just like the Menu methodmap:

Code:

public void DisplaySuperSecretMenu(int client) {
    SmartMenu menu = new SmartMenu(MenuHandler);
    menu.SetTitle("Super Secret Menu");
    menu.ExitButton = true;

    menu.PushCell("super-secret-value", 5);
    menu.AddItem("1", "Option 1");
    menu.AddItem("2", "Option 2");

    menu.Display(client, MENU_TIME_FOREVER);
}

public int MenuHandler(SmartMenu menu, MenuAction action, int param1, int param2) {
    switch(action) {
        case(MenuAction_Select): {
            int secret_value = menu.GetCell("super-secret-value");
            ...
        }

        case(MenuAction_End): {
            delete menu;
        }
    }
}

https://github.com/farbrorgodis/smart-menu

Re: [INC] Menu stocks

Quote:

Originally Posted by Potato Uno (Post 2441943)

If it compiles with

PHP Code:


		
			
#pragma newdecls required

then it is new syntax compliant.

Well yeah, it'll compile, but true syntax would be

Code:

Menu menu = new Menu(hndlr, MENU_ACTIONS_DEFAULT);

And everything would then follow

Code:

    menu.AddItem("item", "item");

    menu.AddItem("item", "item");

    menu.ExitButton = false;

    menu.OptionFlags = MENU_NO_SOUND;

    menu.Display(client, 10);