AlliedModders - How to get admin immunity?

AlliedModders (https://forums.alliedmods.net/index.php)

- Scripting (https://forums.alliedmods.net/forumdisplay.php?f=107)

- - How to get admin immunity? (https://forums.alliedmods.net/showthread.php?t=316023)

How to get admin immunity?

How to get admin immunity into variable?

Re: How to get admin immunity?

GetAdminImmunityLevel

Having said that, if you want to know whether a user can target another user, CanUserTarget is likely more useful.

Re: How to get admin immunity?

Didn't even put this in a compiler.

Code:



stock int GetClientAdminImmunity(client)

{

        new AdminId:AID = GetUserAdmin(client);

        if(AID == INVALID_ADMIN_ID)

                return 0;

        

        return GetAdminImmunityLevel(AID);

}

Immunity of administrators in the menu

Hi people!
There is the following code:

PHP Code:


		
			
for(int i = 1; i<=MaxClients; ++i)

{

    if(ValidPlayer(i))

    {

        char str_i[3];

        IntToString(i, str_i, sizeof(str_i));

        char name[64];

        GetClientName(i, name, sizeof(name));

         

        menu.AddItem(str_i, name, ITEMDRAW_DEFAULT);

    }

}

en: How can I make so that the list does not add admins with immunity above the admin who called the menu
ru: Как мне сделать так, чтобы в список не добавлялись админы с имунитетом выше того админа который вызвал меню

Re: How to get admin immunity?

en: Use helper method for detecting, can your admin target another or not.
ru: Используйте вспомогательный метод для определения, может Ваш админ таргетить другого или нет.

https://sm.alliedmods.net/new-api/clients/CanUserTarget

Re: How to get admin immunity?

Quote:

Originally Posted by Hennesy (Post 2650756)

How can I make so that the list does not add admins with immunity above the admin who called the menu

PHP Code:


		
			
stock void CreatePlayerMenu(int client, bool bots=false)
{
    Menu menu = new Menu(Menu_Handler);
    menu.SetTitle("Choose a player:");

    char userid[11], buffer[256];
    for (int i = 1; i <= MaxClients; i++)
    {
        if (client != i && IsClientInGame(i) && CanUserTarget(client, i) && !(!bots && IsFakeClient(i)))
        {
            IntToString(GetClientUserId(i), userid, sizeof(userid));
            Format(buffer, sizeof(buffer), "%N [%s]", i, userid);
            menu.AddItem(userid, buffer);
        }
    }

    if (!menu.ItemCount)
    {
        menu.AddItem("", "No players available.", ITEMDRAW_DISABLED);
    }

    menu.Display(client, 20);
}

public int Menu_Handler(Menu menu, MenuAction action, int client, int param2)
{
    if (action == MenuAction_Select)
    {
        char userid[11];
        menu.GetItem(param2, userid, sizeof(userid));
        int target = GetClientOfUserId(StringToInt(userid));
        if (target)
        {
            // Do stuff with target
        } else {
            // Target is no longer in-game
        }
    } else if (action == MenuAction_End) {
        delete menu;
    }

    return 0;
}