[ItsEvergreen]

Hi. I'm trying to edit the admin_overrides.cfg. I'm trying to set it up on my server so a donator can use a command to teleport to the skybox on my Unusual/Promo Trading server and not have accass to the full teleport command.

The one command I want to work is sm_teleport @me -2389.258056 -4447.823730 307.036804

I can give access to sm_teleport but I want to limit it to the one command only so a user does not have access to the full command.

[VJScope]

adminmenu_grouping:

/* Add group options to be added to 'group' or 'groupplayer' type submenus
 * The left side is the name that will show in the menu, right is the command that will be fired
 *
 * For more information: http://wiki.alliedmods.net/Custom_Admin_Menu_%28SourceMod%29
 */	

Groups
{
	"All"					"@all"
	"Bots"					"@bots"
	"Alive"					"@alive"
	"Dead"					"@dead"
	"Humans"				"@humans"
	"Current aim"			"@aim"

	/* You can enable these if you are using Counter-Strike Source and running the cstrike extension */
//	"Terrorists"			"@t"
//	"Counter-Terrorists"	"@ct"

}

I don't think you can just use @me or @self. Correct me if I'm wrong. You could try for example:

"sm_teleport ItsEvergreen" "adminflag"

[ItsEvergreen]

If your wondering if the command works or something or whatever. Will the command works fine for me. That's not the problem. Thanks but it did not work oh will I'm not having a problem with the command working, it works fine. I want to limit it, like in the way I have explained.

[Bacardi]

You need request new little plugin for to donators.

If you give them admin command, where you can target other(s), you can't limit them targeting (expect when admins immunity comes against)

*edit
Here if you want. Usage

sm_teleportme x y z
sm_teleportme save
sm_teleportme

Spoiler

PHP Code:

#include <sdktools>
new Float:g_fLocations[MAXPLAYERS+1][3];
new bool:g_bSaved[MAXPLAYERS+1];

public OnPluginStart()
{
    RegAdminCmd("sm_teleportme", teleport, ADMFLAG_RESERVATION, "Text here");
}

public Action:teleport(client, args)
{
    if(!client || !IsClientInGame(client))
    {
        return Plugin_Handled;
    }

    if(args == 0)
    {
        if(g_bSaved[client])
        {
            TeleportEntity(client, g_fLocations[client], NULL_VECTOR, NULL_VECTOR);
            ShowActivity2(client, "[SM]", "Teleported last saved location: %0.2f %0.2f %0.2f", g_fLocations[client][0], g_fLocations[client][1], g_fLocations[client][2]);
            LogAction(client, -1, "%L Teleported last saved location: %0.2f %0.2f %0.2f", client, g_fLocations[client][0], g_fLocations[client][1], g_fLocations[client][2]);
        }
        else
        {
            ReplyToCommand(client, "Save your location first: sm_teleportme save");
        }
    }
    else if(args == 1)
    {
        new String:arg[10];
        GetCmdArg(1, arg, sizeof(arg));
        if(StrEqual(arg, "save", false))
        {
            GetClientAbsOrigin(client, g_fLocations[client]);
            g_bSaved[client] = true;
            ReplyToCommand(client, "Location saved %0.2f %0.2f %0.2f", g_fLocations[client][0], g_fLocations[client][1], g_fLocations[client][2]);
        }
        return Plugin_Handled;
    }
    else if(args == 3)
    {
        new String:arg[10];
        GetCmdArg(1, arg, sizeof(arg));
        g_fLocations[client][0] = StringToFloat(arg);
        GetCmdArg(2, arg, sizeof(arg));
        g_fLocations[client][1] = StringToFloat(arg);
        GetCmdArg(3, arg, sizeof(arg));
        g_fLocations[client][2] = StringToFloat(arg);
        TeleportEntity(client, g_fLocations[client], NULL_VECTOR, NULL_VECTOR);
        ShowActivity2(client, "[SM]", "Teleported location: %0.2f %0.2f %0.2f", g_fLocations[client][0], g_fLocations[client][1], g_fLocations[client][2]);
        LogAction(client, -1, "%L Teleported location: %0.2f %0.2f %0.2f", client, g_fLocations[client][0], g_fLocations[client][1], g_fLocations[client][2]);
    }
    return Plugin_Handled;
}

public OnClientConnected(client)
{
    g_bSaved[client] = false;
} 


[ItsEvergreen]

Thanks Ill try this/these

[Bacardi]

aaa did you wanted only to work in this one location ?
-2389.258056 -4447.823730 307.036804

*edit

sm_teleportme

Spoiler

PHP Code:

#include <sdktools>

public OnPluginStart()
{
    RegAdminCmd("sm_teleportme", teleport, ADMFLAG_RESERVATION, "You go -2389.258056, -4447.823730, 307.036804");
}

public Action:teleport(client, args)
{
    if(!client || !IsClientInGame(client))
    {
        return Plugin_Handled;
    }
    new Float:pos[] = {-2389.258056, -4447.823730, 307.036804};
    TeleportEntity(client, pos, NULL_VECTOR, NULL_VECTOR);
    ShowActivity2(client, "[SM]", "Teleported %0.2f %0.2f %0.2f", pos[0], pos[1], pos[2]);
    LogAction(client, -1, "%L teleported %0.2f %0.2f %0.2f", client, pos[0], pos[1], pos[2]);
    return Plugin_Handled;
} 


[ItsEvergreen]

yes maybe more later if i pick, them

[ItsEvergreen]

Will I get this message when I try to use it/the command.

] sm_teleportme
Unknown command: sm_teleportme

[Bacardi]

any errors in SM log files.

You have loaded plugin
rcon sm plugins list

[ItsEvergreen]

Ok I ckecked and there where some errors, but no errors that I seen for the Teleport Plugin / teleport.smx. I have deleted the files causing the errors, but its still not working. And are you sure that sm_teleportme is a valid command? Does it work for you? And what plugin are you using to teleport if it does work or whatever?