[Paaf]

Hi there,

I'm trying to detect when a player is knifed by a teammate.
That's not that easy because the player is not hurt or anything...
No way to hook "player_hurt" or OnTakeDamage...

Have you got an idea ?

[Razmo51]

OnTakeDamage (from SDKhooks) works between teammate's damages

[Mathias.]

PHP Code:

#include <sourcemod>
#include <sdktools>

new g_iWeaponOffset = -1;

public OnPluginStart()
{
    g_iWeaponOffset = FindSendPropOffs("CBaseCombatCharacter", "m_hMyWeapons");
}

public Action:OnPlayerRunCmd(client, &buttons, &impulse, Float:vel[3], Float:angles[3], &weapon)
{
    // If player attack
    if (buttons & IN_ATTACK)
    {
        // Check if he currently hold a knife
        weapon = GetEntDataEnt2(client, g_iWeaponOffset+(2*4));
        if(weapon > 0 && IsValidEdict(weapon))
        {
            decl String:weaponName[64];
            GetEdictClassname(weapon, weaponName,64);
            if(StrEqual(weaponName, "weapon_knife"))
            {
                // Now check if the player is looking at a teamate
                new target = GetClientAimTarget(client, true);
                if (target != -1 && GetClientTeam(client) == GetClientTeam(target))
                {
                    // Check the distance between the two player to see if the attack could be done, since I am not sure of the distance I will put a guess number but I'm sure u can figure it out
                    decl Float:clientPos[3], Float:targetPos[3];
                    GetClientAbsOrigin(client, clientPos);
                    GetClientAbsOrigin(target, targetPos);
                    if (GetVectorDistance(clientPos, targetPos) <= 80.0)
                    {
                        PrintToChat(client, "I have knifed my teamate %N without friendly fire and detected it.", target);
                    }
                }
            }
        }
    }
} 


I did compile with not error but not tested it yet, it should work. Have fun.

[Mathias.]

Okay I have tested my version and it do not work cause I use the same variable weapon and I use an other way to get the current player weapon. In the follow code it does everything you need but I have added blocking attack and since the GetClientAim is not perfect you absoluty need to aim correctly on the play to make it work. 120 units is a good distance because when the player run you can get it at this distance, but you can make it shorter between 80~120 depending on your use.

PHP Code:

#include <sourcemod>
#include <sdktools>

public Action:OnPlayerRunCmd(client, &buttons, &impulse, Float:vel[3], Float:angles[3], &weapon)
{

    decl attacks;
    // If player attack (append left or and right click)
    if (buttons & IN_ATTACK)
    {
        attacks |= IN_ATTACK;
    }
    
    if (buttons & IN_ATTACK2)
    {
        attacks |= IN_ATTACK2;
    }
    
    // if attacks happened
    if (attacks)
    {
        // Check if he currently hold a knife
        new iWeapon = GetEntPropEnt(client, Prop_Send, "m_hActiveWeapon");
        if(iWeapon > 0 && IsValidEdict(iWeapon))
        {
            decl String:weaponName[64];
            GetEdictClassname(iWeapon, weaponName,64);
            if(StrEqual(weaponName, "weapon_knife"))
            {
                // Now check if the player is looking at a teamate
                new target = GetClientAimTarget(client, true);
                if (target != -1 && GetClientTeam(client) == GetClientTeam(target))
                {
                    // Check the distance between the two player to see if the attack could be done, since I am not sure of the distance I will put a guess number but I'm sure u can figure it out
                    decl Float:clientPos[3], Float:targetPos[3];
                    GetClientAbsOrigin(client, clientPos);
                    GetClientAbsOrigin(target, targetPos);
                    if (GetVectorDistance(clientPos, targetPos) <= 120.0)
                    {
                        PrintToChat(client, "Attack cancel on %N.", target);
                        buttons &= ~attacks;
                    }
                }
            }
        }
    }
} 


[Bacardi]

Here, all four SDKHook type what detect attack.

PHP Code:

#include <sourcemod>
#include <sdkhooks>

public OnPluginStart()
{
    // Reload plugin during game ? Hook players again.
    for(new i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i))
        {
            OnClientPutInServer(i);
        }
    }
}

public OnClientPutInServer(client)
{
    SDKHook(client, SDKHook_TraceAttack,        TraceAttack);
    SDKHook(client, SDKHook_TraceAttackPost,    TraceAttackPost);
    SDKHook(client, SDKHook_OnTakeDamage,        OnTakeDamage);
    SDKHook(client, SDKHook_OnTakeDamagePost,    OnTakeDamagePost);
}

public Action:TraceAttack(victim, &attacker, &inflictor, &Float:damage, &damagetype, &ammotype, hitbox, hitgroup)
{
    if(attacker > 0 && attacker <= MaxClients) // Attacker is one of client indexs
    {
        if(attacker != victim)    // Victim else than attacker himself
        {
            if(GetClientTeam(attacker) == GetClientTeam(victim))    // Both are same team
            {
                PrintToServer("TraceAttack %N %N", attacker, victim);
            }
        }
    }
}

public TraceAttackPost(victim, attacker, inflictor, Float:damage, damagetype, ammotype, hitbox, hitgroup)
{
    if(attacker > 0 && attacker <= MaxClients)
    {
        if(attacker != victim)
        {
            if(GetClientTeam(attacker) == GetClientTeam(victim))
            {
                PrintToServer("TraceAttackPost %N %N", attacker, victim);
            }
        }
    }
}

public Action:OnTakeDamage(victim, &attacker, &inflictor, &Float:damage, &damagetype)
{
    if(attacker > 0 && attacker <= MaxClients)
    {
        if(attacker != victim)
        {
            if(GetClientTeam(attacker) == GetClientTeam(victim))
            {
                PrintToServer("OnTakeDamage %N %N", attacker, victim);
            }
        }
    }
}

public OnTakeDamagePost(victim, attacker, inflictor, Float:damage, damagetype)
{
    if(attacker > 0 && attacker <= MaxClients)
    {
        if(attacker != victim)
        {
            if(GetClientTeam(attacker) == GetClientTeam(victim))
            {
                PrintToServer("OnTakeDamagePost %N %N", attacker, victim);
            }
        }
    }
} 


[Paaf]

Thx Bacardi, I will test those four SDKHook types and see if one of them can be used.

If not, I will use the code of Black-Rabbit. At least, I'm sure this way works, I just need to adjust the distance as you said. Thank you for your answer and testing

I will test this this afternoon and keep you informed.

[Bacardi]

Originally Posted by Paaf Thx Bacardi, I will test those four SDKHook types and see if one of them can be used.

Those will work if you not have outdated sdkhooks gamedata files.

Originally Posted by Paaf If not, I will use the code of Black-Rabbit. At least, I'm sure this way works, I just need to adjust the distance as you said.

...I certainly would not use.

[Paaf]

Okey, after testing TraceAttack (from SDKHook) works perfectly :

SDKHook(client, SDKHook_TraceAttack, TraceAttack);

Thank you all for your answer !

[Mathias.]

This is nice to know.

Thank for sharing.
Black-Rabbit