[oddbilly]

hey this is odd from odd scoutzknivez server cs:cz

as many of u know the (developer 1) setting boosts fps and if u turn off vsync u can reach 200+ fps...these settings combined with the scoutzknivez map settings allows a retarded amount of strafing....

i need a plugin that does not allow anyone to turn on developer 1 at all
someone made a plugin that sets everyones developer to 0 every few seconds but someone made a scripts that overides it...

contact me for questions or if u have suggestions
help anyone

[ConnorMcLeod]

Try this :

#include <amxmodx>

#define MAXPLAYERS  32

new max_reset
new count[MAXPLAYERS+1]

public plugin_init() {
    register_plugin("Check fps", "1.0", "connor")
    max_reset = register_cvar("max_bad_value", "5")
}

public plugin_cfg() {
    set_task(5.0, "fps_check", _, _, _, "b")
}

public client_connect(id) {
    count[id] = 0
}

public client_disconnect(id) {
    count[id] = 0
}

public fps_check() {
    new players[MAXPLAYERS], inum
    get_players(players, inum, "ch") //don't collect BOTs & HLTVs
    for(new i; i<inum; ++i)
    {
        query_client_cvar(players[i] , "fps_max" , "cvar_result")
        query_client_cvar(players[i] , "developer" , "cvar_result")
    }
}

public cvar_result(id, const cvar[], const value[])
{
    if(equal(value, "Bad CVAR request"))
    {
        server_cmd("kick #%d Please remove the alias that blocks fps_max or developer cvar", get_user_userid(id))
    }

    new iValue = str_to_num(value)
    if(equal(cvar,"fps_max"))
    {

        if(iValue > 101)
        {
            client_cmd(id, "fps_max 101")
            client_print(id, print_chat, "Your ^"fps_max^" cvar has been set to 101, don't touch it")
            count[id]++
        }
    }
    else if(equal(cvar,"developer"))
    {
        if(iValue)
        {
            //developer is higher than 0
            client_cmd(id, "developer 0")
            client_print(id, print_chat, "Your ^"developer^" cvar has been set to 0, don't touch it")
            count[id]++
        }
    }
    
    if(count[id] == get_pcvar_num(max_reset))
        server_cmd("kick #%d You have bad cvar values to play on this server", get_user_userid(id))
}

attachment below is only with developer feature :

[oddbilly]

i dont need to check for fps_max only developer 1
if they have dev 1 then kick with msg "youve been kicked for using developer 1"or something would be great..
i dont mod nor do i compile so i need the actuall amxx file
thanks alot for the quick response

[oddbilly]

thank u im going to test now
...testing looks good
thanks

[oddbilly]

it seems they have found a way around this blocker by setting it to developer 0.9 ...can we add it so anything but 0 gets changed back to 0 or kick

[v3x]

#include <amxmodx>

public plugin_init()
    register_plugin("Dev blocker", "1.0", "v3x");

public client_infochanged(id)
    CheckForDev(id);

public client_putinserver(id)
    CheckForDev(id);

public CheckForDev(id)
{
    new info[2];
    get_user_info(id, "developer", info, 1);

    if(str_to_num(info) != 0)
    {
        client_print(id, print_console, "* Developer must be set to 0 in this server");
        set_user_info(id, "developer", "0");
    }
}

That should do the trick.

[ConnorMcLeod]

I'm not sure your method works, as you also convert first result char into an integer.

Try this :

PHP Code:

#include <amxmodx>

#define MAXPLAYERS    32

new g_pcvarMaxCount
new g_iCount[MAXPLAYERS+1]

public plugin_init()
{
    register_plugin("Developer 0", "1.0.1", "connorr")
    g_pcvarMaxCount = register_cvar("max_bad_value", "2")

    set_task(10.0, "taskDeveloperCheck", _, _, _, "b")
}

public client_putinserver(id)
{
    g_iCount[id] = 0
}

public taskDeveloperCheck()
{
    new players[MAXPLAYERS], inum
    get_players(players, inum, "ch") //don't collect BOTs & HLTVs
    for(new i; i<inum; ++i)
    {
        query_client_cvar(players[i] , "developer" , "cvar_result")
    }
}

public cvar_result(id, const cvar[], const value[])
{
    new Float:fValue = str_to_float(value)

    if(!fValue)
        return

    client_cmd(id, "developer 0")
    client_print(id, print_chat, "Your ^"developer^" cvar has been set to 0, don't change it")
    
    if(++g_iCount[id] >= get_pcvar_num(g_pcvarMaxCount))
    {
        server_cmd("kick #%d Developer isn't allowed on this server", get_user_userid(id))
    }
} 


[Halflifeplayer]

You should use this plugin and you can block and set whatever cvar you want your choice

AMX CVAR Guard - AlliedModders

I use it if you try to type in the command says this cvar is blocked. This plugin blocks it all the time no matter what...

CS must be weird cause someons fps shouldn't effect how they move in game. FPS is how fast they render frames. How fast you render frames can't make the game play speed up in the real game. Plus if they don't have there monitor set to refresh the same amount they don't even see those frames. Plus if there cl_cmdrate is lower than there fps there not even sending that many updates. But I am sure you don't want to hear the netcode crap....

This cvar guard works perfect you pick the cvar and the setting and it is blocked they can't excute the command at anytime while there in your server.

[ConnorMcLeod]

Originally Posted by Halflifeplayer You should use this plugin and you can block and set whatever cvar you want your choice AMX CVAR Guard - AlliedModders I use it if you try to type in the command says this cvar is blocked. This plugin blocks it all the time no matter what... CS must be weird cause someons fps shouldn't effect how they move in game. FPS is how fast they render frames. How fast you render frames can't make the game play speed up in the real game. Plus if they don't have there monitor set to refresh the same amount they don't even see those frames. Plus if there cl_cmdrate is lower than there fps there not even sending that many updates. But I am sure you don't want to hear the netcode crap.... This cvar guard works perfect you pick the cvar and the setting and it is blocked they can't excute the command at anytime while there in your server.

If you block your cvar before joining the server, this plugin just does nothing

[MAUGHOLD]

Originally Posted by oddbilly hey this is odd from odd scoutzknivez server cs:cz as many of u know the (developer 1) setting boosts fps and if u turn off vsync u can reach 200+ fps...these settings combined with the scoutzknivez map settings allows a retarded amount of strafing.... i need a plugin that does not allow anyone to turn on developer 1 at all someone made a plugin that sets everyones developer to 0 every few seconds but someone made a scripts that overides it... contact me for questions or if u have suggestions help anyone

From what I understand, Setting devloper to 1 doesn't really give you any higher FPS it just looks like it does. HLDS has a hard coded FPS of 100 max.