AlliedModders - nVault Tutorial

AlliedModders (https://forums.alliedmods.net/index.php)

- Code Snippets/Tutorials (https://forums.alliedmods.net/forumdisplay.php?f=83)

- - nVault Tutorial (https://forums.alliedmods.net/showthread.php?t=91503)

nVault Tutorial

Intro
nVault is an AMX-X tool designed for an easy method of saving and retrieving data from an external file. I have seen many people ask how to save data in a plugin so it can be retrieved after a map change or server restart. nVault will allow you to do this and it is very simple to use. nVault stores data using a key:data system; each chunk of data that you save has a unique key that corresponds to it. Both key and data are always strings when saving but data can be retrieved as integer, float, or string (see nvault_get). Data is saved to a nvault file in binary format, not plain text; this means that you cannot edit the file in [your favorite text editor here] but there is an nVault Editor that can be used. Also note that you cannot iterate through entries in a nvault file with the native nvault functions. You can iterate through entries using the nVault Utility include file. The ability the store arrays in nVault can also be accomplished with the nVault Utility.

nVault info from AMX-X documentation:
http://www.amxmodx.org/funcwiki.php?go=module&id=20

Code:

nVault is a binary vault implementation. It allows you to open named vaults (which are stored in 

data\vault) and read/write to them at any time. 



The vault is implemented with a simple hash lookup, and the binary file format is primitive. However, it 

should be much faster than AMX Mod X's built-in vault for most things. Each entry is also timestamped, 

so you can prune for old entries. 



Furthermore, the vault attempts to be journaled. That is, it keeps a log of everything it does, so if the 

server crashes, it can "replay" the journal and recover damage. The journal is erased on synchronization 

to the vault binary, which occurs on vault close/mapchange.

These are the available nvault functions:

Code:

nvault_open - Opens a vault by name (such as "myvault").

nvault_close - Closes a vault.

nvault_lookup - Looks up a vault value for full information.

nvault_get - Gets a vault value by returning an int setting a byref float or setting a string & maxlength.

nvault_set - Sets a vault value with current timestamp.

nvault_pset - Sets a permanent vault value with no timestamp.

nvault_remove - Remove an entry from vault.

nvault_touch - "Touches" a key to update its timestamp value. 

nvault_prune - Prunes the vault for entries that are within the given timestamps.

nvault_open
Before doing any transactions with a vault, it must first be opened. This is done with the nvault_open command; it takes 1 string parameter which is the name of the file that is created on the servers hard-disk ([name].vault). When you call the nvault_open() command, it will return a handle (integer value) that is used by all of the other nvault functions as a reference to that particular vault. If an error occurs when opening the vault, nvault_open() will return -1 (INVALID_HANDLE) so it is a good idea to verify if it opened correctly prior to using any other commands.

Code:

nvault_open( const szVaultName[] )



szVaultName = This will be the name of your vault. Every time you want to communicate with this vault you must always use the same name to access that vault. A file will be created in data\vault folder named [szVaultName].vault



Return value: Vault id on success, -1 on failure.

PHP Code:


		
			
//Open a vault and throw a plugin error if INVALID_HANDLE is returned.
new iVaultHandle = nvault_open( "testvault" );

if ( iVaultHandle == INVALID_HANDLE )
    set_fail_state( "Error opening nVault" );

nvault_close
This function will close the vault. It takes the vault handle to close as a parameter. Once a vault is closed you cannot do any transactions with the vault until it is re-opened. In most circumstances it is best to put nvault_close() in plugin_end(). Failure to close a vault file will cause it to be corrupt and you will lose all data.

Code:

nvault_close( iHandle )



iHandle = The handle of the vault that we want to close



Return value: 1 on success, 0 on failure

PHP Code:


		
			
//Open and close a vault.
new iVaultHandle = nvault_open( "testvault" );

nvault_close( iVaultHandle );

nvault_lookup
This function will lookup data using a string key and will place the found data into szValue by-reference for a max of iMaxLength characters. If data is found, the function will return 1 (true), if no data found 0 (false). Timestamp will hold the time at which the entry was written/updated or touched last. This function can only retrieve data from the vault and store it into a string variable. See timestamps section below for an explanation of how timestamps work. This function should be used if you would like to see if a particular key exists in the vault.

Code:

nvault_lookup( iHandle , const szKey[] , szValue[] , iMaxLength , iTimestamp )



iHandle = The handle returned from nvault_open.

szKey = The key you want to use for the data lookup.

szValue = The string variable that will store the data we are retrieving.

iMaxLength = The max length of the string we want read into szValue.

iTimestamp = Will hold a timestamp for when entry was written or last touched.



Return value: 1 if data exists, 0 if no data exists.

PHP Code:


		
			
//Lookup a string stored in a vault using the players steamid as the key.
new szAuthID[35];
new szData[30];
new iTimestamp;
new iVault;
new iDataExists

get_user_authid( id , szAuthID , charsmax( szAuthID ) );

iVault = nvault_open( "testvault" );
iDataExists = nvault_lookup( iVault , szAuthID , szData , charsmax( szData ) , iTimestamp );

//An entry was found, the data for this key is now stored in szData.
if ( iDataExists )
{
    client_print( id , print_chat , "Data=%s Timestamp=%d" , szData , iTimestamp );
}
else
{
    client_print( id , print_chat , "No entry found with key %s" , szAuthID );
}

nvault_get
This function is very similar to nvault_lookup; it looks up data in a vault using the specified key. However, nvault_get is a bit more flexible than nvault_lookup because it allows you to retrieve data directly into a variable other than string. This will negate the need for you to do any data conversion once the data is retrieved as you would need to do if you use nvault_lookup to retrieve a float or int. Note, nvault_get does not allow you to retrieve the timestamp so if you do need the timestamp then you will need to use nvault_lookup.

Code:

nvault_get( handle , const szKey[] , ... )



handle = The handle returned from nvault_open.

key = The key you want to use for the data lookup.

[...] = [Variable # of parameters] This can either be a float variable, string & maxlen, or empty. See below



The number of parameters tells the function what type of data you wish to retrieve. Parameter count starts after szKey[]

0 parameters = nvault_get will return the integer value.

1 parameters = the float value will be passed by reference.

2 parameters = the string value will be passed by ref for maxlen characters. 



Integer: iValue = nvault_get( iHandle , szKey[] );

Return value: Integer value that was found, or 0 if the key was not found or if the data value is non-numerical (ie. a string).



Float: nvault_get( iHandle , szKey[] , float );

Return value: 1 if data found, or 0 if key was not found.



String: nvault_get( iHandle , szKey[] , szValue[] , iMaxLen );

Return value: Length of string data retrieved, or 0 if key was not found.

PHP Code:


		
			
//Retrieve an integer, float, and string value from a vault.
new iVault;
new szAuthID[35];
new szData[30];

iVault = nvault_open( "testvault" );
get_user_authid( id , szAuthID , charsmax( szAuthID ) );

//To retrieve a number that is stored as the data
new iNumber = nvault_get( iVault , szAuthID );

//To retrieve a float that is stored as the data
new Float: fValue;
nvault_get( iVault , szAuthID , fValue );

//To retrieve a string that is stored as the data
new szDataString[10];
nvault_get( iVault , szAuthID , szDataString , charsmax( szDataString ) );

nvault_set
This will write data to the vault and timestamp the entry.

Code:

nvault_set( handle , const key[] , const value[] )



handle = The handle returned from nvault_open.

key = The key you want to use for the data lookup.

value = The string you want to write to vault



Return value: 1 on success, 0 on failure.

PHP Code:


		
			
//Save the phrase "hello world" to vault using steamid as the key.
new iVault;
new szAuthID[35];
new szData[30];

iVault = nvault_open( "testvault" );
get_user_authid( id , szAuthID , charsmax( szAuthID ) );

//Pass the value directly with no variable
nvault_set( iVault , szAuthID , "hello world" );

//Pass the value with a string variable
new szText[] = "hello world";
nvault_set( iVault , szAuthID , szText );

nvault_pset
The same as nvault_set() except this writes an entry without a timestamp so the entry will not be removed by the nvault_prune() function (if called). The timestamp value is 0 when permanent.

Code:

Return value: 1 on success, 0 on failure.

nvault_remove
This removes an entry from the vault that has the specified key value.

Code:

nvault_remove( handle , const key[] )



handle = The handle returned from nvault_open.

key = The key of the vault entry to remove.



Return value: 1 on success, 0 on failure.

PHP Code:


		
			
//Remove an entry from vault
new iVault;

iVault = nvault_open( "testvault" );

//Set a test entry with key "test entry"
nvault_set( iVault , "test entry" , "test value" );

//Remove the entry that was just saved
nvault_remove( iVault , "test entry" );

nvault_touch
This function will 'touch' an entry, updating it's timestamp; the entry value will remain unchanged. If the key does not exist that is being touched, an empty entry for that key will be created. See timestamps section below for an explanation of timestamps.

Code:

nvault_touch( iHandle , const szKey[] , [ iTimestamp = -1 ] ) 



iHandle = The handle of the vault

szKey = The key for which we want to update timestamp

iTimeStamp - [Optional param] If not passed to the function (or -1 is passed) 

it will update the key with the current time. Otherwise it will update the 

key with the timestamp specified.



Return value: 1 on success, 0 on failure.

PHP Code:


		
			
//Touch the entry
new iVault;
new szAuthID[35];

iVault = nvault_open( "testvault" );

get_user_authid( id , szAuthID , charsmax( szAuthID ) );

//Touch the entry with current timestamp
nvault_touch( iVault , szAuthID );

//Touch entry with timestamp 1 hour ago. (60 * 60) = 3600
nvault_touch( iVault , szAuthID , get_systime() - 3600 );

nvault_prune
This function is used to remove entries that fall within the specified start and end timestamps. A timestamp value is in seconds so keep this in consideration when pruning entries. See timestamps section below for an explanation of timestamps.

Code:

nvault_prune( iHandle , iStart , iEnd )



iHandle = The handle returned from nvault_open.

iStart = The timestamp where to begin removing entries.

iEnd = The timestamp where to stop removing entries.



Return value: Number of vault entries pruned on success, 0 on failure.

PHP Code:


		
			
new iVault;

iVault = nvault_open( "testvault" );

//Remove all entries in vault. 0 = earliest possible time, get_systime() = now.
nvault_prune( iVault , 0 , get_systime() );

//Remove entries in vault that are 15 days old or more.
//get_systime() returns the current timestamp
//1 day = 86400 seconds = 60 secs * 60 mins * 24 hours
nvault_prune( iVault , 0 , get_systime() - ( 15 * 86400 ) );

Timestamps
Timestamps in nvault are in unix-time format (aka POSIX time) which is equal to the number of seconds that have elapsed since midnight January 1, 1970. To prune or compare a timestamp retrieved in nvault_lookup, you can do simple multiplication to convert seconds to minutes, hours, days, or weeks. Example: Day = 60 * 60 * 24 = 86400.

In the above nvault_prune example it shows how to prune entries that are 15 days old or more. If you wanted to prune entries that are 10+ minutes old, you would do nvault_prune( iHandle , 0 , get_systime() - ( 60 * 10 ) ).

See this link for info on Unix Time: http://en.wikipedia.org/wiki/Unix_time
AMX-X include file for converting Unix Time <-> Normal Time: http://forums.alliedmods.net/showthread.php?t=91915
Convert Unix Time <-> Normal Time on the web: http://www.onlineconversion.com/unix_time.htm

Using nVault in your plugin
If you will be using nvault functions constantly throughout your plugin, it is best to keep the nvault file open while your plugin is running. To do this, use a global variable to hold the handle and call nvault_open() in plugin_init() or plugin_config() (or anywhere you choose). To close the vault, call nvault_close() in plugin_end().

nVault Limitations
The major things (IMO) that are missing in nVault is the ability to determine the number of entries in a vault, the ability to cycle through entries in a vault, and storing arrays. I created an include file, nVault Utility which provides this missing functionality. Just be advised, the nVault handle used with nVault and nVault Utility are *NOT* interchangeable, which means you will have 2 separate handles if you are working with both at the same time (ie. you cannot use the handle returned by nvault_open() with functions in nVault utility and vice-versa. The only exception for this is for the two functions nvault_set_array() and nvault_get_array(), which do use the handle returned by nvault_open().

Example Plugin
The below plugin shows how to do save a players money and score to the vault. When a user disconnects, these items are saved and when he re-connects they get restored.

Plugin

PHP Code:


		
			
//This plugin allows you to save your money and score to vault using your steamid as the key. Since we are saving two  
//different items both using steam-id as the key, we must format the key for each individual item. For money, the key 
//will be "STEAM_0:0:1234MONEY" and score will be "STEAM_0:0:1234SCORE". If you are only saving one piece of information 
//to the vault with the players steamid then you can use the steamid alone without formatting it. You can save multiple 
//items in each nvault entry but for the sake of keeping this example basic I am using a separate key for each. If you 
//save multiple items you will need to parse each individual item after reading from the vault.

#include <amxmodx>
#include <nvault>
#include <cstrike>
#include <fun>

new g_Vault;               //Global var to hold our vault handle
new g_szAuthID[33][35];    //Global array to store auth ids of players
new g_pExpireDays;         //CVar pointer for expiredays cvar

public plugin_init()
{
    register_plugin( "nVault Example" , "1.0" , "bugsy" );

    register_clcmd( "say /savemoney" , "cmdSaveMoney" );
    register_clcmd( "say /getmoney" , "cmdGetMoney" );
    register_clcmd( "say /savescore" , "cmdSaveScore" );
    register_clcmd( "say /getscore" , "cmdGetScore" );

    g_pExpireDays = register_cvar( "cvar_expiredays" , "5" );
}

public plugin_cfg()
{
    //Open our vault and have g_Vault store the handle.
    g_Vault = nvault_open( "yourvault" );

    //Make the plugin error if vault did not successfully open
    if ( g_Vault == INVALID_HANDLE )
        set_fail_state( "Error opening nVault" );

    //This will remove all entries in the vault that are 5+ (or cvar+) days old at server-start
    //or map-change
    nvault_prune( g_Vault , 0 , get_systime() - ( 86400 * get_pcvar_num( g_pExpireDays ) ) );
}

public plugin_end()
{
    //Close the vault when the plugin ends (map change\server shutdown\restart)
    nvault_close( g_Vault );
}

public client_authorized(id)
{
    //Get the connecting users authid and store it in our global string array so it
    //will not need to be retrieved every time we want to do an nvault transaction.
    get_user_authid( id , g_szAuthID[id] , charsmax( g_szAuthID[] ) );
}

public cmdSaveMoney(id)
{
    //Save a single item into the value of the entry.
    //Example: STEAM_0:0:1234 16000

    new szMoney[7];        //Data holder for the money amount
    new szKey[40];        //Key used to save money "STEAM_0:0:1234MONEY"

    formatex( szKey , charsmax( szKey ) , "%sMONEY" , g_szAuthID[id] );
    formatex( szMoney , charsmax( szMoney ) , "%d" , cs_get_user_money(id) );
    
    nvault_set( g_Vault , szKey , szMoney );

    client_print( id , print_chat , "* Your money was saved to vault" );
}

public cmdGetMoney(id)
{
    //Retrieve a single item from vault
    //Example: STEAM_0:0:1234 16000

    new szKey[40];
    formatex( szKey , charsmax( szKey ) , "%sMONEY" , g_szAuthID[id] );
    new iMoney = nvault_get( g_Vault , szKey );

    //If our money key was found, set the users money to the value we read from vault and
    //delete the key so the player will not get the same money again.
    if ( iMoney )
    {
        cs_set_user_money( id , iMoney , 1 );
        nvault_remove( g_Vault , szKey );

        client_print( id , print_chat , "* Your money was loaded from vault: $%d" , iMoney );
    }
    else
    {
        client_print( id , print_chat , "* You have no money entry in vault." );
    }
}

public cmdSaveScore(id)
{
    //Save 2 items into the value of the entry.
    //Example: STEAM_0:0:1234 15 5

    new szData[8];    //Data key holding kills and deaths in this format: "15 2"
    new szKey[40];    //Key to store data: "STEAM_0:0:1234SCORE"

    formatex( szKey , charsmax( szKey ) , "%sSCORE" , g_szAuthID[id] );
    formatex( szData , charsmax( szData ) , "%d %d" , get_user_frags(id) , get_user_deaths(id) );

    nvault_set( g_Vault , szKey , szData );

    client_print( id , print_chat , "* Your score was saved to vault." );
}

public cmdGetScore(id)
{
    //Read 2 items that that are saved in the same entry
    //Example: STEAM_0:0:1234 15 5

    new szData[8];
    new szKey[40];

    formatex( szKey , charsmax( szKey ) , "%sSCORE" , g_szAuthID[id] );

    //If data was found
    if ( nvault_get( g_Vault , szKey , szData , charsmax( szData ) ) )
    {
        //Look for a space within the data (is used to separate kills and deaths)
        new iSpacePos = contain( szData , " " );
        
        if ( iSpacePos > -1 )
        {    
            new szKills[4];
            new szDeaths[4];
            
            //Put kills and deaths into their own variables so they can be handled individually
            formatex( szKills , charsmax( szKills ) , "%s" , szData );
            formatex( szDeaths , charsmax( szDeaths ) , "%s" , szData[ iSpacePos + 1 ] );

            //Set the players score with these values.
            set_user_frags( id , str_to_num( szKills ) );
            cs_set_user_deaths( id , str_to_num( szDeaths ) );

            client_print( id , print_chat , "* Your score was loaded: %s kills, %s deaths" , szKills , szDeaths );
        }
    }
    else
    {
        client_print( id , print_chat , "* You have no score entry in vault." );
    }
}

Sweet, I was just looking for this tutorial the other day :). I hope it's good :|.

EDIT: Read it.

Would there be file access issues if you tried to access a single nVault from two plugins? Just curious really.

wooT thx for this tuto :O

+karma

edit:

seems like i cant give now, will try give later

and thx for the tut

so many tutorials in such a small periode of time... gj although i never needed to use nvault, sql <3 :D

Well done. Nice to know but I will stay with (My)SQL(ite) :)

The overhead for SQL isn't always necessary for basic data storage. nVault also does not require the knowledge of how to write queries. nVault provides a very basic and easy to understand means of saving\retrieving data to an external file. :grrr:

Quote:

Originally Posted by Bugsy (Post 819363)

ofc it does but most things i did were very simple to create using ordinary textfiles. i mostly use sql cuz the data is shown in huge motd which are php files... i think you understand :D

Good job! I always wanted to know how to use the prune function.

PHP Code:


		
			
public cmdSaveScore(id)

{

    //Save 2 items into the value of the entry.

    //Example: STEAM_0:0:1234 15 5



    new szData[8];

    new szKey[40];

    formatex( szKey , 39 , "%sMONEY" , g_szAuthID[id] );

    formatex( szData , 7 , "%d %d" , get_user_kills(id) , get_user_deaths(id) );



    nvault_set( g_Vault , szKey , szData );



    client_print( id , print_chat , "* Your score was saved to vault." );

}



public cmdGetScore(id)

{

    //Read 2 items that that are saved in the same entry

    //Example: STEAM_0:0:1234 15 5



    new szData[8];

    new szKey[40];

    formatex( szKey , 39 , "%sMONEY" , g_szAuthID[id] );



    if ( nvault_get( g_Vault , szKey , szData , 7 ) )

    {

        new iSpacePos = contain( szData , " " );

        new szKills[4];

        new szDeaths[4];

        

        if ( iSpacePos > -1 )

        {    

            formatex( szKills , iSpacePos , "%s" , szData );

            formatex( szDeaths , 3 , "%s" , szData[ iSpacePos + 1 ] );



            set_user_kills( id , str_to_num( szKills );

            set_user_deaths( id , str_to_num( szDeaths );



            client_print( id , print_chat , "* Your score was loaded: %s kills, %s deaths" , szKills , szDeaths );

        }

    }

    else

    {

        client_print( id , print_chat , "* You have no score entry in vault." );

    }

}

Don't you mean:

PHP Code:


		
			
formatex( szKey , 39 , "%sSCORE" , g_szAuthID[id] );

Quote:

Originally Posted by Bugsy (Post 819363)

This is why I said I'm going to stick with SQL, since I know how to query it is not a problem for me :wink:. It's definitely a helpful and nice tutorial for everyone else but as long as it is not extremely incomplex, temporary or limited data that has to be stored I will always use SQL.

Question: I have a bad opinion about vaults ever since my old WC3 Server suffered from a huge XP-database and crashed on every mapchange. Is this still possible with nVault?

Quote:

Originally Posted by Nextra (Post 819544)

Even if querying isn't a problem for you it could still be overkill depending on what you are storing. If you are only storing a single item and only need to retrieve it based on a single key then it is a waste of CPU to use SQL. Whatever floats your boat though. :grrr:

I've never had any issues with nVault. I have used it for all of my data saving needs.

Quote:

Originally Posted by Bugsy (Post 819582)

Of course. As I said: If it's uncomplex or temporary data I wouldn't bother doing a SQL-implementation.

Thanks Exolent for catching the typo. +k

Made corrections to example plugin. There were a few minor typo's and added required modules to make it compile via copy and paste.

If you could add a function to return just the timestamp for a vault key that would be great.

Code:

nvault_timestamp(vault, key[]); // Finds when the item was last touched.

Also, it would be awesome it we could write as to the save to the vault in the same data type that it was intended to be in.

Code:

stock nvault_timestamp(const vault, const key[]) {
    static data[2], timestamp;
    return nvault_lookup(vault, key, data, charsmax(data), timestamp) ? timestamp : 0;
}

Thanks for the tutorial, it has been useful for me.

Quote:

Originally Posted by fysiks (Post 819100)

Would there be file access issues if you tried to access a single nVault from two plugins? Just curious really.

Same question.
And how many entries is to much for nvault?

Quote:

Originally Posted by fysiks (Post 819100)

Would there be file access issues if you tried to access a single nVault from two plugins?

File access protection is based on the process, and there's only one process accessing all the vaults: hl.exe, so no problems.

Of course there's the problem two or more threads can't write to one file at the same time, but this isn't an issue, since AMXx runs on a single thread.

Yeah, I figured that was the case.

Can anyone help me with storing multiple data.

Code:

#include < amxmodx >

#include < nvault >



new g_iVaultID

new g_szSteamID[ 33 ][ 34 ]

new g_iData[ 33 ] 

new g_iData2[ 33 ] 

new g_iData3[ 33 ] 

new g_iData4[ 33 ] 

new g_iData5[ 33 ] 

new g_iData6[ 33 ] 



public plugin_init( )

{

    register_plugin( "Shit", "Crap", "Lol" )

    

    register_clcmd( "say /show", "fn_Show" )

    register_clcmd( "say /save", "fn_Save" )

}



public plugin_end( )

{

    nvault_close( g_iVaultID )

}



public plugin_cfg( )

{

    g_iVaultID = nvault_open( "test_vault" )

    

    if( g_iVaultID == INVALID_HANDLE )

    {

        set_fail_state( "Error opening Test Nvault" )

    }

}



public client_putinserver( Player )

{

    get_user_authid( Player, g_szSteamID[ Player ], charsmax( g_szSteamID[ ] ) )

    

    Load_Stuff( Player )

}



public fn_Show( Player )

{

    client_print( Player, print_chat, "Data1: %d; Data2: %d; Data3: %d; Data4: %d; Data5:%d; Data6: %d", g_iData[ Player ], g_iData2[ Player ], g_iData3[ Player ], g_iData4[ Player ], g_iData5[ Player ], g_iData6[ Player ] )

}



public fn_Save( Player )

{

    new szSteamID[ 34 ]

    formatex( szSteamID, charsmax( szSteamID ), "%sTEST", g_szSteamID[ Player ] )

    

    g_iData[ Player ] = random_num( 0, 200 )

    g_iData2[ Player ] = random_num( 201, 400 )

    g_iData3[ Player ] = random_num( 401, 600 )

    g_iData4[ Player ] = random_num( 601, 800 )

    g_iData5[ Player ] = random_num( 801, 999 )

    g_iData6[ Player ] = random_num( 1000, 1099 )

    

    new szData[ 50 ]

    formatex( szData, charsmax( szData ), "%d %d %d %d %d %d", g_iData[ Player ], g_iData2[ Player ], g_iData3[ Player ], g_iData4[ Player ], g_iData5[ Player ], g_iData6[ Player ] )

    

    nvault_set( g_iVaultID, szSteamID, szData )

    

    client_print( Player, print_chat, "Data1: %d; Data2: %d; Data3: %d; Data4: %d; Data5:%d; Data6: %d", g_iData[ Player ], g_iData2[ Player ], g_iData3[ Player ], g_iData4[ Player ], g_iData5[ Player ], g_iData6[ Player ]  )

}



Load_Stuff( Player )

{

    new szData[ 50 ], szSteamID[ 34 ]

    formatex( szSteamID, charsmax( szSteamID ), "%sTEST", g_szSteamID[ Player ] )

    

    if( nvault_get( g_iVaultID, szSteamID, szData, 49 ) )

    {

        new iSpacePos = contain( szData, " " )

        

        if( iSpacePos > -1 )

        {

            new szData1[ 4 ], szData2[ 4 ], szData3[ 4 ], szData4[ 4 ], szData5[ 4 ], szData6[ 5 ]

            formatex( szData1, iSpacePos, "%s", szData )

            formatex( szData2, 3, "%s", szData[ iSpacePos + 1 ] )

            formatex( szData3, 3, "%s", szData2[ iSpacePos + 1 ] )

            formatex( szData4, 3, "%s", szData3[ iSpacePos + 1 ] )

            formatex( szData5, 3, "%s", szData4[ iSpacePos + 1 ] )

            formatex( szData6, 4, "%s", szData5[ iSpacePos + 1 ] )

            

            

            g_iData[ Player ] = str_to_num( szData1 )

            g_iData2[ Player ] = str_to_num( szData2 )

            g_iData3[ Player ] = str_to_num( szData3 )

            g_iData4[ Player ] = str_to_num( szData4 )

            g_iData5[ Player ] = str_to_num( szData5 )

            g_iData6[ Player ] = str_to_num( szData6 )

        }

    }

}

I dont why, but g_iData[ ] values all the time are 0. :(

PHP Code:


		
			
            new szData1[ 4 ], szData2[ 4 ], szData3[ 4 ], szData4[ 4 ], szData5[ 4 ], szData6[ 5 ]

            formatex( szData1, iSpacePos, "%s", szData )

            formatex( szData2, 3, "%s", szData[ iSpacePos + 1 ] )

            formatex( szData3, 3, "%s", szData2[ iSpacePos + 1 ] )

            formatex( szData4, 3, "%s", szData3[ iSpacePos + 1 ] )

            formatex( szData5, 3, "%s", szData4[ iSpacePos + 1 ] )

            formatex( szData6, 4, "%s", szData5[ iSpacePos + 1 ] )

I haven't looked over everything closely but the above code is most likely the problem. Try this:

PHP Code:


		
			
            new szData1[ 4 ], szData2[ 4 ], szData3[ 4 ], szData4[ 4 ], szData5[ 4 ], szData6[ 5 ]

        

            parse( szData , szData1 , charsmax( szData1 ) ,

              szData2 , charsmax( szData2 ) ,

              szData3 , charsmax( szData3 ) ,

              szData4 , charsmax( szData4 ) ,

              szData5 , charsmax( szData5 ) ,

              szData6 , charsmax( szData6 ) )

Thank you Bugsy, now it works ;]

XP title e.g 1 kill 10 XP, and 800 XP title serious player
XP

PHP Code:


		
			
0 XP 

100 XP 

200 XP 

400 XP 

800 XP 

1600 XP 

3200 XP

Tittles

PHP Code:


		
			
0 XP lamer 

100 XP Beginner 

200 XP Amateur 

400 XP Professional 

800 XP Master 

1600 XP Igrok 

3200 XP Counter-Strike Pather

pleace give me this plugin or create

Quote:

Originally Posted by lashsh (Post 1284561)

XP title e.g 1 kill 10 XP, and 800 XP title serious player
XP

pleace give me this plugin or create

http://forums.alliedmods.net/showpos...54&postcount=6

Sockets + php to handle real important database stuff.
nVault to logs less important temporary data.

What more?:) gj

Quote:

Originally Posted by johnally (Post 1467607)

Sockets + php to handle real important database stuff.
nVault to logs less important temporary data.

What more?:) gj

Thanks for your informative contribution to the thread! Contrary to your opinion, nVault can be used for storing "important permanent data" as well as "less important temporary data."

PHP Code:


		
			
nvault_prune (g_iVault, 0, get_systime() - ( 86400 * 10) )

this will remove all data that are inactive for 10 days?

That will delete entries that are older than 10 days.

nvault_prune( Vault , start time , end time )

All entries that fall within starting and ending time are deleted.

0 = start of time
get_systime() = now
86400 * 10 = 10 days

Is there a way, that it loads the nvault but doesn't create a file in data/vault ?

I've tried this in CS and it did create one but it seems like I can't get this to working in TFC. Could you maybe have a look bugsy?

Is there a function to prune only one key in a vault file? For example the scores in the example plugin.

Code:

/* Prunes a specific key in the vault if it is within the given timestampps
 * This will not erase values set with pset
 */
stock nvault_prune_key(vault, const key[], start, end) {
    new timestamp;
    if(nvault_lookup(vault, key, "", 0, timestamp) && timestamp > 0 && (start <= timestamp <= end)) {
        nvault_remove(vault, key);
        return 1;
    }
    
    return 0;
}

What's the point of nvault_touch if it only updates timestamp? I would as well want it to update my data.

Do I have to first make a check if data exists and only then use nvault_set? (Finds first and replaces the data after)
Or does nvault_set do it automatically without creating a new record?

Nothing is mentioned if nvault_set updates or not.

Just interested.

Quote:

Originally Posted by Infernuz (Post 1651640)

What's the point of nvault_touch if it only updates timestamp? I would as well want it to update my data.

Use nvault_set() to update your data and the timestamp will update, too.

Quote:

Originally Posted by Infernuz (Post 1651640)

Do I have to first make a check if data exists and only then use nvault_set? (Finds first and replaces the data after)
Or does nvault_set do it automatically without creating a new record?

Nothing is mentioned if nvault_set updates or not.

Well the whole point of "keys" are that they are unique in the vault.
If it were to create new entries instead of updating, those keys would not be unique.
So the answer is: yes, nvault_set() updates the data if it already exists.

Thanks for the stock exolent. However, how should I check if the days expired, and then prune that key for the user? A general pruning doesn't work, since I don't know how to do that with your stock. Right now I have this:

PHP Code:


		
			
        new szDeathKey[41]
        
        formatex(szDeathKey, charsmax(szDeathKey), "%s_DEATH", g_szAuthID[id])
    
        //check here the days expired, and if so, prune that key
        nvault_prune_key(g_score_vault, szDeathKey, get_systime(), 86400 * get_pcvar_num(amx_death_expire_days))

Is that right like that?

Quote:

Originally Posted by bibu (Post 1648269)

Is there a function to prune only one key in a vault file? For example the scores in the example plugin.

There is a score key for every player so there will not only be one score key. If you are referring to deleting all players 'score' key then no, the native 'prune' function works only with the timestamp. You will need to use the nvault utility include and delete keys containing "score".

See my post in #34. It just only for one player and does work IMO.

Sorry about that bibu, I didn't see page 2 for some reason and that this has already been resolved. Exolents function will do just fine, the only thing I think you have wrong is the window of time for pruning entries. Correct me if I'm wrong, I'm a little rusty.

PHP Code:


		
			
nvault_prune_key(g_score_vault, szDeathKey, get_systime(), 86400 * get_pcvar_num(amx_death_expire_days))

Start: get_sys_time() = Now
End: 86400 * days = Days to remove in seconds (which is days starting from 01/01/1970 or w\e).

Should be

Start: 0 (01/01/1970)
End: get_systime() - ( get_pcvar_num( amx_death_expire_days ) * 86400 ) ) (Now - X days)

Bugsy I am thinking abit wrong and couldn't really understand your explanation. Could you rephrase that?

Quote:

Originally Posted by bibu (Post 1652980)

Could you rephrase that?

Change

PHP Code:


		
			
nvault_prune_key(g_score_vault, szDeathKey, get_systime(), 86400 * get_pcvar_num(amx_death_expire_days))

PHP Code:


		
			
nvault_prune_key(g_score_vault, szDeathKey, 0, get_systime() - (86400 * get_pcvar_num(amx_death_expire_days)))

Quote:

Originally Posted by Exolent[jNr] (Post 1653028)

Change

PHP Code:


		
			
nvault_prune_key(g_score_vault, szDeathKey, get_systime(), 86400 * get_pcvar_num(amx_death_expire_days))

PHP Code:


		
			
nvault_prune_key(g_score_vault, szDeathKey, 0, get_systime() + (86400 * get_pcvar_num(amx_death_expire_days)))

That will delete all entries. start=0 with end=get_systime() would delete all; in addition you are adding excess days onto now which says delete everything from the start of time until 15 days from now. Change + to - and it is good, as I posted in #37.

Quote:

Originally Posted by bibu (Post 1652980)

Bugsy I am thinking abit wrong and couldn't really understand your explanation. Could you rephrase that?

When you prune, you are deleting entries that have a time stamp that falls within Start and End range. So for start time you use 0 (beginning of Epoch time) and for the end date you use now minus the number of days for expired entries. A timestamp is the number of seconds that have elapsed since 01/01/70 (IIRC), so the lower the number, the older the time is from now. Suppose you wanted to delete items that are older than 15 days:

0 < 17 day old entry to delete < 15 days from now
0 < 1328148921(now minus 17 days) < 1328321721(now minus 15 days)

Here's some math:

Start = 0

Calculate End time value (Now - 15 days)

Now = 1329610846
15 Days = 1296000
1329610846 - 1296000 = 1328314846

Outdated entry example to delete (17 days old, Now - 17 days)

17 Days = 1468800
1329610846 - 1468800 = 1328142046

Delete this 17 day old entry since:
0(Start) < 1328142046(17 day old entry) < 1328314846(now - 15 days)

So what you want is this:

PHP Code:


		
			
nvault_prune_key( g_score_vault , szDeathKey , 0 , get_systime() - ( 86400 * get_pcvar_num( amx_death_expire_days ) ) )