[CSDM] Disable the "one team joining peer round"

DA · **Author**

Hey guys,

Everyone know the problem with csdm when someone cheat and you want to make a demo but you can't join the spectator without reconnect to the server. Also I need a plugin who admins can join a team or the spectator more than ones a round. I hope someone can make it.

teame06 · *Last edited by teame06; 10-02-2006 at 13:06.*

Code:

/**
 * csdm_main.sma
 * Allows for Counter-Strike to be played as DeathMatch.
 *
 * CSDM Main - Main plugin to communicate with module
 *
 * (C)2003-2006 David "BAILOPAN" Anderson
 *
 *  Give credit where due.
 *  Share the source - it sets you free
 *  <a href="http://www.opensource.org/" target="_blank" rel="nofollow noopener">http://www.opensource.org/</a>
 *  <a href="http://www.gnu.org/" target="_blank" rel="nofollow noopener">http://www.gnu.org/</a>
 */

#include <amxmodx>
#include <amxmisc>
#include <csdm>

new bool:g_StopRespawn[33]

public csdm_Init(const version[])
{
    if (version[0] == 0)
    {
        set_fail_state("CSDM failed to load.")
        return
    }
}

public plugin_init()
{
    register_plugin("CDSM Stop Respawn", "1.0", "teame06")
    register_clcmd("amx_respawn", "restore_respawn", ADMIN_LEVEL_G, "Stop/Restore Spawns")
}

public csdm_PostDeath(killer, victim, headshot, const weapon[])
{
    if(g_StopRespawn[victim])
        return PLUGIN_HANDLED

    return PLUGIN_CONTINUE
}

public restore_respawn(id,lvl,cid)
{
    if(!cmd_access(id,lvl,cid,1))
        return PLUGIN_HANDLED

    new teamid = get_user_team(id)
    if(teamid == _TEAM_T || teamid == _TEAM_CT)
    {
        if(g_StopRespawn[id])
        {
            g_StopRespawn[id] = false
            csdm_respawn(id)

            console_print(id, "Spawning is re-enable")
            return PLUGIN_HANDLED
        }
        else
        {
            g_StopRespawn[id] = true
            user_silentkill(id)

            console_print(id, "Stop re-spawning")
            return PLUGIN_HANDLED
        }
    }
    return PLUGIN_CONTINUE
}

public client_connect(id)
{
    g_StopRespawn[id] = false
}

This is a script I made along time ago. This will allow your admin to spectate while still in a team. All it does it stop your respawn and kill the admin so he can spectate.

DA · 10-02-2006 , 14:25 Re: [CSDM] Disable the "one team joining peer round"

A question. Is it the csdm_main plugin?
Also must I overwrite the csdm_main plugin?

teame06 · 10-02-2006 , 14:49 Re: [CSDM] Disable the "one team joining peer round"

It just another addon plugin for CSDM. You can name the file what ever you want. I just called it csdm_stop_respawn.sma

DA · 10-02-2006 , 15:42 Re: [CSDM] Disable the "one team joining peer round"

hmm. Thats really nice. But there is a bug. When I write amx_respawn in the console then I don't respawn. That's right. Okay. Then I want to play further and I write in the chat respawn. Okay. Then I respawn and I get killed. But then I must write again respawn. And then I killed again. And I must again write respawn in the console. You know what I mean? ;)
Can you fix it for me please?

teame06 · 10-02-2006 , 15:59 Re: [CSDM] Disable the "one team joining peer round"

You need to type amx_respawn again to enable your respawn again and it will force respawn you. This plugin wasn't design for you to type /respawn in chat.

DA · 10-02-2006 , 16:59 Re: [CSDM] Disable the "one team joining peer round"

Oh. Thanks. Working great.

+ Karma

DA · 10-19-2006 , 14:35 Re: [CSDM] Disable the "one team joining peer round"

Hey,

Sorry for pushing up this thread but I need your help.
I want that everyone on the server can use this function.
I have try myself to change the plugin but it works not.

Here is my script:

Code:

/**
 * csdm_main.sma
 * Allows for Counter-Strike to be played as DeathMatch.
 *
 * CSDM Main - Main plugin to communicate with module
 *
 * (C)2003-2006 David "BAILOPAN" Anderson
 *
 *  Give credit where due.
 *  Share the source - it sets you free
 *  <a href="http://www.opensource.org/" target="_blank">http://www.opensource.org/</a>
 *  <a href="http://www.gnu.org/" target="_blank">http://www.gnu.org/</a>
 */

#include <amxmodx>
#include <amxmisc>
#include <csdm>

new bool:g_StopRespawn[33]

public csdm_Init(const version[])
{
    if (version[0] == 0)
    {
        set_fail_state("CSDM failed to load.")
        return
    }
}

public plugin_init()
{
    register_plugin("CDSM Stop Respawn", "1.0", "teame06")
    register_clcmd("say", "HandleSay")
}

public csdm_PostDeath(killer, victim, headshot, const weapon[])
{
    if(g_StopRespawn[victim])
        return PLUGIN_HANDLED

    return PLUGIN_CONTINUE
}

public HandleSay(id,lvl,cid)
{
    new Speech[192];
    read_args(Speech,192);
    remove_quotes(Speech);
    
    if(equali(Speech,"stoprespawn"))
    {
    new teamid = get_user_team(id)
    if(teamid == _TEAM_T || teamid == _TEAM_CT)
    {
        if(g_StopRespawn[id])
        {
            g_StopRespawn[id] = false
            csdm_respawn(id)

            console_print(id, "Spawning is re-enable")
            return PLUGIN_HANDLED
        }
            else
            {
            g_StopRespawn[id] = true
            user_silentkill(id)

            console_print(id, "Stop re-spawning")
            return PLUGIN_HANDLED
            }
    }
    }
return PLUGIN_CONTINUE
}

It works but sometimes when players connect the command is autmaticle on.
I hope you can help me.

teame06 · 10-19-2006 , 14:46 Re: [CSDM] Disable the "one team joining peer round"

Re-Add this code below. You didn't copy it from my script above. So you left it out.

Code:

public client_connect(id)
{
    g_StopRespawn[id] = false;
}

DA · 10-19-2006 , 15:47 Re: [CSDM] Disable the "one team joining peer round"

ahh. Thanks. I test it out.