[MistaGee]

Hi,

I need to call a function everytime the clients shoot. How do I do that?

Greetz MGee

[xeroblood]

This is one way I did that in my Prox-Mines plugin:

#include <amxmodx>

// Tracks players Shots-Fired: [0]=WeaponID, [1]=Ammo
new g_iCurrWeapon[33][2]



public plugin_init()
{
    register_event( "CurWeapon", "Event_ShotFired",  "b" )
}

public Event_ShotFired( id )
{
    // Players current weapon data..
    new wID = read_data( 2 )
    new wAmmo = read_data( 3 )

    if( g_iCurrWeapon[id][0] != wID ) // User Changed Weapons..
    {
        g_iCurrWeapon[id][0] = wID
        g_iCurrWeapon[id][1] = wAmmo
        return PLUGIN_CONTINUE
    }
    if( g_iCurrWeapon[id][1] < wAmmo ) // User Reloaded..
    {
        g_iCurrWeapon[id][1] = wAmmo
        return PLUGIN_CONTINUE
    }
    if( g_iCurrWeapon[id][1] == wAmmo ) // User did something else, but didn't shoot..
        return PLUGIN_CONTINUE

    // This far means user shot his/her gun..
    // Save new weapon data..
    g_iCurrWeapon[id][1] = wAmmo
    g_iCurrWeapon[id][0] = wID

    // Do Stuff here..

    return PLUGIN_CONTINUE
}

I hope that helps!

[MistaGee]

maaan this is great, exactly what I needed to finish my plugin!

big THX

this means +karma_4u and
http://forums.alliedmods.net/showthr...=137934#142762