[Dores]

OMG it's exaclty like noclip!
I hate you for your awesomeness Exolent.

[cs1.7]

really cool.

how do you correctly increase velocity?

i have added:

PHP Code:

    static Float:maxspeed;
    pev(client, pev_maxspeed, maxspeed);
    set_pev(client, pev_maxspeed, 600.0); // i have added this line 


..but it acts weird though! The speed is much lower than 600 ..or 500 or whatever. If you press duck though ..it gets (i would guess the full speed)

I dont know if it's a little (cool) typo by Exolent[jNr] where he accidently doubled the speed (instead of halfing it). But: i wonder why the speed gets increased but definitely not as high as demanded in the code. Maybe i set the speed wrong. Please show the correct way.


-----

on a side note: as i was experimenting with setting speed i added:

PHP Code:

    static Float:maxspeed;
    pev(client, pev_maxspeed, maxspeed);
    set_pev(client, pev_maxspeed, maxspeed * 2.0); // i have added this line 


The funny thing: As soon as u go over 1.0, you get the following effect. The "twirl" effect might be very cool for punishments plugins. Like ATAC.
Maybe you can reproduce the "twirl" effect in a "correct way" and create atac_twirl ..or something. Thats just a hint.

http://www.file-upload.eu/download-1...unish.rar.html

[Dores]

Just double the variable with the wanted speed.

PHP Code:

static Float:MaxSpeed ; pev( id, pev_maxspeed, MaxSpeed );
MaxSpeed *= 2.0; // Or whatever.
// Now, after using velocity_by_aim(), it will have a doubled value. 


[Exolent[jNr]]

Instead of using pev_maxspeed, just use a value you want.

[cs1.7]

Originally Posted by Exolent[jNr] Instead of using pev_maxspeed, just use a value you want.

do you mean like:

PHP Code:

    pev(id, pev_maxspeed, maxspeed); 


replace pev_maxspeed with 500

PHP Code:

    pev(id, 500, maxspeed); 


if yes, it does not work.


another thing: if you are in the air and not moving you ..slowly.. sink down to the ground. I could set user gravity to absolute zero to terminate this sinking effect and after deactivating via "say /fly" reset to users previous gravity. Any ideas to remove the sinking effect in a better way?

[Exolent[jNr]]

No, I mean change the whole "maxspeed" part to your value:

PHP Code:

    static Float:maxspeed;
    //pev(client, pev_maxspeed, maxspeed);
    maxspeed = 250.0; 


Gravity would be the best way to fix the sinking.

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

#define NOCLIP_SPEED 250.0

new bool:g_flying[33];

public plugin_init()
{
    register_plugin("Noclip Simulator", "0.1", "Exolent");
    
    register_clcmd("say /fly", "CmdFly");
    
    register_forward(FM_PlayerPreThink, "FwdPlayerPreThink");
}

public client_disconnect(client)
{
    g_flying[client] = false;
}

public CmdFly(client)
{
    g_flying[client] = !g_flying[client];
    
    client_print(client, print_chat, "You are no%s flying.", g_flying[client] ? "w" : " longer");
    
    set_pev(client, pev_gravity, g_flying[client] ? 0.000001 : 1.0);
    
    return PLUGIN_HANDLED;
}

public FwdPlayerPreThink(client)
{
    if( !g_flying[client] || !is_user_alive(client) ) return;
    
    set_pev(client, pev_movetype, MOVETYPE_FLY);
    
    new Float:maxspeed = NOCLIP_SPEED;
    if( is_user_ducking(client) )
    {
        // I don't know the real calculation for ducking velocity
        // but this will have to do for now
        maxspeed /= 2.0;
    }
    
    static Float:aim_velocity[3];
    velocity_by_aim(client, floatround(maxspeed), aim_velocity);
    
    static Float:client_origin[3];
    pev(client, pev_origin, client_origin);
    
    new button = pev(client, pev_button);
    
    new Float:velocity[3];
    if( button & IN_FORWARD )
    {
        velocity[0] += aim_velocity[0];
        velocity[1] += aim_velocity[1];
        velocity[2] += aim_velocity[2];
    }
    if( button & IN_BACK )
    {
        velocity[0] -= aim_velocity[0];
        velocity[1] -= aim_velocity[1];
        velocity[2] -= aim_velocity[2];
    }
    if( button & IN_MOVERIGHT )
    {
        // angle velocity_aim -90 degrees
        
        //velocity[0] += ((floatcos(-90.0, degrees) * velocity_aim[0]) - (floatsin(-90.0, degrees) * velocity_aim[1]));
        //                 cos 90 = 0                                     sin -90 = -1
        //               (( 0 * velocity_aim[0] ) - ( -1 * velocity_aim[1] ))
        //               velocity_aim[1]
        velocity[0] += aim_velocity[1];
        
        //velocity[1] += ((floatsin(-90.0, degrees) * velocity_aim[0]) - (floatcos(-90.0, degrees) * velocity_aim[1]));
        //                sin -90 = -1                                      cos -90 = 0
        //               (( -1 * velocity_aim[0] ) - ( 0 * velocity_aim[1] ))
        //               -velocity_aim[0]
        velocity[1] -= aim_velocity[0];
    }
    if( button & IN_MOVELEFT )
    {
        // angle velocity_aim 90 degrees
        
        //velocity[0] += ((floatcos(90.0, degrees) * velocity_aim[0]) - (floatsin(90.0, degrees) * velocity_aim[1]));
        //               cos 90 = 0                                      sin 90 = 1
        //               (( 0 * velocity_aim[0] ) - ( 1 * velocity_aim[1] ))
        //               -velocity_aim[1]
        velocity[0] -= aim_velocity[1];
        
        //velocity[1] += ((floatsin(90.0, degrees) * velocity_aim[0]) - (floatcos(90.0, degrees) * velocity_aim[1]));
        //               sin 90 = 1                                      cos 90 = 0
        //               (( 1 * velocity_aim[0] ) - ( 0 * velocity_aim[1] ))
        //               velocity_aim[0]
        velocity[1] += aim_velocity[0];
    }
    
    set_pev(client, pev_velocity, velocity);
}

// modified from kz_ljs_xm
bool:is_user_ducking(client)
{
    static Float:absmin[3], Float:absmax[3];
    pev(client, pev_absmin, absmin);
    pev(client, pev_absmax, absmax);
    
    return ( (absmax[2] - absmin[2]) > 64.0 );
} 


[cs1.7]

just that you know:


the speed values with this pev_maxspeed seemingly do not equal the actual cs speeds in game. i mean if i put

PHP Code:

#define NOCLIP_SPEED 600.0 


then i would say it's actually like 300.0. it's much slower. half?

the same thing as i reported about

PHP Code:

  static Float:maxspeed;
    pev(client, pev_maxspeed, maxspeed);
    set_pev(client, pev_maxspeed, 600.0); // i have added this line 


it must be the way pev_maxspeed works. your code is perfect.

this one of my new fav plugins.

edit
i think it's something else:
ey, could it be that the is_user_ducking part of your code divides and affects the regular flying speed too?

i mean i just set

if( is_user_ducking(id) )
{
// I don't know the real calculation for ducking velocity
// but this will have to do for now
maxspeed /= 1.0;
}

and i truely flew as fast as 600.0

the regular flying speed is beeing divided by the value of is_user_ducking. So if u set is_user_ducking = 1.0 , then u get the full speed of #define NOCLIP_SPEED

[Dores]

Side note: You should know that: num / 1 = num. But you seem to ignore me anyways.

[cs1.7]

it works awesome. i just wondered why it behaved like that.

Exolent[jNr] is gonna get alot of karmas from me. i was on this for two years now..lol


maybe i should create a vid.

[cs1.7]

ey Exolent[jNr]

this is by far one of my fav codes.

I just found out something though.


If you are in the sky and look/aim on your feet ..then you almost cant move sidewards..with A or D.

The same goes if you look in the opposite direction. Look straight in the air..then it's the same problem..if ou try to move to the sides (A or D) ..then you almost can't move too.

I have the feeling the more you aim upwards/downwards..the slower you are if you want to move to the side (A or D).