[Wrath]

I need a TF2 plugin

Jarate that damage's and has a afterburn equivilant to the Pyro's flaregun

Thanks

[retsam]

I dont have the code for it, but I dont think it would be that difficult to do.

Youd just need to check if the client threw a jarate, hook player_hurt and for the victim have it do TF_IgnitePlayer or whatever it is for a specified duration.

Youre going to have yellow piss turning into red fire on people and since they are also pissed on, they will be taking extra dmg from the fire but hey.

[pheadxdll]

Really easy to do. Just have a timer running that checks the player condition of all the players. Someone with more time should be able to code this for you.

[bl4nk]

PHP Code:

#pragma semicolon 1

#include <sourcemod>

new Handle:g_hTimerHandle[MAXPLAYERS+1];
new Handle:g_hCvarTime;
new Handle:g_hCvarDamage;

public Plugin:myinfo =
{
    name = "Acid Jarate",
    author = "bl4nk",
    description = "Players take damage while Jarated",
    version = "1.0.0",
    url = "http://forums.alliedmods.net"
};

public OnPluginStart()
{
    g_hCvarTime = CreateConVar("sm_acidjarate_time", "3.0", "Time inbetween each damage tick", FCVAR_PLUGIN, true, 0.1, false, _);
    g_hCvarDamage = CreateConVar("sm_acidjarate_damage", "5", "Damage to do per tick", FCVAR_PLUGIN, true, 1.0, false, _);

    HookEvent("player_jarated", Event_PlayerJarated);
    HookEvent("player_jarated_fade", Event_PlayerJaratedFade);
    HookEvent("player_death", Event_PlayerDeath);
    HookEvent("teamplay_round_start", Event_RoundStart);
}

public OnClientDisconnect(client)
{
    if (g_hTimerHandle[client] != INVALID_HANDLE)
    {
        KillTimer(g_hTimerHandle[client]);
        g_hTimerHandle[client] = INVALID_HANDLE;
    }
}

public OnMapStart()
{
    for (new i = 0; i <= MaxClients; i++)
    {
        g_hTimerHandle[i] = INVALID_HANDLE;
    }
}

public Event_PlayerJarated(Handle:event, const String:name[], bool:dontBroadcast)
{
    new client = GetEventInt(event, "victim_index");
    g_hTimerHandle[client] = CreateTimer(GetConVarFloat(g_hCvarTime), Timer_DamagePlayer, client, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE);
}

public Event_PlayerJaratedFade(Handle:event, const String:name[], bool:dontBroadcast)
{
    new client = GetEventInt(event, "victim_index");

    KillTimer(g_hTimerHandle[client]);
    g_hTimerHandle[client] = INVALID_HANDLE;
}

public Event_PlayerDeath(Handle:event, const String:name[], bool:dontBroadcast)
{
    new client = GetClientOfUserId(GetEventInt(event, "userid"));

    if (g_hTimerHandle[client] != INVALID_HANDLE)
    {
        KillTimer(g_hTimerHandle[client]);
        g_hTimerHandle[client] = INVALID_HANDLE;
    }
}

public Event_RoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
    for (new i = 0; i <= MaxClients; i++)
    {
        if (g_hTimerHandle[i] != INVALID_HANDLE)
        {
            KillTimer(g_hTimerHandle[i]);
            g_hTimerHandle[i] = INVALID_HANDLE;
        }
    }
}

public Action:Timer_DamagePlayer(Handle:timer, any:client)
{
    new damage = GetConVarInt(g_hCvarDamage);
    SetEntProp(
        client,
        Prop_Send,
        "m_iHealth",
        GetEntProp(client, Prop_Send, "m_iHealth") - damage
    );
} 


sm_acidjarate_time 3.0 - Time inbetween each damage tick
sm_acidjarate_damage 5 - Damage to do per tick

[retsam]

Ahhh bl4nk is so nice. ;p I hope he says thank you.

[Wrath]

Many thanks

[Wrath]

I tested it out, it doesnt seem to function, no errors in the log, but no dmg with jarate

[Wrath]

Any clues as to went wrong. Please help

[Theme97]

The Jarate events never actually fire, but they exist.

Anyway, here's my solution. Enjoy it while I brace for attacks on bad coding style.

PHP Code:

#pragma semicolon 1

#include <sourcemod>
#include <sdktools>

#define PL_VERSION "1.0"

public Plugin:myinfo = {
    name        = "Acid Jarate",
    author      = "Theme97",
    description = "Players take damage while Jarated",
    version     = "1.0.0",
    url         = "http://forums.alliedmods.net/"
}

new Handle:cvar_time;
new Handle:cvar_damage;

public OnPluginStart() {
    cvar_time = CreateConVar("sm_acidjarate_time", "3.0", "Time inbetween each damage tick", FCVAR_PLUGIN, true, 0.1, false, _);
    cvar_damage = CreateConVar("sm_acidjarate_damage", "5", "Damage to do per tick", FCVAR_PLUGIN, true, 1.0, false, _);
}

public OnMapStart() {
    CreateTimer(GetConVarFloat(cvar_time), timer_damageplayer);
}

public Action:timer_damageplayer(Handle:timer) {
    new damage = GetConVarInt(cvar_damage), health;
    for (new i = 1; i <= MaxClients; i++) {
        if (IsClientInGame(i) && GetEntData(i, FindSendPropInfo("CTFPlayer", "m_nPlayerCond")) & (1 << 19)) {
            health = GetEntProp(i, Prop_Send, "m_iHealth") - damage;
            if (health < 1) health = 1;
            SetEntProp(i, Prop_Send, "m_iHealth", health);
        }
    }
    CreateTimer(GetConVarFloat(cvar_time), timer_damageplayer);
} 


There's no easy way to check who threw the Jarate, so we can't make the player die by it with the right death message, but if you still want them to die, just change timer_damageplayer:

PHP Code:

public Action:timer_damageplayer(Handle:timer) {
    new damage = GetConVarInt(cvar_damage), health;
    for (new i = 1; i <= MaxClients; i++) {
        if (IsClientInGame(i) && GetEntData(i, FindSendPropInfo("CTFPlayer", "m_nPlayerCond")) & (1 << 19)) {
            health = GetEntProp(i, Prop_Send, "m_iHealth") - damage;
            if (health < 1) {
                ForcePlayerSuicide(i);
            } else {
                SetEntProp(i, Prop_Send, "m_iHealth", health);
            }
        }
    }
    CreateTimer(GetConVarFloat(cvar_time), timer_damageplayer, _, TIMER_FLAG_NO_MAPCHANGE);
} 


[bl4nk]

Originally Posted by Theme97 The Jarate events never actually fire, but they exist.

Are you sure about this? I was using 'net_showevents 2' in my console and saw them fire just fine. I wouldn't have wrote the plugin if I didn't see them go off.