[MmikiM]

[pl]
BOMB_MESSAGE = Bomba zostala podlozona... Ale nie slychac jej!

Polish translate

[Kukulis :*]

Lithuanian

[lt]
BOMB_MESSAGE = Bomba buvo padeta. Bet padeta be jokio garso!

[Nextra]

This should be better performance-wise (sorry for not explaining and just giving the code).

PHP Code:

#include <amxmodx>
#include <fakemeta>

new const g_bomb_sounds[] = 
{
    "c4_beep1.wav",
    "c4_beep2.wav",
    "c4_beep3.wav",
    "c4_beep4.wav",
    "c4_beep5.wav",
    "c4_click.wav"
}

new cvar_enabled
new g_forward = -1

public plugin_init()
{
    register_plugin("Silent Bomb", "1.0", "fezh")

    cvar_enabled = register_cvar("amx_silent_bomb", "1")

    register_logevent("logevent_plantedthebomb", 3, "2=Planted_The_Bomb")
    register_logevent("logevent_roundstart", 2, "1=Round_Start")
    register_dictionary("silent_bomb.txt")
}

public fw_EmitSound(ent, channel, const sound[])
{
    if(equal(sound, "weapons/", 8))
    {
        for (new i = 0; i < sizeof g_bomb_sounds; i++)
        {
            if (equal(sound[8], g_bomb_sounds[i]))
            {
                return FMRES_SUPERCEDE;
            }
        }
    }
    return FMRES_IGNORED;
}

public logevent_roundstart()
{
    if(g_forward>-1)
    {
        unregister_forward(FM_EmitSound, g_forward);
        g_forward = -1;
    }
}
public logevent_plantedthebomb()
{
    if (get_pcvar_num(cvar_enabled))
    {
        if(g_forward==-1)
        {
            g_forward = register_forward(FM_EmitSound, "fw_EmitSound");
        }        
        client_print(0, print_chat, "[AMXX] %L", LANG_PLAYER, "BOMB_MESSAGE")
    }
} 


[dorin2oo7]

Romanian Trasnlation

[ro]
BOMB_MESSAGE = Bomba a fost pusa, dar nu are sunet!

[fezh]

Originally Posted by Nextra This should be better performance-wise (sorry for not explaining and just giving the code).

I don't understand the purpose of the optimization.. Obviously if you don't have the cvar enabled the plugin won't work, but the forward still registered.. So is that the reason?

[Alka]

Originally Posted by dorin2oo7 Romanian Trasnlation [ro] BOMB_MESSAGE = Bomba a fost pusa plantata... dar nu are sunet!

Sounds better. ^^'

[Arkshine]

Originally Posted by fezh I don't understand the purpose of the optimization.. Obviously if you don't have the cvar enabled the plugin won't work, but the forward still registered.. So is that the reason?

The purpose is to use the forward EmitSound only when necessary, avoiding unnecessary calls.

[Nextra]

The optimization does two things:
- The forward is only registered when the bomb is actually planted. Therefore avoiding all the equal and get_pcvar_num calls (in an ordinary cs round the bomb is only planted apx one quarter of the round time).
- The sound folder is checked first avoiding the loop for every single sound (even if it is not out of the weapons folder) and allowing you to leave it out of each sound string.

I'm not sure how much the latter benefits performance but the former is definitely a bigger optimization (relative to the overall performance of this plugin).


Agan, sorry for not explaining it right away.

[a.aqua]

Russ translation

[ru]
BOMB_MESSAGE = Bomba ystanovlena.. No zvuk otklu4en ;)

[xPaw]

What about this

PHP Code:

#include <amxmodx>
#include <fakemeta>

new g_Cvar_Enabled;
new g_iForward = -1;

public plugin_init( ) {
    register_plugin("Silent Bomb", "1.0", "fezh");
    
    g_Cvar_Enabled = register_cvar("amx_silent_bomb", "1");
    
    register_logevent( "logevent_plantedthebomb", 3, "2=Planted_The_Bomb" );
    register_logevent( "logevent_roundstart", 2, "1=Round_Start" );
    register_dictionary( "silent_bomb.txt" );
}

public FwdEmitSound( iEntity, iChannel, const szSound[ ] ) {
    if( equal( szSound, "weapons/c4_", 11 ) )
        if( szSound[ 11 ] == 'b' || szSound[ 11 ] == 'c' )
            return FMRES_SUPERCEDE;
    
    return FMRES_IGNORED;
}

public logevent_roundstart( ) {
    if( g_iForward > -1 ) {
        unregister_forward( FM_EmitSound, g_iForward );
        
        g_iForward = -1;
    }
}

public logevent_plantedthebomb( ) {
    if( get_pcvar_num( g_Cvar_Enabled ) ) {
        if( g_iForward == -1 )
            g_iForward = register_forward( FM_EmitSound, "FwdEmitSound" );
        
        client_print( 0, print_chat, "[AMXX] %L", LANG_PLAYER, "BOMB_MESSAGE" );
    }
} 


[ru]
BOMB_MESSAGE = Bomba ustanovlena.. No u nejo net zvuka!

Sounds better ^^