AlliedModders - [REQ] Play Time

AlliedModders (https://forums.alliedmods.net/index.php)

- Suggestions / Requests (https://forums.alliedmods.net/forumdisplay.php?f=12)

- - [REQ] Play Time (https://forums.alliedmods.net/showthread.php?t=301888)

Hi. I want a plugin when a player played more than 48 hours gets TZ flag(VIP).

Re: [REQ] Play Time

Untested and I'm not sure what flag you want, so you need to update that part in the code.

PHP Code:


		
			

#include <amxmodx>
#include <nvault>

new const Version[] = "0.1";

#define MAX_PLAYERS 32

const FortyEightHours = ( 86400 * 2 );

enum PlayerData
{
    pdAuthID[ 34 ],
    pdConnectTime,
    pdPlayTime,
    pdIgnorePlayer
}

new g_pdData[ MAX_PLAYERS + 1 ][ PlayerData ];
new g_Vault;

public plugin_init() 
{
    register_plugin( "Play Time VIP" , Version , "bugsy" );

    g_Vault = nvault_open( "ptvip" );
}

public plugin_end() 
{
    nvault_close( g_Vault );
}

public client_authorized( id )
{
    new szTime[ 11 ] , iTS , szMsg[ 48 ];
    
    if ( !( g_pdData[ id ][ pdIgnorePlayer ] = ( is_user_bot( id ) || is_user_hltv( id ) ) ) )
    {
        get_user_authid( id , g_pdData[ id ][ pdAuthID ] , charsmax( g_pdData[][ pdAuthID ] ) );
        
        g_pdData[ id ][ pdConnectTime ] = get_systime();
        
        if ( nvault_lookup( g_Vault , g_pdData[ id ][ pdAuthID ] , szTime , charsmax( szTime ) , iTS ) )
        {
            g_pdData[ id ][ pdPlayTime ] = str_to_num( szTime );
            
            if ( g_pdData[ id ][ pdPlayTime ] >= FortyEightHours )
            {
                set_user_flags( id , ADMIN_LEVEL_F );
                
                formatex( szMsg , charsmax( szMsg ) , "You have played for %d seconds and now have VIP" , g_pdData[ id ][ pdPlayTime ] );
            }
            else
            {
                formatex( szMsg , charsmax( szMsg ) , "You have played for %d seconds. Play more to get VIP" , g_pdData[ id ][ pdPlayTime ] );
            }
        }
        else
        {
            copy( szMsg , charsmax( szMsg ) , "This is your first time connecting." );
        }
        
        set_task( 8.0 , "ShowMessage" , id , .parameter=szMsg , .len=sizeof( szMsg ) );
    }
}

public client_disconnect( id )
{
    new szTime[ 11 ];
    
    if ( !g_pdData[ id ][ pdIgnorePlayer ] )
    {
        num_to_str( g_pdData[ id ][ pdPlayTime ] + ( get_systime() - g_pdData[ id ][ pdConnectTime ] ) , szTime , charsmax( szTime ) );
        nvault_set( g_Vault , g_pdData[ id ][ pdAuthID ] , szTime );
        g_pdData[ id ][ pdPlayTime ] = 0;
    }
}

public ShowMessage( szMsg[] , id )
{
    if ( is_user_connected( id ) )
    {
        client_print( id , print_chat , szMsg );
    }
}

Re: [REQ] Play Time

I changed it 10 seconds for testing and It didn't work.

Re: [REQ] Play Time

Did you disconnect and reconnect. And how do you know it didnt work? The message gets displayed immediately upon connecting so you wouldn't see it, I will need to add a delay.

Re: [REQ] Play Time

Yes I did. After 10 seconds there was no message and also I checked it via amx_who

Re: [REQ] Play Time

Try the updated code

Re: [REQ] Play Time

Not working also no messages shown

Re: [REQ] Play Time

Are there any errors? Steam?

Re: [REQ] Play Time

No errors also I have the latest hlds (build 7561)

Re: [REQ] Play Time

My hlds sometimes crashes after adding this plugin

Re: [REQ] Play Time

Fixed. I found 2 things that were wrong. Shutdown your server and delete the vault file otherwise you will get a crash.

Re: [REQ] Play Time

Thanks It's working but It doesn't save VIP in users.ini and when I changed my name I wasn't VIP anymore. I want it to set VIP by steam ID.

Re: [REQ] Play Time

It will not modify users.ini but the player will get the flag once they connect. Name change will not impact this.

Re: [REQ] Play Time

Can you make it to modify users.ini? Where does it save now?

Re: [REQ] Play Time

It doesn't save anywhere, the plugin adds the flag to the player when he connects. As long as the plugin is running he will get the flag.

Re: [REQ] Play Time

If I want to remove a flag from specific player how can I do this? Cause it's not in users.ini

Re: [REQ] Play Time

I̶ ̶t̶h̶i̶n̶k̶ ̶y̶o̶u̶ ̶c̶a̶n̶ ̶b̶l̶a̶c̶k̶l̶i̶s̶t̶ ̶t̶h̶e̶ ̶p̶e̶o̶p̶l̶e̶ ̶f̶r̶o̶m̶ ̶u̶s̶i̶n̶g̶ ̶t̶h̶i̶s̶ ̶b̶y̶ ̶s̶i̶m̶p̶l̶y̶ ̶a̶d̶d̶i̶d̶n̶g̶ ̶t̶h̶e̶m̶ ̶t̶o̶ ̶u̶s̶e̶r̶s̶.̶i̶n̶i̶ ̶w̶i̶t̶h̶ ̶f̶l̶a̶g̶ ̶z̶

Re: [REQ] Play Time

Quote:

Originally Posted by khashayar007 (Post 2553458)

If I want to remove a flag from specific player how can I do this? Cause it's not in users.ini

I can add a blacklist command

Re: [REQ] Play Time

Can you add mysql to this plugin? I mean the plugin writes playtime and steamID to database and reads it from database.

Re: [REQ] Play Time

Quote:

Originally Posted by khashayar007 (Post 2553493)

Can you add mysql to this plugin? I mean the plugin writes playtime and steamID to database and reads it from database.

tell me one good reason why this is necessary.

Re: [REQ] Play Time

Cause when server shuts down the playtime for all players resets.

Re: [REQ] Play Time

The play time should never reset.

Re: [REQ] Play Time

Made a small fix where the previous players play time would be given to the next player if the player has never been to the server before.

Re: [REQ] Play Time

How to remove a player if it's vip? So the player must play again to be vip.

Re: [REQ] Play Time

I can add a command for that, too.

Re: [REQ] Play Time

Added blacklist and remove commands. Untested.

PHP Code:


		
			


#include <amxmodx>

#include <amxmisc>

#include <nvault>



new const Version[] = "0.2";



#define MAX_PLAYERS 32



const FortyEightHours = ( 86400 * 2 );



enum PlayerData

{

    pdAuthID[ 34 ],

    pdConnectTime,

    pdPlayTime,

    pdIgnorePlayer

}



new g_pdData[ MAX_PLAYERS + 1 ][ PlayerData ];

new g_Vault;



public plugin_init() 

{

    register_plugin( "Play Time VIP" , Version , "bugsy" );



    register_clcmd( "ptv_blacklist" , "Blacklist" );

    register_clcmd( "ptv_removevip" , "RemoveVIP" );

    

    g_Vault = nvault_open( "ptvip" );

}



public plugin_end() 

{

    nvault_close( g_Vault );

}



public client_authorized( id )

{

    new szTime[ 11 ] , iTS , szMsg[ 48 ];

    

    if ( !( g_pdData[ id ][ pdIgnorePlayer ] = ( is_user_bot( id ) || is_user_hltv( id ) ) ) )

    {

        get_user_authid( id , g_pdData[ id ][ pdAuthID ] , charsmax( g_pdData[][ pdAuthID ] ) );

        

        g_pdData[ id ][ pdConnectTime ] = get_systime();

        

        if ( nvault_lookup( g_Vault , g_pdData[ id ][ pdAuthID ] , szTime , charsmax( szTime ) , iTS ) )

        {

            g_pdData[ id ][ pdPlayTime ] = str_to_num( szTime );

            

            if ( g_pdData[ id ][ pdPlayTime ] != -1 )

            {

                if ( g_pdData[ id ][ pdPlayTime ] >= FortyEightHours )

                {

                    set_user_flags( id , ADMIN_LEVEL_F );

                    

                    formatex( szMsg , charsmax( szMsg ) , "You have played for %d seconds and now have VIP" , g_pdData[ id ][ pdPlayTime ] );

                }

                else

                {

                    formatex( szMsg , charsmax( szMsg ) , "You have played for %d seconds. Play more to get VIP" , g_pdData[ id ][ pdPlayTime ] );

                }

            }

        }

        else

        {

            copy( szMsg , charsmax( szMsg ) , "This is your first time connecting." );

        }

        

        set_task( 8.0 , "ShowMessage" , id , .parameter=szMsg , .len=sizeof( szMsg ) );

    }

}



public client_disconnect( id )

{

    new szTime[ 11 ];

    

    if ( !g_pdData[ id ][ pdIgnorePlayer ] && ( g_pdData[ id ][ pdPlayTime ] != -1 ) )

    {

        num_to_str( g_pdData[ id ][ pdPlayTime ] + ( get_systime() - g_pdData[ id ][ pdConnectTime ] ) , szTime , charsmax( szTime ) );

        nvault_set( g_Vault , g_pdData[ id ][ pdAuthID ] , szTime );

        g_pdData[ id ][ pdPlayTime ] = 0;

    }

}



public ShowMessage( szMsg[] , id )

{

    if ( is_user_connected( id ) )

    {

        client_print( id , print_chat , szMsg );

    }

}



public Blacklist( id )

{

    new szPlayer[ 32 ] , iPlayer , szBlacklist[] = "-1";

    

    read_argv( 1 , szPlayer , charsmax( szPlayer ) );

    

    if ( ( iPlayer = cmd_target( id , szPlayer ) ) )

    {

        nvault_pset( g_Vault , g_pdData[ iPlayer ][ pdAuthID ] , szBlacklist );

        remove_user_flags( iPlayer , ADMIN_LEVEL_F );

        client_print( iPlayer , print_chat , "* You have been blacklisted from getting VIP." );

    }

    

    return PLUGIN_HANDLED;

}



public RemoveVIP( id )

{

    new szPlayer[ 32 ] , iPlayer;

    

    read_argv( 1 , szPlayer , charsmax( szPlayer ) );

    

    if ( ( iPlayer = cmd_target( id , szPlayer ) ) )

    {

        nvault_remove( g_Vault , g_pdData[ iPlayer ][ pdAuthID ] );

        remove_user_flags( iPlayer , ADMIN_LEVEL_F );

        client_print( iPlayer , print_chat , "* Your VIP status has been removed." );

    } 

    

    return PLUGIN_HANDLED;

}

Re: [REQ] Play Time

Thank you so much It's working. But I need to see who is in vip list so that I can remove it. Can you make a menu for ptv_removevip that shows all vips thus I can delete the vip I want.

Re: [REQ] Play Time

Bugsy can you please add a feature when a player becomes vip after 48 hours remove it's vip.

Re: [REQ] Play Time

Quote:

Originally Posted by khashayar007 (Post 2556510)

Thank you so much It's working. But I need to see who is in vip list so that I can remove it. Can you make a menu for ptv_removevip that shows all vips thus I can delete the vip I want.

This will require that you use the nvault_array include which requires that all servers running this have either a amxmodx dev build running or have the fixed nvault module installed.

Quote:

Originally Posted by khashayar007 (Post 2570220)

Bugsy can you please add a feature when a player becomes vip after 48 hours remove it's vip.

I don't understand this request.

Re: [REQ] Play Time

Quote:

Originally Posted by Bugsy (Post 2570446)

This will require that you use the nvault_array include which requires that all servers running this have either a amxmodx dev build running or have the fixed nvault module installed.

I have the dev version. Can you make it?

Re: [REQ] Play Time

@Bugsy
Sorry for jumping in, but, do you have any idea why sometimes nVault plugins crash the server and don't start until you remove the vault file? Didn't wanna create a thread just for this problem.

Re: [REQ] Play Time

Check if the key isn't empty before saving the data. I can confirm this is happening.

Re: [REQ] Play Time

Usually a corrupt vault file. Easiest fix is to delete the vault file and start fresh and make sure you are properly closing the vault when the map changes @ plugin_end(). I suppose a server crash could cause this to happen since the vault is not getting a graceful close.

I was testing something else today and accidentally saved a vault record with a blank key and it did not give me any errors.

Re: [REQ] Play Time

Not sure why and when it happens, but adding a blank check definitely prevents it. I did some testing a while ago.

Re: [REQ] Play Time

It happened to me without setting a blank key, I was saving my Levels & XP on SteamID. After I closed the vault in plugin_end it didn't crash anymore but I'm not sure how to reproduce it.

Re: [REQ] Play Time

Not closing in plugin_end(), saving data for bots and possibly blank keys - I have experienced corrputing in these cases.

Re: [REQ] Play Time

Having a stack trace from say GDB would help a lot in solving that problem if it's true.

Re: [REQ] Play Time

Added menu for removing VIP and blacklisted, including both online and offline players. I have only done basic testing since I do not run a server and only have access to bots.

The plugin now requires nVault Utility and nVault Array. Those not running a dev build of AMX-X must use a fixed version of the nVault module.

Spoiler

PHP Code:


		
			

#include <amxmodx>
#include <amxmisc>
#include <nvault>
#include <nvault_util>
#include <nvault_array>

new const Version[] = "0.8";

#define MAX_PLAYERS 32

new const VaultName[] = "PlayTimeVIP";
new const FortyEightHours = ( 86400 * 2 );

enum PlayerData
{
    pdAuthID[ 34 ],
    pdName[ 32 ],
    pdConnectTime,
    pdPlayTime,
    bool:pdIgnorePlayer,
    bool:pdIsVIP,
    bool:pdIsBlackListed
}

new g_pdData[ MAX_PLAYERS + 1 ][ PlayerData ];
new g_Vault;
new g_AdminFlags;

public plugin_init() 
{
    register_plugin( "Play Time VIP" , Version , "bugsy" );

    register_clcmd( "ptv_blacklist" , "Blacklist" );
    register_clcmd( "ptv_removeblacklistmenu" , "RemoveBlacklistMenu" );
    
    register_clcmd( "ptv_removevip" , "RemoveVIP" );
    register_clcmd( "ptv_removevipmenu" , "RemoveVIPMenu" );
    
    register_event( "HLTV" , "NewRound" , "a" , "1=0" , "2=0" ); 
    
    g_AdminFlags = read_flags( "bcdefghijkmnopqrstu" );
    
    g_Vault = nvault_open( VaultName );
}

public plugin_end() 
{
    nvault_close( g_Vault );
}

public client_authorized( id )
{
    new iTS;
    
    arrayset( g_pdData[ id ][ pdAuthID ][ 0 ] , 0 , sizeof( g_pdData[] ) );
    
    if ( !( g_pdData[ id ][ pdIgnorePlayer ] = ( ( get_user_flags( id ) & g_AdminFlags ) || is_user_bot( id ) || is_user_hltv( id ) ) ) )
    {
        get_user_authid( id , g_pdData[ id ][ pdAuthID ] , charsmax( g_pdData[][ pdAuthID ] ) );
        
        if ( nvault_get_array( g_Vault , g_pdData[ id ][ pdAuthID ] , g_pdData[ id ][ pdAuthID ][ 0 ] , sizeof( g_pdData[] ) , iTS ) )
        {    
            if ( g_pdData[ id ][ pdPlayTime ] >= FortyEightHours )
            {
                remove_user_flags( id , ADMIN_USER );
                set_user_flags( id , g_AdminFlags );
                
                g_pdData[ id ][ pdIsVIP ] = true;
            }    
        }

        get_user_name( id , g_pdData[ id ][ pdName ] , charsmax( g_pdData[][ pdName ] ) );
        g_pdData[ id ][ pdConnectTime ] = get_systime();
    }
}

public client_disconnect( id )
{
    if ( !g_pdData[ id ][ pdIgnorePlayer ] )
    {
        g_pdData[ id ][ pdPlayTime ] += ( get_systime() - g_pdData[ id ][ pdConnectTime ] );
        nvault_set_array( g_Vault , g_pdData[ id ][ pdAuthID ] , g_pdData[ id ][ pdAuthID ][ 0 ] , sizeof( g_pdData[] ) );
    }
}

public NewRound()
{
    new iPlayers[ 32 ] , iNum , iPlayer , iSecondsNeededForVIP , szTime[ 64 ] , iSysTime;
    
    get_players( iPlayers , iNum , "ch" );
    
    for ( new i = 0 ; i < iNum ; i++ )
    {
        iPlayer = iPlayers[ i ];
        
        if ( g_pdData[ iPlayer ][ pdIgnorePlayer ] == false )
        {
            iSysTime = get_systime();

            if ( ( g_pdData[ iPlayer ][ pdIsVIP ] == false ) && ( ( g_pdData[ iPlayer ][ pdPlayTime ] + ( iSysTime - g_pdData[ iPlayer ][ pdConnectTime ] ) ) >= FortyEightHours ) )
            {
                remove_user_flags( iPlayer , ADMIN_USER );
                set_user_flags( iPlayer , g_AdminFlags );
                
                g_pdData[ iPlayer ][ pdIsVIP ] = true;
                
                client_print( iPlayer , print_chat , "* You are now VIP!" , szTime );
                
                continue;
            }    
            
            if ( ( g_pdData[ iPlayer ][ pdIsVIP ] == false ) )
            {
                iSecondsNeededForVIP = FortyEightHours - ( g_pdData[ iPlayer ][ pdPlayTime ] + ( iSysTime - g_pdData[ iPlayer ][ pdConnectTime ] ) );
                
                FormatTime( iSecondsNeededForVIP , szTime , charsmax( szTime ) );
                
                client_print( iPlayer , print_chat , "* You must play an additional %s to get VIP." , szTime );
            }
        }
    }
}

public Blacklist( id , level , cid )
{
    if ( !cmd_access( id , level , cid , 1 ) )
        return PLUGIN_HANDLED;
        
    new szPlayer[ 32 ] , iPlayer;
    
    read_argv( 1 , szPlayer , charsmax( szPlayer ) );

    if ( ( iPlayer = cmd_target( id , szPlayer , ( CMDTARGET_OBEY_IMMUNITY | CMDTARGET_NO_BOTS ) ) ) )
    {
        g_pdData[ iPlayer ][ pdIsBlackListed ] = true;
        g_pdData[ iPlayer ][ pdPlayTime ] = 0;
        
        remove_user_flags( iPlayer , g_AdminFlags );
        set_user_flags( iPlayer , ADMIN_USER );
        
        nvault_set_array( g_Vault , g_pdData[ iPlayer][ pdAuthID ] , g_pdData[ iPlayer ][ pdAuthID ][ 0 ] , sizeof( g_pdData[] ) );

        client_print( iPlayer , print_chat , "* You have been blacklisted from getting VIP." );
    }
        
    return PLUGIN_HANDLED;
}

public RemoveVIP( id , level , cid )
{
    if ( !cmd_access( id , level , cid , 1 ) )
        return PLUGIN_HANDLED;
        
    new szPlayer[ 32 ] , iPlayer;
    
    read_argv( 1 , szPlayer , charsmax( szPlayer ) );
    
    if ( ( iPlayer = cmd_target( id , szPlayer , ( CMDTARGET_OBEY_IMMUNITY | CMDTARGET_NO_BOTS ) ) ) )
    {
        g_pdData[ iPlayer ][ pdIsVIP ] = false;
        g_pdData[ iPlayer ][ pdPlayTime ] = 0;
        
        remove_user_flags( iPlayer , g_AdminFlags );
        set_user_flags( iPlayer , ADMIN_USER );
        
        nvault_set_array( g_Vault , g_pdData[ iPlayer ][ pdAuthID ] , g_pdData[ iPlayer ][ pdAuthID ][ 0 ] , sizeof( g_pdData[] ) );
        
        client_print( iPlayer , print_chat , "* Your VIP status has been removed." );
    } 
    
    return PLUGIN_HANDLED;
}

public RemoveVIPMenu( id , level , cid )
{
    if ( !cmd_access( id , level , cid , 0 ) )
        return PLUGIN_HANDLED;
        
    new iVault , iNum , iOffset , iMenu , szKey[ 34 ] , iTS;
    new pdData[ PlayerData ] , bool:bAnyVIPs;
    
    nvault_close( g_Vault );
    g_Vault = nvault_open( VaultName );
    
    iVault = nvault_util_open( VaultName );
    iNum = nvault_util_count( iVault );
    
    iMenu = menu_create( "Remove VIP" , "RemoveVIPMenuMenuHandler" );
    
    for ( new i = 1 ; i <= iNum ; i++ )
    {
        iOffset = nvault_util_read_array( iVault , iOffset , szKey , charsmax( szKey ) , pdData[ pdAuthID ][ 0 ] , sizeof( pdData ) , iTS );
    
        if ( pdData[ pdIsVIP ] == true )
        {
            menu_additem( iMenu , pdData[ pdName ] , _:pdData[ pdAuthID ][ 0 ] );
            bAnyVIPs = true;
        }
    }
    
    nvault_util_close( iVault );
    
    if ( bAnyVIPs == true )
    {
        menu_display( id , iMenu );
    }
    else
    {
        client_print( id , print_chat , "* No players are VIP." );
    }
    
    return PLUGIN_HANDLED;
}


public RemoveVIPMenuMenuHandler( id , iMenu , iItem )
{        
    new iPlayers[ 32 ] , iNum , iPlayer , szName[ 32 ] , iAccess , iCB , pdData[ PlayerData ];
    
    if ( iItem == MENU_EXIT ) 
    {
        menu_destroy( iMenu );
        return;
    }
    
    menu_item_getinfo( iMenu , iItem , iAccess , pdData[ pdAuthID ][ 0 ] , sizeof( pdData ) , szName , charsmax( szName ) , iCB );
    
    pdData[ pdIsVIP ] = false;
    pdData[ pdPlayTime ] = 0;
    
    nvault_set_array( g_Vault , pdData[ pdAuthID ] , pdData[ pdAuthID ][ 0 ] , sizeof( pdData[] ) );
        
    get_players( iPlayers , iNum , "ch" );
    
    for ( new i = 0 ; i < iNum ; i++ )
    {
        iPlayer = iPlayers[ i ];
        
        if ( equal( pdData[ pdAuthID ] , g_pdData[ iPlayer ][ pdAuthID ] ) )
        {
            g_pdData[ iPlayer ][ pdIsVIP ] = false;
            g_pdData[ iPlayer ][ pdPlayTime ] = 0;
        
            remove_user_flags( iPlayer , g_AdminFlags );
            set_user_flags( iPlayer , ADMIN_USER );
            
            break;
        }
    }
    
    client_print( id , print_chat , "* Removed %s from VIP list." , szName );
}

public RemoveBlacklistMenu( id , level , cid )
{
    if ( !cmd_access( id , level , cid , 0 ) )
        return PLUGIN_HANDLED;
        
    new iVault , iNum , iOffset , iMenu , szKey[ 34 ] , iTS;
    new pdData[ PlayerData ] , bool:bAnyBlacklisted;
    
    nvault_close( g_Vault );
    g_Vault = nvault_open( VaultName );
    
    iVault = nvault_util_open( VaultName );
    iNum = nvault_util_count( iVault );
    
    iMenu = menu_create( "Remove Blacklist" , "RemoveBlacklistMenuMenuHandler" );
    
    for ( new i = 1 ; i <= iNum ; i++ )
    {
        iOffset = nvault_util_read_array( iVault , iOffset , szKey , charsmax( szKey ) , pdData[ pdAuthID ][ 0 ] , sizeof( pdData ) , iTS );
    
        if ( pdData[ pdIsBlackListed ] == true )
        {
            menu_additem( iMenu , pdData[ pdName ] , pdData[ pdAuthID ][ 0 ] );
            bAnyBlacklisted = true;
        }
    }
    
    nvault_util_close( iVault );
    
    if ( bAnyBlacklisted == true )
    {
        menu_display( id , iMenu );
    }
    else
    {
        client_print( id , print_chat , "* No players are blacklisted." );
    }
    
    return PLUGIN_HANDLED;
}

public RemoveBlacklistMenuMenuHandler( id , iMenu , iItem )
{
    new iPlayers[ 32 ] , iNum , iPlayer , szName[ 32 ] , iAccess , iCB , pdData[ PlayerData ];
    
    if ( iItem == MENU_EXIT ) 
    {
        menu_destroy( iMenu );
        return;
    }
    
    menu_item_getinfo( iMenu , iItem , iAccess , pdData[ pdAuthID ][ 0 ] , sizeof( pdData ) , szName , charsmax( szName ) , iCB );
    
    pdData[ pdIsBlackListed ] = false;
    pdData[ pdPlayTime ] = 0;
    
    nvault_set_array( g_Vault , pdData[ pdAuthID ] , pdData[ pdAuthID ][ 0 ] , sizeof( pdData ) );
    
    get_players( iPlayers , iNum , "ch" );
    
    for ( new i = 0 ; i < iNum ; i++ )
    {
        iPlayer = iPlayers[ i ];
        
        if ( equal( pdData[ pdAuthID ] , g_pdData[ iPlayer ][ pdAuthID ] ) )
        {
            g_pdData[ iPlayer ][ pdIsBlackListed ] = false;
            g_pdData[ iPlayer ][ pdPlayTime ] = 0;
            
            break;
        }
    }
    
    client_print( id , print_chat , "* Removed %s from the blacklist." , szName );
}

FormatTime( iSeconds , szBuffer[] , iSize )
{
    new iPos;
    
    new iDays = iSeconds / 86400;
    iSeconds -= iDays * 86400;
    
    new iHours = iSeconds / 3600;
    iSeconds -= iHours * 3600;
    
    new iMinutes = iSeconds / 60;
    iSeconds -= iMinutes * 60;
    
    if ( iDays )
        iPos = formatex( szBuffer , iSize , "%d day%s, " , iDays , iDays > 1 ? "s" : "" );
    
    if ( iHours )
        iPos += formatex( szBuffer[ iPos ] , iSize-iPos , "%d hour%s, " , iHours , iHours > 0 ? "s" : "" );
        
    if ( iMinutes )
        iPos += formatex( szBuffer[ iPos ] , iSize-iPos , "%d minute%s, " , iMinutes , iMinutes > 0 ? "s" : "" );
        
    szBuffer[ iPos - 2 ] = EOS;
    
    return iPos;
}

Re: [REQ] Play Time

There are two errors in compiling

PHP Code:


		
			
nvault_array.inc(42) : error 021: symbol already defined: "nvault_set_array"

nvault_array.inc(80) : error 021: symbol already defined: "nvault_get_array"