[Alucard^]

Bueno, les comento lo que hace este plugin y dsp les digo mi problema...

El plugin convierte los frags y deaths del scoreboard (al apretar TAB) en Health y Armor (Vida y Chaleco). Se actualiza al respawnear... se actualiza al recibir daño, se actualiza al comprar armor...

Y tambien hace que al matar a alguien o al morir no cuenten los frags y deaths.... solo muestra la vida y el armor.

El unico problema (por lo menos el unico que note al testearlo)... es que al matar a alguien, el armor se va a 0 (cuando en realidad no tengo 0, tengo mas)... Si dsp de eso recibo daño o respawneo, el armor se vuelve a actualizar bien... pero weno la idea es que no pase eso de que se vaya a 0...

PHP Code:

#include <amxmodx>
#include <fun>
#include <cstrike>
#include <hamsandwich>

#define PLUGIN    "Health/Armor in Scoreboard"
#define AUTHOR    "Alucard"
#define VERSION    "1.0"

new Health, Armor, Teams

new g_msgArmorType, g_msgHealth, g_msgScoreInfo

new p_dead

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    p_dead = register_cvar("ha_dead", "1")

    register_clcmd("kill", "HookCmdKill")
    
    RegisterHam(Ham_Spawn, "player", "HookSpawn", 1)
    
    register_event("DeathMsg", "DeathMsg", "a")

    g_msgArmorType = get_user_msgid("ArmorType")
    g_msgHealth = get_user_msgid("Health")
    g_msgScoreInfo = get_user_msgid("ScoreInfo")
    
    register_message(g_msgHealth, "HookGeneral")
    register_message(g_msgArmorType, "HookGeneral")
}

public HookCmdKill(id)
{
    set_user_frags(id, 0)
    cs_set_user_deaths(id, 0)
}

public HookSpawn(id)
{
    Health = get_user_health(id)
    Armor = get_user_armor(id)
    
    set_user_frags(id, Health)
    cs_set_user_deaths(id, Armor)
}

public HookGeneral(msg_id, msg_dest, id)
{
    Health = get_user_health(id)
    Armor = get_user_armor(id)
    Teams = get_user_team(id)
    
    if(get_pcvar_num(p_dead) )
    {
        if(Health < 0)
        {
            Health = 0
            Armor = 0
        }
        message_begin(MSG_ALL,g_msgScoreInfo)
        write_byte(id)  
        write_short(Health) 
        write_short(Armor) 
        write_short(0) 
        write_short(Teams) 
        message_end()
    }
}


public DeathMsg()
{
    new Killer = read_data(1)
    //new Victim = read_data(2)
    
    Health = get_user_health(Killer)
    Armor = get_user_armor(Killer)
    
    set_user_frags(Killer, Health - 1)
    cs_set_user_deaths(Killer, Armor)
} 


A ver si alguien sabe como puedo resolver esto... tmb pido ayuda para optimizarlo, estoy casi seguro que se puede optimizar bastante el plugin...

Cabe aclarar tmb que lo del HookCmdKill lo agregue al final y no lo probe... y no estoy seguro si el comando "kill" es hookeable, aunque supongo que si. Podria haber usado el forward client_connect, pero si se puede hookear es mejor de esta forma asi no tengo que incluir el modulo engine.

[L//]

Arregla el orden de esto

PHP Code:

    register_message(g_msgHealth, "HookGeneral")
    register_message(g_msgArmorType, "HookGeneral")

    g_msgArmorType = get_user_msgid("ArmorType")
    g_msgHealth = get_user_msgid("Health")
    g_msgScoreInfo = get_user_msgid("ScoreInfo") 


cambialo a ...

PHP Code:

    g_msgArmorType = get_user_msgid("ArmorType")
    g_msgHealth = get_user_msgid("Health")
    g_msgScoreInfo = get_user_msgid("ScoreInfo")

    register_message(g_msgHealth, "HookGeneral")
    register_message(g_msgArmorType, "HookGeneral") 


Sino no estarias registrando los mensajes correctamente. Proba cambiando eso, si no funciona, lo sigo mirando

[Alucard^]

Jaja, justamente eso lo cambie cuando lo postie, solo por que me parecia mas comodo leerlo asi :E pero lo testie de la forma que pusiste al final... asi que ese no es el problema =(

Igual gracias ;)

PD: Ahi cambie lo que dijiste.

[L//]

Mira... no lo pude testear, asi que nose si anda.

PHP Code:

#include <amxmodx>
#include <fun>
#include <cstrike>
#include <fakemeta>
#include <hamsandwich>

#define PLUGIN    "Health/Armor in Scoreboard"
#define AUTHOR    "Alucard (EDITADO por L//)"
#define VERSION    "1.0"

new health, armor

new g_msgArmorType, g_msgHealth, g_msgScoreInfo

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_forward(FM_ClientKill, "fw_clientkill")
    
    RegisterHam(Ham_Killed, "player", "fw_playerkilled")
    RegisterHam(Ham_Spawn, "player", "HookSpawn", 1)

    g_msgArmorType = get_user_msgid("ArmorType")
    g_msgHealth = get_user_msgid("Health")
    g_msgScoreInfo = get_user_msgid("ScoreInfo")
    
    register_message(g_msgHealth, "HookGeneral")
    register_message(g_msgArmorType, "HookGeneral")
}

// Client Kill Forward
public fw_clientkill(id)
{
    set_user_frags(id, 0)
    cs_set_user_deaths(id, 0)
    
    update_scoreboard(id, 0, 0)
    
    return FMRES_IGNORED
}

public HookSpawn(id)
{
    health = get_user_health(id)
    armor = get_user_armor(id)    
    
    set_user_frags(id, health)
    cs_set_user_deaths(id, armor)
    
    update_scoreboard(id, health, armor)
}

public HookGeneral(msg_id, msg_dest, id)
{
    health = get_user_health(id)
    armor = get_user_armor(id)
    
    if(health < 0)
    {
        health = 0
        armor = 0
    }
    
    update_scoreboard(id, health, armor)
}

// Ham Player Killed Forward
public fw_playerkilled(victim, attacker, shouldgib)
{
    health = get_user_health(attacker)
    armor = get_user_armor(attacker)        
    
    set_user_frags(attacker, health)
    cs_set_user_deaths(attacker, armor)
    
    set_user_frags(victim, 0)
    cs_set_user_deaths(victim, 0)
    
    update_scoreboard(attacker, health, armor)
    update_scoreboard(victim, 0, 0)
}

update_scoreboard(id, healt, armor)
{
    message_begin(MSG_BROADCAST, g_msgScoreInfo)
    write_byte(id)                 // id
    write_short(healt)                 // frags
    write_short(armor)                 // deaths
    write_short(0)                    // class?
    write_short(get_user_team(id))     // team
    message_end()
} 


[Kiske]

El problema del Plugin es que va a ser Confuso si no editas donde dice SCORE
Porque donde diga SCORE dira la Vida, y donde diga DEATHS dira el Escudo

[Alucard^]

@kiske

Si pero hasta lo que yo, no se puede editar eso y nah no mo molesta igual... con un simple client_print podes avisar de que tratan los frags y deaths en el plugin... eso dsp lo agrego. Este tipo de plugins es para mods donde los frags no interesan, como por ej el surf o kz.

@ L//

No funca =( El mismo problema... al matar se me pone 0 el armor. Y ahora con este plugin al matar a alguien me suma 1 frag.

Realmente no entiendo porque me pone en 0 el armor. Si justamente le seteo los deaths como el armor al matar.

PHP Code:

cs_set_user_deaths(id, Armor) 


[Starsailor]

Proba este:

PHP Code:

#include <amxmodx>
#include <fakemeta>

#define PLUGIN    "Health/Armor in Scoreboard"
#define AUTHOR    "Alucard"
#define VERSION    "1.0"

new Health, Armor, Teams

new g_msgScoreInfo

new p_dead

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    p_dead = register_cvar("ha_dead", "1")
    
    register_forward(FM_CmdStart,"FwdCmdStart")
    
    g_msgScoreInfo = get_user_msgid("ScoreInfo")
}

public FwdCmdStart(id, uc_handle, seed)
{
    if(get_uc(uc_handle, UC_Buttons) & IN_SCORE)
    {
        UpdateScoreboard(id)
    }
    
}

public UpdateScoreboard(id)
{
    if(!get_pcvar_num(p_dead))
    {
        return FMRES_IGNORED
    }
    
    Health = get_user_health(id)
    Armor = get_user_armor(id)
    Teams = get_user_team(id)
    
    if(!is_user_alive(id))
    {
        Health = 0
        Armor = 0
    }
    
    message_begin(MSG_ALL,g_msgScoreInfo)
    write_byte(id)  
    write_short(Health) 
    write_short(Armor) 
    write_short(0) 
    write_short(Teams) 
    message_end()
    
    return FMRES_IGNORED
} 


No se si es la forma mas eficiente de hacerlo, pero en mi server anduvo bien

[Alucard^]

Muchas Gracias Starsailor... tu metodo me sirvio....

Igualmente, gracias a todos.

http://forums.alliedmods.net/showthread.php?t=103809