[Marcoux]

Well, I need something like a ban sistem, where the plugin can realize weather If the time specified in a timestamp (or wichever format you may want to use and you think it's convenient) is previous than now, or not, In simple words, it checks if you are still banned.

I have knowledge about MySQL, and plugins, though I don't really realise how to handle well with strings to manage with time, which is pretty hard since of the different sizes of months and else.

Thanks in advance.

[Exolent[jNr]]

Tell me what you want to do and I can write you a simple script showing how to do it.

[10101010]

Why would you want that? You can ban players normally

EDIT: This may help you


http://www.google.com.ar/codesearch?...title&resnum=4

[Marcoux]

Well, lets supose somehow I set a timestamp in a MySQL. Something like this:

----AuthID-----Unban timestamp

Then, when a player connect, it retrieves the unban timestamp from his AuthID.

Up to here, I know how to everything,it's pretty easy.

Now, I want to know if the date and time of the timestamp, is before or after now. In other words, if the player is still banned, or if his ban has ended.

Thats just the thing I want to know.

[Exolent[jNr]]

Here is an example code of how it would be done with timestamps.

PHP Code:

#include < amxmodx >
#include < amxmisc >
#include < sqlx >
#include < fakemeta >

#define ENCODE_TEXT(%1) engfunc( EngFunc_AllocString, %1 )
#define DECODE_TEXT(%1,%2,%3) global_get( glb_pStringBase, %1, %2, %3 )

new Handle:g_hSqlTuple;

public plugin_init( ) {
    g_hSqlTuple = SQL_MakeStdTuple( );
}

CheckBan( client ) {
    static szAuthid[ 35 ];
    get_user_authid( client, szAuthid, 34 );
    
    if( containi( szAuthid, "STEAM_0:" ) == -1 ) {
        return;
    }
    
    static szQuery[ 128 ];
    formatex( szQuery, 127, "SELECT `timestamp` FROM `bantable` WHERE `authid` = '%s';", szAuthid );
    
    static iData[ 2 ];
    iData[ 0 ] = ENCODE_TEXT( szAuthid );
    
    SQL_ThreadQuery( g_hSqlTuple, "QueryCheckBan", szQuery, iData, 2 );
}

public QueryCheckBan( iFailState, Handle:hQuery, szError[ ], iError, iData[ ], iDataSize, Float:fQueueTime ) {
    switch( iFailState ) {
        case TQUERY_CONNECT_FAILED: {
            log_amx( "Connection failed: %s", szError);
        }
        case TQUERY_QUERY_FAILED: {
            log_amx( "Query failed: %s", szError );
        }
        default: {
            new iTimeStamp = SQL_ReadResult( hQuery, 0 );
            
            if( get_systime( ) >= iTimeStamp ) {
                // ban time expired
                
                static szAuthid[ 35 ];
                DECODE_TEXT( iData[ 0 ], szAuthid, 34 );
                
                static szQuery[ 128 ];
                formatex( szQuery, 127, "DELETE FROM `bantable` WHERE `authid` = '%s';", szAuthid );
                
                SQL_ThreadQuery( g_hSqlTuple, "QueryDeleteBan", szQuery );
            }
        }
    }
}

public QueryDeleteBan( iFailState, Handle:hQuery, szError[ ], iError, iData[ ], iDataSize, Float:fQueueTime ) {
    switch( iFailState ) {
        case TQUERY_CONNECT_FAILED: {
            log_amx( "Connection failed: %s", szError);
        }
        case TQUERY_QUERY_FAILED: {
            log_amx( "Query failed: %s", szError );
        }
        default: {
            // successfully deleted ban
        }
    }
}

AddBan( client, iBanMinutes ) {
    static szAuthid[ 35 ];
    get_user_authid( client, szAuthid, 34 );
    
    if( containi( szAuthid, "STEAM_0:" ) == -1 ) {
        return;
    }
    
    new iUnbanTime = get_systime( ) + ( iBanMinutes * 60 );
    
    static szQuery[ 128 ];
    formatex( szQuery, 127, "INSERT INTO `bantable` ( `authid`, `timestamp` ) VALUES ( '%s', %i );", szAuthid, iUnbanTime );
    
    SQL_ThreadQuery( g_hSqlTuple, "QueryAddBan", szQuery );
}

public QueryAddBan( iFailState, Handle:hQuery, szError[ ], iError, iData[ ], iDataSize, Float:fQueueTime ) {
    switch( iFailState ) {
        case TQUERY_CONNECT_FAILED: {
            log_amx( "Connection failed: %s", szError);
        }
        case TQUERY_QUERY_FAILED: {
            log_amx( "Query failed: %s", szError );
        }
        default: {
            // successfully added ban
        }
    }
} 


[Marcoux]

Will try, In a few minutes I answer you

Thanks you very much

[Marcoux]

Ok I don't know If this is double post, but, It's needed.

Your code worked really fine, I just didin't know about get_systime, which is really usefull since I can manage easily with time in just an integer.

Now what I would like, if you now any API, por getting a more user-friendly time format, from sys time.

Like

128937189273 ---> 02-08-09 14:23:45 (just an example)

[Exolent[jNr]]

http://forums.alliedmods.net/showthread.php?t=91915

[Marcoux]

Genius!
Karmageddon!